rt/t/ticket/search_by_watcher_group.t

   1 use strict;
   2 use warnings;
   3
   4 use RT::Test tests => undef;
   5
   6 use Test::Warn;
   7
   8 my $q = RT::Test->load_or_create_queue( Name => 'General' );
   9 ok $q && $q->id, 'loaded or created queue';
  10 my $queue = $q->Name;
  11
  12
  13 my $group;
  14 {
  15     $group = RT::Group->new( RT->SystemUser );
  16     my ($id, $msg) = $group->CreateUserDefinedGroup( Name => 'Test' );
  17     ok $id, "$msg";
  18 }
  19
  20 my $root = RT::Test->load_or_create_user( Name => 'root', MemberOf => $group->id );
  21 ok $root && $root->id;
  22
  23 RT::Test->create_tickets(
  24     { Queue => $q, },
  25     { Subject => '-', },
  26     { Subject => 'o', Owner => $root->id },
  27     { Subject => 'r', Requestor => $root->id },
  28     { Subject => 'c', Cc => $root->id },
  29     { Subject => 'a', AdminCc => $root->id },
  30 );
  31
  32 run_tests(
  33     'OwnerGroup = "Test"' => { '-' => 0, o => 1, r => 0, c => 0, a => 0 },
  34     'RequestorGroup = "Test"' => { '-' => 0, o => 0, r => 1, c => 0, a => 0 },
  35     'CCGroup = "Test"' => { '-' => 0, o => 0, r => 0, c => 1, a => 0 },
  36     'AdminCCGroup = "Test"' => { '-' => 0, o => 0, r => 0, c => 0, a => 1 },
  37     'WatcherGroup = "Test"' => { '-' => 0, o => 1, r => 1, c => 1, a => 1 },
  38 );
  39
  40 warning_like {
  41     my $tickets = RT::Tickets->new( RT->SystemUser );
  42     my ($status, $msg) = $tickets->FromSQL('OwnerGroup != "Test"');
  43     ok !$status, "incorrect op: $msg";
  44 } qr{Invalid OwnerGroup Op: !=};
  45
  46 done_testing();
  47
  48 sub run_tests {
  49     my @test = @_;
  50     while ( my ($query, $checks) = splice @test, 0, 2 ) {
  51         run_test( $query, %$checks );
  52     }
  53 }
  54
  55 sub run_test {
  56     my ($query, %checks) = @_;
  57
  58     my $tix = RT::Tickets->new(RT->SystemUser);
  59     $tix->FromSQL($query);
  60     my $error = 0;
  61
  62     my $count = 0;
  63     $count++ foreach grep $_, values %checks;
  64     is($tix->Count, $count, "found correct number of ticket(s) by '$query'") or $error = 1;
  65
  66     my $good_tickets = ($tix->Count == $count);
  67     while ( my $ticket = $tix->Next ) {
  68         next if $checks{ $ticket->Subject };
  69         diag $ticket->Subject ." ticket has been found when it's not expected";
  70         $good_tickets = 0;
  71     }
  72     ok( $good_tickets, "all tickets are good with '$query'" ) or $error = 1;
  73
  74     diag "Wrong SQL query for '$query':". $tix->BuildSelectQuery if $error;
  75 }