rt/t/web/queue_caching.t

   1 use strict;
   2 use warnings;
   3 use RT::Test tests => 48;
   4
   5 # make an initial queue, so we have more than 1
   6 my $original_test_queue = new_queue("Test$$");
   7
   8 my ($baseurl, $m) = RT::Test->started_ok;
   9 ok $m->login, 'logged in';
  10
  11 diag("Check for 2 existing queues being visible");
  12 {
  13     check_queues($m);
  14 }
  15
  16 diag("Add a new queue, which won't show up until we fix the cache");
  17 {
  18     new_queue("New Test $$");
  19     check_queues($m);
  20 }
  21
  22 diag("Disable an existing queue, it should stop appearing in the list");
  23 {
  24     ok($original_test_queue->SetDisabled(1));
  25     check_queues($m);
  26 }
  27
  28 diag("Bring back a disabled queue");
  29 {
  30     ok($original_test_queue->SetDisabled(0));
  31     check_queues($m);
  32 }
  33
  34 diag("Rename the original queue, make sure the name change is uncached");
  35 {
  36     ok($original_test_queue->SetName("Name Change $$"));
  37     check_queues($m);
  38 }
  39
  40 diag("Test a user who has more limited rights Queues");
  41 {
  42
  43 my $user_a = RT::Test->load_or_create_user(
  44     Name => 'user_a', Password => 'password',
  45 );
  46 ok $user_a && $user_a->id, 'loaded or created user';
  47
  48 ok( RT::Test->set_rights(
  49         { Principal => $user_a, Right => [qw(SeeQueue CreateTicket)], Object => $original_test_queue },
  50 ), 'Allow user a to see the testing queue');
  51
  52 my $a_m = RT::Test::Web->new;
  53 ok $a_m->login('user_a', 'password'), 'logged in as user A';
  54
  55 # check that they see a single queue
  56 check_queues($a_m,[$original_test_queue->Id],[$original_test_queue->Name]);
  57
  58 ok( RT::Test->add_rights(
  59         { Principal => $user_a, Right => [qw(SeeQueue CreateTicket)] },
  60 ), 'add global queue viewing rights');
  61
  62 check_queues($a_m);
  63
  64 }
  65
  66 sub new_queue {
  67     my $name = shift;
  68     my $new_queue = RT::Queue->new(RT->SystemUser);
  69     ok($new_queue->Create( Name => $name, Description => "Testing for $name queue" ), "Created queue ".$new_queue->Name);
  70     return $new_queue;
  71 }
  72
  73 sub internal_queues {
  74     my $internal_queues = RT::Queues->new(RT->SystemUser);
  75     $internal_queues->Limit(FIELD => 'Disabled', VALUE => 0);
  76     my $queuelist;
  77     while ( my $q = $internal_queues->Next ) {
  78         $queuelist->{$q->Id} = $q->Name;
  79     }
  80     return $queuelist;
  81 }
  82
  83
  84 # takes a WWW::Mech object and two optional arrayrefs of queue ids and names
  85 # compares the list of ids and names to the dropdown of Queues for the New Ticket In form
  86 sub check_queues {
  87     my ($browser, $queue_id_list, $queue_name_list) = @_;
  88     $browser->get_ok($baseurl,"Navigated to homepage");
  89     ok(my $form = $browser->form_name('CreateTicketInQueue'), "Found New Ticket In form");
  90     ok(my $queuelist = $form->find_input('Queue','option'), "Found queue select");
  91
  92     my @queue_ids = $queuelist->possible_values;
  93     my @queue_names = $queuelist->value_names;
  94
  95     my $full_queue_list = internal_queues();
  96     $queue_id_list = [keys %$full_queue_list] unless $queue_id_list;
  97     $queue_name_list = [values %$full_queue_list] unless $queue_name_list;
  98     is_deeply([sort @queue_ids],[sort @$queue_id_list],
  99               "Queue list contains the expected queue ids");
 100     is_deeply([sort @queue_names],[sort @$queue_name_list],
 101               "Queue list contains the expected queue namess");
 102 }