FS/bin/freeside-paymentech-upload

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use Getopt::Std;
   5 use Date::Format qw(time2str);
   6 use File::Temp qw(tempdir); #0.19 for ->newdir() interface, not in 5.10.0
   7 use Net::SFTP::Foreign;
   8 use Expect;
   9 use FS::UID qw(adminsuidsetup datasrc);
  10 use FS::Record qw(qsearch qsearchs);
  11 use FS::pay_batch;
  12 use FS::cust_pay_batch;
  13 use FS::Conf;
  14 use FS::Log;
  15
  16 use vars qw( $opt_a $opt_t $opt_v $opt_p );
  17 getopts('avtp:');
  18
  19 #$Net::SFTP::Foreign::debug = -1;
  20
  21 sub log_and_die {
  22   my $message = shift;
  23   my $log = FS::Log->new('freeside-paymentech-upload');
  24   $log->error($message);
  25   die $message;
  26 }
  27
  28 sub usage { "
  29   Usage:
  30     freeside-paymentech-upload [ -v ] [ -t ] user batchnum
  31     freeside-paymentech-upload -a [ -p payby ] [ -v ] [ -t ] user\n
  32 " }
  33
  34 my $user = shift or die &usage;
  35 adminsuidsetup $user;
  36
  37 my $zip_check = `which zip` or log_and_die("can't find zip executable\n");
  38
  39 my @batches;
  40
  41 if($opt_a) {
  42   my %criteria = (status => 'O');
  43   $criteria{'payby'} = uc($opt_p) if $opt_p;
  44   $criteria{'type'} = 'DEBIT' unless FS::pay_batch->can_handle_electronic_refunds('paymentech');
  45   @batches = qsearch('pay_batch', \%criteria);
  46   log_and_die("No open batches found".($opt_p ? " of type '$opt_p'" : '').".\n")
  47     if !@batches;
  48 }
  49 else {
  50   my $batchnum = shift;
  51   log_and_die("batchnum not passed\n".&usage) if !$batchnum;
  52   @batches = qsearchs('pay_batch', { batchnum => $batchnum } );
  53   log_and_die("Can't find payment batch '$batchnum'\n") if !@batches;
  54
  55   if ($batches[0]->type eq "CREDIT") {
  56     warn "running credit\n";
  57     log_and_die( "Batch number $batchnum is a credit (batch refund) batch, and this format can not handle batch refunds.\n" )
  58       unless FS::pay_batch->can_handle_electronic_refunds('paymentech');
  59   }
  60 }
  61
  62 my $conf = new FS::Conf;
  63 my @batchconf = $conf->config('batchconfig-paymentech');
  64 # BIN, terminalID, merchantID, username, password
  65 my $username = $batchconf[3] or log_and_die("no Paymentech batch username configured\n");
  66 my $password = $batchconf[4] or log_and_die("no Paymentech batch password configured\n");
  67
  68 #my $tmpdir = File::Temp->newdir();
  69 my $tmpdir = tempdir( CLEANUP => 1 ); #DIR=>somewhere?
  70
  71 my @filenames;
  72
  73 foreach my $pay_batch (@batches) {
  74   my $batchnum = $pay_batch->batchnum;
  75   my $filename = sprintf('%06d',$batchnum) . '-' .time2str('%Y%m%d%H%M%S', time);
  76   print STDERR "Exporting batch $batchnum to $filename...\n" if $opt_v;
  77   my $text = $pay_batch->export_batch(format => 'paymentech');
  78   $text =~ s!<fileID>FILEID</fileID>!<fileID>$filename</fileID>!
  79     or log_and_die("couldn't find FILEID tag\n");
  80   open OUT, ">$tmpdir/$filename.xml";
  81   print OUT $text;
  82   close OUT;
  83
  84   system('zip', '-P', $password, '-q', '-j',
  85            "$tmpdir/$filename.zip", "$tmpdir/$filename.xml");
  86
  87   log_and_die("failed to create zip file\n") if (! -f "$tmpdir/$filename.zip" );
  88   push @filenames, $filename;
  89 }
  90
  91 my $host = ($opt_t ? 'orbitalbatchvar.paymentech.net'
  92                    : 'orbitalbatch.paymentech.net');
  93 print STDERR "Connecting to $username\@$host...\n" if $opt_v;
  94
  95 my $sftp;
  96 my $ssh_retry      = 25;   # number of times to try connection, needs to be >= 1
  97 my $ssh_retry_wait = 60*5; # seconds to wait between tries
  98 while ($ssh_retry > 0) {
  99   $sftp = Net::SFTP::Foreign->new( host => $host,
 100                                    user => $username,
 101                                    password => $password,
 102                                    timeout => 300,
 103                                  );
 104   last unless $sftp->error;
 105   $ssh_retry -= 1;
 106   sleep($ssh_retry_wait) if $ssh_retry > 0;
 107 }
 108
 109 log_and_die("failed to connect to '$username\@$host'\n(".$sftp->error.")\n")
 110     if $sftp->error;
 111
 112 foreach my $filename (@filenames) {
 113   $sftp->put("$tmpdir/$filename.zip", "$filename.zip")
 114     or log_and_die("failed to upload file (".$sftp->error.")\n");
 115 }
 116
 117 print STDERR "Finished!\n" if $opt_v;
 118
 119 =head1 NAME
 120
 121 freeside-paymentech-upload - Transmit a payment batch to Chase Paymentech via SFTP.
 122
 123 =head1 SYNOPSIS
 124
 125   freeside-paymentech-upload [ -a [ -p PAYBY ] ] [ -v ] [ -t ] user batchnum
 126
 127 =head1 DESCRIPTION
 128
 129 Command line tool to upload a payment batch to the Chase Paymentech gateway.
 130 The batch will be exported to the Paymentech XML format, packaged in a ZIP
 131 file, and transmitted via SFTP.  Use L<freeside-paymentech-download> to retrieve the
 132 response file.
 133
 134 -a: Send all open batches, instead of specifying a batchnum.
 135
 136 -p PAYBY: With -a, limit to batches of that payment type, e.g. -p CARD.
 137
 138 -v: Be verbose.
 139
 140 -t: Send the transaction to the test server.
 141
 142 user: freeside username
 143
 144 batchnum: pay_batch primary key
 145
 146 =head1 BUGS
 147
 148 Passing the zip password on the command line is slightly risky.
 149
 150 =head1 SEE ALSO
 151
 152 L<FS::pay_batch>
 153
 154 =cut
 155
 156 1;
 157