FS/bin/freeside-paymentech-upload

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use Getopt::Std;
   5 use Date::Format qw(time2str);
   6 use File::Temp qw(tempdir); #0.19 for ->newdir() interface, not in 5.10.0
   7 use Net::SFTP::Foreign;
   8 use Expect;
   9 use FS::UID qw(adminsuidsetup datasrc);
  10 use FS::Record qw(qsearch qsearchs);
  11 use FS::pay_batch;
  12 use FS::cust_pay_batch;
  13 use FS::Conf;
  14 use FS::Log;
  15
  16 use vars qw( $opt_a $opt_t $opt_v $opt_p );
  17 getopts('avtp:');
  18
  19 #$Net::SFTP::Foreign::debug = -1;
  20
  21 sub log_and_die {
  22   my $message = shift;
  23   my $log = FS::Log->new('freeside-paymentech-upload');
  24   $log->error($message);
  25   die $message;
  26 }
  27
  28 sub usage { "
  29   Usage:
  30     freeside-paymentech-upload [ -v ] [ -t ] user batchnum
  31     freeside-paymentech-upload -a [ -p payby ] [ -v ] [ -t ] user\n
  32 " }
  33
  34 my $user = shift or die &usage;
  35 adminsuidsetup $user;
  36
  37 my $zip_check = `which zip` or log_and_die("can't find zip executable\n");
  38
  39 my @batches;
  40
  41 if($opt_a) {
  42   my %criteria = (status => 'O');
  43   $criteria{'payby'} = uc($opt_p) if $opt_p;
  44
  45   my $extra_sql;
  46   $extra_sql = " AND ((payby = 'CHEK' AND type != 'CREDIT') OR (payby != 'CHEK'))" unless FS::pay_batch->can_handle_electronic_refunds('paymentech');
  47
  48   my %hash = (
  49     table => 'pay_batch',
  50     hashref   => \%criteria,
  51     extra_sql => $extra_sql,
  52   );
  53
  54   @batches = qsearch(\%hash);
  55   log_and_die("No open batches found".($opt_p ? " of type '$opt_p'" : '').".\n")
  56     if !@batches;
  57 }
  58 else {
  59   my $batchnum = shift;
  60   log_and_die("batchnum not passed\n".&usage) if !$batchnum;
  61   @batches = qsearchs('pay_batch', { batchnum => $batchnum } );
  62   log_and_die("Can't find payment batch '$batchnum'\n") if !@batches;
  63
  64   if ($batches[0]->type eq "CREDIT") {
  65     warn "running credit\n";
  66     log_and_die( "Batch number $batchnum is a credit (batch refund) batch, and this format can not handle batch refunds.\n" )
  67       unless FS::pay_batch->can_handle_electronic_refunds('paymentech');
  68   }
  69 }
  70
  71 my $conf = new FS::Conf;
  72 my @batchconf = $conf->config('batchconfig-paymentech');
  73 # BIN, terminalID, merchantID, username, password
  74 my $username = $batchconf[3] or log_and_die("no Paymentech batch username configured\n");
  75 my $password = $batchconf[4] or log_and_die("no Paymentech batch password configured\n");
  76
  77 #my $tmpdir = File::Temp->newdir();
  78 my $tmpdir = tempdir( CLEANUP => 1 ); #DIR=>somewhere?
  79
  80 my @filenames;
  81
  82 foreach my $pay_batch (@batches) {
  83   my $batchnum = $pay_batch->batchnum;
  84   my $filename = sprintf('%06d',$batchnum) . '-' .time2str('%Y%m%d%H%M%S', time);
  85   print STDERR "Exporting batch $batchnum to $filename...\n" if $opt_v;
  86   my $text = $pay_batch->export_batch(format => 'paymentech');
  87   unless ($text) {
  88     print STDERR "Batch is empty, resolving..." if $opt_v;
  89     next;
  90   }
  91   $text =~ s!<fileID>FILEID</fileID>!<fileID>$filename</fileID>!
  92     or log_and_die("couldn't find FILEID tag\n");
  93   open OUT, ">$tmpdir/$filename.xml";
  94   print OUT $text;
  95   close OUT;
  96
  97   system('zip', '-P', $password, '-q', '-j',
  98            "$tmpdir/$filename.zip", "$tmpdir/$filename.xml");
  99
 100   log_and_die("failed to create zip file\n") if (! -f "$tmpdir/$filename.zip" );
 101   push @filenames, $filename;
 102 }
 103 log_and_die("All batches empty\n") if !@filenames;
 104
 105 my $host = ($opt_t ? 'orbitalbatchvar.paymentech.net'
 106                    : 'orbitalbatch.paymentech.net');
 107 print STDERR "Connecting to $username\@$host...\n" if $opt_v;
 108
 109 my $sftp;
 110 my $ssh_retry      = 25;   # number of times to try connection, needs to be >= 1
 111 my $ssh_retry_wait = 60*5; # seconds to wait between tries
 112 while ($ssh_retry > 0) {
 113   $sftp = Net::SFTP::Foreign->new( host => $host,
 114                                    user => $username,
 115                                    password => $password,
 116                                    timeout => 300,
 117                                  );
 118   last unless $sftp->error;
 119   $ssh_retry -= 1;
 120   sleep($ssh_retry_wait) if $ssh_retry > 0;
 121 }
 122
 123 log_and_die("failed to connect to '$username\@$host'\n(".$sftp->error.")\n")
 124     if $sftp->error;
 125
 126 foreach my $filename (@filenames) {
 127   $sftp->put("$tmpdir/$filename.zip", "$filename.zip")
 128     or log_and_die("failed to upload file (".$sftp->error.")\n");
 129 }
 130
 131 print STDERR "Finished!\n" if $opt_v;
 132
 133 =head1 NAME
 134
 135 freeside-paymentech-upload - Transmit a payment batch to Chase Paymentech via SFTP.
 136
 137 =head1 SYNOPSIS
 138
 139   freeside-paymentech-upload [ -a [ -p PAYBY ] ] [ -v ] [ -t ] user batchnum
 140
 141 =head1 DESCRIPTION
 142
 143 Command line tool to upload a payment batch to the Chase Paymentech gateway.
 144 The batch will be exported to the Paymentech XML format, packaged in a ZIP
 145 file, and transmitted via SFTP.  Use L<freeside-paymentech-download> to retrieve the
 146 response file.
 147
 148 -a: Send all open batches, instead of specifying a batchnum.
 149
 150 -p PAYBY: With -a, limit to batches of that payment type, e.g. -p CARD.
 151
 152 -v: Be verbose.
 153
 154 -t: Send the transaction to the test server.
 155
 156 user: freeside username
 157
 158 batchnum: pay_batch primary key
 159
 160 =head1 BUGS
 161
 162 Passing the zip password on the command line is slightly risky.
 163
 164 =head1 SEE ALSO
 165
 166 L<FS::pay_batch>
 167
 168 =cut
 169
 170 1;
 171