rt/t/web/walk.t

   1
   2 use strict;
   3 use warnings;
   4
   5 use RT::Test;
   6 use HTML::TreeBuilder;
   7
   8 my ( $baseurl, $m ) = RT::Test->started_ok;
   9
  10 ok( $m->login( 'root' => 'password' ), 'login as root' );
  11
  12 my %viewed = ( '/NoAuth/Logout.html' => 1 );    # in case logout
  13
  14 my $user = RT::User->new($RT::SystemUser);
  15 $user->Load('root');
  16 ok( $user->id, 'loaded root' );
  17
  18 my $queue = RT::Queue->new($RT::SystemUser);
  19 $queue->Load('General');
  20 ok( $queue->id, 'loaded General queue' );
  21
  22 my $group = RT::Group->new($RT::SystemUser);
  23 ok( $group->CreateUserDefinedGroup( Name => 'group_foo' ) );
  24 my $cf = RT::CustomField->new($RT::SystemUser);
  25 ok(
  26     $cf->Create(
  27         Name       => 'cf_foo',
  28         Type       => 'Freeform',
  29         LookupType => 'RT::Queue-RT::Ticket',
  30     )
  31 );
  32 ok( $cf->id, 'created cf_foo' );
  33
  34 my $class = RT::Class->new($RT::SystemUser);
  35 ok( $class->Create( Name => 'class_foo' ) );
  36 ok( $class->id, 'created class_foo' );
  37
  38 # to make search have results
  39 my $open_ticket = RT::Test->create_ticket(
  40     Subject => 'ticket_foo',
  41     Queue   => 1,
  42 );
  43
  44 my $resolved_ticket = RT::Test->create_ticket(
  45     Subject => 'ticket_bar',
  46     Status  => 'resolved',
  47     Queue   => 1,
  48 );
  49
  50 my @links = (
  51     '/',
  52     '/Admin/Users/Modify.html?id=' . $user->id,
  53     '/Admin/Groups/Modify.html?id=' . $group->id,
  54     '/Admin/Queues/Modify.html?id=' . $queue->id,
  55     '/Admin/CustomFields/Modify.html?id=' . $cf->id,
  56     '/Admin/Scrips/Modify.html?id=1',
  57     '/Admin/Global/Template.html?Template=1',
  58     '/Admin/Articles/Classes/Modify.html?id=' . $class->id,
  59     '/Search/Build.html?Query=id<10',
  60     '/Ticket/Display.html?id=' . $open_ticket->id,
  61     '/Ticket/Display.html?id=' . $resolved_ticket->id,
  62 );
  63
  64 for my $link (@links) {
  65     test_page($m, $link);
  66 }
  67
  68 $m->get_ok('/NoAuth/Logout.html');
  69
  70 sub test_page {
  71     my $m = shift;
  72     my $link = shift;
  73     $m->get_ok( $link, $link );
  74     $m->no_warnings_ok($link);
  75
  76     my $tree = HTML::TreeBuilder->new();
  77     $tree->parse( $m->content );
  78     $tree->elementify;
  79     my ($top_menu)  = $tree->look_down( id => 'main-navigation' );
  80     my ($page_menu) = $tree->look_down( id => 'page-navigation' );
  81
  82     my (@links) =
  83       grep { !$viewed{$_}++ && /^[^#]/ }
  84       map { $_->attr('href') || () } ( $top_menu ? $top_menu->find('a') : () ),
  85       ( $page_menu ? $page_menu->find('a') : () );
  86
  87     for my $link (@links) {
  88         test_page($m, $link);
  89     }
  90 }
  91