rt/t/ticket/sort-by-user.t

   1 #!/usr/bin/perl
   2
   3 use RT::Test nodata => 1, tests => 52;
   4
   5 use strict;
   6 use warnings;
   7
   8 use RT::Tickets;
   9 use RT::Queue;
  10 use RT::CustomField;
  11
  12 #########################################################
  13 # Test sorting by Owner, Creator and LastUpdatedBy
  14 # we sort by user name
  15 #########################################################
  16
  17 diag "Create a queue to test with.";
  18 my $queue_name = "OwnerSortQueue$$";
  19 my $queue;
  20 {
  21     $queue = RT::Queue->new( RT->SystemUser );
  22     my ($ret, $msg) = $queue->Create(
  23         Name => $queue_name,
  24         Description => 'queue for custom field sort testing'
  25     );
  26     ok($ret, "$queue test queue creation. $msg");
  27 }
  28
  29 my @uids;
  30 my @users;
  31 # create them in reverse order to avoid false positives
  32 foreach my $u (qw(Z A)) {
  33     my $name = $u ."-user-to-test-ordering-$$";
  34     my $user = RT::User->new( RT->SystemUser );
  35     my ($uid) = $user->Create(
  36         Name => $name,
  37         Privileged => 1,
  38     );
  39     ok $uid, "created user #$uid";
  40
  41     my ($status, $msg) = $user->PrincipalObj->GrantRight( Right => 'OwnTicket', Object => $queue );
  42     ok $status, "granted right";
  43     ($status, $msg) = $user->PrincipalObj->GrantRight( Right => 'CreateTicket', Object => $queue );
  44     ok $status, "granted right";
  45
  46     push @users, $user;
  47     push @uids, $user->id;
  48 }
  49
  50 my (@data, @tickets, @test) = (0, ());
  51
  52
  53 sub run_tests {
  54     my $query_prefix = join ' OR ', map 'id = '. $_->id, @tickets;
  55     foreach my $test ( @test ) {
  56         my $query = join " AND ", map "( $_ )", grep defined && length,
  57             $query_prefix, $test->{'Query'};
  58
  59         foreach my $order (qw(ASC DESC)) {
  60             my $error = 0;
  61             my $tix = RT::Tickets->new( RT->SystemUser );
  62             $tix->FromSQL( $query );
  63             $tix->OrderBy( FIELD => $test->{'Order'}, ORDER => $order );
  64
  65             ok($tix->Count, "found ticket(s)")
  66                 or $error = 1;
  67
  68             my ($order_ok, $last) = (1, $order eq 'ASC'? '-': 'zzzzzz');
  69             while ( my $t = $tix->Next ) {
  70                 my $tmp;
  71                 if ( $order eq 'ASC' ) {
  72                     $tmp = ((split( /,/, $last))[0] cmp (split( /,/, $t->Subject))[0]);
  73                 } else {
  74                     $tmp = -((split( /,/, $last))[-1] cmp (split( /,/, $t->Subject))[-1]);
  75                 }
  76                 if ( $tmp > 0 ) {
  77                     $order_ok = 0; last;
  78                 }
  79                 $last = $t->Subject;
  80             }
  81
  82             ok( $order_ok, "$order order of tickets is good" )
  83                 or $error = 1;
  84
  85             if ( $error ) {
  86                 diag "Wrong SQL query:". $tix->BuildSelectQuery;
  87                 $tix->GotoFirstItem;
  88                 while ( my $t = $tix->Next ) {
  89                     diag sprintf "%02d - %s", $t->id, $t->Subject;
  90                 }
  91             }
  92         }
  93     }
  94 }
  95
  96 @data = (
  97     { Subject => 'Nobody' },
  98     { Subject => 'Z', Owner => $uids[0] },
  99     { Subject => 'A', Owner => $uids[1] },
 100 );
 101
 102 @tickets = RT::Test->create_tickets( { Queue => $queue->id }, @data );
 103
 104 @test = (
 105     { Order => "Owner" },
 106 );
 107 run_tests();
 108
 109 @data = (
 110     { Subject => 'RT' },
 111     { Subject => 'Z', Creator => $uids[0] },
 112     { Subject => 'A', Creator => $uids[1] },
 113 );
 114 @tickets = RT::Test->create_tickets( { Queue => $queue->id }, @data );
 115 @test = (
 116     { Order => "Creator" },
 117 );
 118 run_tests();
 119
 120 @data = (
 121     { Subject => 'RT' },
 122     { Subject => 'Z', LastUpdatedBy => $uids[0] },
 123     { Subject => 'A', LastUpdatedBy => $uids[1] },
 124 );
 125 @tickets = RT::Test->create_tickets( { Queue => $queue->id }, @data );
 126 @test = (
 127     { Order => "LastUpdatedBy" },
 128 );
 129 run_tests();
 130
 131 @tickets = ();