torrus/perllib/Torrus/DevDiscover/CiscoCatOS.pm

   1 #  Copyright (C) 2002  Stanislav Sinyagin
   2 #
   3 #  This program is free software; you can redistribute it and/or modify
   4 #  it under the terms of the GNU General Public License as published by
   5 #  the Free Software Foundation; either version 2 of the License, or
   6 #  (at your option) any later version.
   7 #
   8 #  This program is distributed in the hope that it will be useful,
   9 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 #  GNU General Public License for more details.
  12 #
  13 #  You should have received a copy of the GNU General Public License
  14 #  along with this program; if not, write to the Free Software
  15 #  Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA.
  16
  17 # $Id: CiscoCatOS.pm,v 1.1 2010-12-27 00:03:55 ivan Exp $
  18 # Stanislav Sinyagin <ssinyagin@yahoo.com>
  19
  20 # Cisco CatOS devices discovery
  21 # To do:
  22 #    Power supply and temperature monitoring
  23 #    RAM monitoring
  24
  25 package Torrus::DevDiscover::CiscoCatOS;
  26
  27 use strict;
  28 use Torrus::Log;
  29
  30
  31 $Torrus::DevDiscover::registry{'CiscoCatOS'} = {
  32     'sequence'     => 500,
  33     'checkdevtype' => \&checkdevtype,
  34     'discover'     => \&discover,
  35     'buildConfig'  => \&buildConfig
  36     };
  37
  38
  39 our %oiddef =
  40     (
  41      # CISCO-SMI
  42      'ciscoWorkgroup'                    => '1.3.6.1.4.1.9.5',
  43      # CISCO-STACK-MIB
  44      'CISCO-STACK-MIB::portName'         => '1.3.6.1.4.1.9.5.1.4.1.1.4',
  45      'CISCO-STACK-MIB::portIfIndex'      => '1.3.6.1.4.1.9.5.1.4.1.1.11',
  46      'CISCO-STACK-MIB::chassisSerialNumberString' =>
  47      '1.3.6.1.4.1.9.5.1.2.19.0'
  48      );
  49
  50
  51 # Not all interfaces are normally needed to monitor.
  52 # You may override the interface filtering in devdiscover-siteconfig.pl:
  53 # redefine $Torrus::DevDiscover::CiscoCatOS::interfaceFilter
  54 # or define $Torrus::DevDiscover::CiscoCatOS::interfaceFilterOverlay
  55
  56 our $interfaceFilter;
  57 our $interfaceFilterOverlay;
  58 my %catOsInterfaceFilter;
  59
  60 if( not defined( $interfaceFilter ) )
  61 {
  62     $interfaceFilter = \%catOsInterfaceFilter;
  63 }
  64
  65
  66 # Key is some unique symbolic name, does not mean anything
  67 # ifType is the number to match the interface type
  68 # ifDescr is the regexp to match the interface description
  69 %catOsInterfaceFilter =
  70     (
  71      'VLAN N' => {
  72          'ifType'  => 53,                     # propVirtual
  73          'ifDescr' => '^VLAN\s+\d+'
  74          },
  75      );
  76
  77 sub checkdevtype
  78 {
  79     my $dd = shift;
  80     my $devdetails = shift;
  81
  82     if( not $dd->oidBaseMatch
  83         ( 'ciscoWorkgroup',
  84           $devdetails->snmpVar( $dd->oiddef('sysObjectID') ) ) )
  85     {
  86         return 0;
  87     }
  88
  89     &Torrus::DevDiscover::RFC2863_IF_MIB::addInterfaceFilter
  90         ($devdetails, $interfaceFilter);
  91
  92     if( defined( $interfaceFilterOverlay ) )
  93     {
  94         &Torrus::DevDiscover::RFC2863_IF_MIB::addInterfaceFilter
  95             ($devdetails, $interfaceFilterOverlay);
  96     }
  97
  98     $devdetails->setCap('interfaceIndexingManaged');
  99
 100     return 1;
 101 }
 102
 103
 104 sub discover
 105 {
 106     my $dd = shift;
 107     my $devdetails = shift;
 108
 109     my $session = $dd->session();
 110     my $data = $devdetails->data();
 111
 112     $data->{'nameref'}{'ifReferenceName'} = 'ifName';
 113     $data->{'nameref'}{'ifSubtreeName'} = 'ifNameT';
 114     $data->{'param'}{'ifindex-table'} = '$ifName';
 115
 116     $data->{'nameref'}{'ifComment'} = 'portName';
 117
 118     # Retrieve port descriptions from CISCO-STACK-MIB
 119
 120     my $portIfIndexOID = $dd->oiddef('CISCO-STACK-MIB::portIfIndex');
 121     my $portNameOID = $dd->oiddef('CISCO-STACK-MIB::portName');
 122
 123     my $portIfIndex = $session->get_table( -baseoid => $portIfIndexOID );
 124     if( defined $portIfIndex )
 125     {
 126         $devdetails->storeSnmpVars( $portIfIndex );
 127
 128         my $portName = $session->get_table( -baseoid => $portNameOID );
 129         if( defined $portName )
 130         {
 131             foreach my $portIndex
 132                 ( $devdetails->getSnmpIndices( $portIfIndexOID ) )
 133             {
 134                 my $ifIndex =
 135                     $devdetails->snmpVar( $portIfIndexOID .'.'. $portIndex );
 136                 my $interface = $data->{'interfaces'}{$ifIndex};
 137
 138                 $interface->{'portName'} =
 139                     $portName->{$portNameOID .'.'. $portIndex};
 140             }
 141         }
 142     }
 143
 144     # In large installations, only named ports may be of interest
 145     if( $devdetails->param('CiscoCatOS::suppress-noname-ports') eq 'yes' )
 146     {
 147         my $nExcluded = 0;
 148         foreach my $ifIndex ( keys %{$data->{'interfaces'}} )
 149         {
 150             my $interface = $data->{'interfaces'}{$ifIndex};
 151             if( not defined( $interface->{'portName'} ) or
 152                 length( $interface->{'portName'} ) == 0 )
 153             {
 154                 $interface->{'excluded'} = 1;
 155                 $nExcluded++;
 156             }
 157         }
 158         Debug('Excluded ' . $nExcluded . ' catalyst ports with empty names');
 159     }
 160
 161     my $chassisSerial =
 162         $dd->retrieveSnmpOIDs( 'CISCO-STACK-MIB::chassisSerialNumberString' );
 163     if( defined( $chassisSerial ) )
 164     {
 165         if( defined( $data->{'param'}{'comment'} ) )
 166         {
 167             $data->{'param'}{'comment'} .= ', ';
 168         }
 169         $data->{'param'}{'comment'} .= 'Hw Serial#: ' .
 170             $chassisSerial->{'CISCO-STACK-MIB::chassisSerialNumberString'};
 171     }
 172
 173     return 1;
 174 }
 175
 176
 177 # Nothing really to do yet
 178 sub buildConfig
 179 {
 180     my $devdetails = shift;
 181     my $cb = shift;
 182     my $devNode = shift;
 183 }
 184
 185
 186 1;
 187
 188
 189 # Local Variables:
 190 # mode: perl
 191 # indent-tabs-mode: nil
 192 # perl-indent-level: 4
 193 # End: