a6800bbb454ee34243d30e32869b1a796347e270
[freeside.git] / rt / t / ticket / search_by_watcher.t
1
2 use strict;
3 use warnings;
4
5 use RT::Test nodata => 1, tests => 2108;
6 use RT::Ticket;
7
8 my $q = RT::Test->load_or_create_queue( Name => 'Regression' );
9 ok $q && $q->id, 'loaded or created queue';
10 my $queue = $q->Name;
11
12 my ($total, @tickets, @test, @conditions) = (0, ());
13
14 sub generate_tix {
15     my @list = (
16         [],
17         ['x@foo.com'], ['y@bar.com'], ['z@bar.com'],
18         ['x@foo.com', 'y@bar.com'],
19         ['y@bar.com', 'z@bar.com'],
20         ['x@foo.com', 'z@bar.com'],
21         ['x@foo.com', 'y@bar.com', 'z@bar.com'],
22     );
23     my @data = ();
24     foreach my $r (@list) {
25         foreach my $c (@list) {
26             my $subject = 'r:'. (join( '', map substr($_, 0, 1), @$r ) || '-') .';';
27             $subject .= 'c:'. (join( '', map substr($_, 0, 1), @$c ) || '-') .';';
28
29             push @data, {
30                 Subject => $subject,
31                 Requestor => $r,
32                 Cc => $c,
33             };
34         }
35     }
36     return RT::Test->create_tickets( { Queue => $q->id }, @data );
37 }
38
39 sub run_tests {
40     while ( my ($query, $checks) = splice @test, 0, 2 ) {
41         run_test( $query, %$checks );
42     }
43 }
44
45 sub run_test {
46     my ($query, %checks) = @_;
47
48     my $tix = RT::Tickets->new(RT->SystemUser);
49     $tix->FromSQL($query);
50     my $error = 0;
51
52     my $count = 0;
53     $count++ foreach grep $_, values %checks;
54     is($tix->Count, $count, "found correct number of ticket(s) by '$query'") or $error = 1;
55
56     my $good_tickets = ($tix->Count == $count);
57     while ( my $ticket = $tix->Next ) {
58         next if $checks{ $ticket->Subject };
59         diag $ticket->Subject ." ticket has been found when it's not expected";
60         $good_tickets = 0;
61     }
62     ok( $good_tickets, "all tickets are good with '$query'" ) or $error = 1;
63
64     diag "Wrong SQL query for '$query':". $tix->BuildSelectQuery if $error;
65 }
66
67 sub run_auto_tests {
68     {
69         my @atmp = @conditions;
70         while ( my ($query, $cb) = splice @atmp, 0, 2 ) {
71             my %checks = ();
72             foreach my $ticket ( @tickets ) {
73                 my $s = $ticket->Subject;
74                 $checks{ $s } = $cb->($s);
75             }
76             run_test($query, %checks);
77         }
78     }
79     my @queries = (
80         '? AND ?'  => sub { $_[0] and $_[1] },
81         '? OR  ?' => sub  { $_[0] or $_[1] },
82     );
83     while ( my ($template, $t_cb) = splice @queries, 0, 2 ) {
84         my @atmp = @conditions;
85         while ( my ($a, $a_cb) = splice @atmp, 0, 2 ) {
86         my @btmp = @conditions;
87         while ( my ($b, $b_cb) = splice @btmp, 0, 2 ) {
88         next if $a eq $b;
89
90             my %checks = ();
91             foreach my $ticket ( @tickets ) {
92                 my $s = $ticket->Subject;
93                 $checks{ $s } = $t_cb->( scalar $a_cb->($s), scalar $b_cb->($s) );
94             }
95
96             my $query = $template;
97             foreach my $tmp ($a, $b) {
98                 $query =~ s/\?/$tmp/;
99             }
100
101             run_test( $query, %checks );
102         } }
103     }
104 # XXX: It
105 #    @queries = (
106 #        '? AND ? AND ?'  => sub { $_[0] and $_[1] and $_[2] },
107 #        '(? OR ?) AND ?' => sub { return (($_[0] or $_[1]) and $_[2]) },
108 #        '? OR (? AND ?)' => sub { $_[0] or ($_[1] and $_[2]) },
109 #        '(? AND ?) OR ?' => sub { ($_[0] and $_[1]) or $_[2] },
110 #        '? AND (? OR ?)' => sub { $_[0] and ($_[1] or $_[2]) },
111 #        '? OR ? OR ?'    => sub { $_[0] or $_[1] or $_[2] },
112 #    );
113 #    while ( my ($template, $t_cb) = splice @queries, 0, 2 ) {
114 #        my @atmp = @conditions;
115 #        while ( my ($a, $a_cb) = splice @atmp, 0, 2 ) {
116 #        my @btmp = @conditions;
117 #        while ( my ($b, $b_cb) = splice @btmp, 0, 2 ) {
118 #        next if $a eq $b;
119 #        my @ctmp = @conditions;
120 #        while ( my ($c, $c_cb) = splice @ctmp, 0, 2 ) {
121 #        next if $a eq $c;
122 #        next if $b eq $c;
123 #
124 #            my %checks = ();
125 #            foreach my $ticket ( @tickets ) {
126 #                my $s = $ticket->Subject;
127 #                $checks{ $s } = $t_cb->( scalar $a_cb->($s), scalar $b_cb->($s), scalar $c_cb->($s) );
128 #            }
129 #
130 #            my $query = $template;
131 #            foreach my $tmp ($a, $b, $c) {
132 #                $query =~ s/\?/$tmp/;
133 #            }
134 #
135 #            run_test( $query, %checks );
136 #        } } }
137 #    }
138
139 }
140
141 @conditions = (
142     'Cc = "not@exist"'       => sub { 0 },
143     'Cc != "not@exist"'      => sub { 1 },
144     'Cc IS NULL'             => sub { $_[0] =~ /c:-;/ },
145     'Cc IS NOT NULL'         => sub { $_[0] !~ /c:-;/ },
146     'Cc = "x@foo.com"'       => sub { $_[0] =~ /c:[^;]*x/ },
147     'Cc != "x@foo.com"'      => sub { $_[0] !~ /c:[^;]*x/ },
148     'Cc LIKE "@bar.com"'     => sub { $_[0] =~ /c:[^;]*(?:y|z)/ },
149 # TODO:
150 #    'Cc NOT LIKE "@bar.com"' => sub { $_[0] !~ /y|z/ },
151
152     'Requestor = "not@exist"'   => sub { 0 },
153     'Requestor != "not@exist"'  => sub { 1 },
154     'Requestor IS NULL'         => sub { $_[0] =~ /r:-;/ },
155     'Requestor IS NOT NULL'     => sub { $_[0] !~ /r:-;/ },
156     'Requestor = "x@foo.com"'   => sub { $_[0] =~ /r:[^;]*x/ },
157     'Requestor != "x@foo.com"'  => sub { $_[0] !~ /r:[^;]*x/ },
158     'Requestor LIKE "@bar.com"' => sub { $_[0] =~ /r:[^;]*(?:y|z)/ },
159 # TODO:
160 #    'Requestor NOT LIKE "@bar.com"' => sub { $_[0] !~ /y|z/ },
161
162     'Watcher = "not@exist"'   => sub { 0 },
163     'Watcher != "not@exist"'  => sub { 1 },
164 # TODO:
165 #    'Watcher IS NULL'         => sub { $_[0] eq 'r:-;c:-;' },
166 #    'Watcher IS NOT NULL'     => sub { $_[0] ne 'r:-;c:-;' },
167     'Watcher = "x@foo.com"'   => sub { $_[0] =~ /x/ },
168 #    'Watcher != "x@foo.com"'  => sub { $_[0] !~ /x/ },
169     'Watcher LIKE "@bar.com"' => sub { $_[0] =~ /(?:y|z)/ },
170 # TODO:
171 #    'Watcher NOT LIKE "@bar.com"' => sub { $_[0] !~ /y|z/ },
172
173     'Subject LIKE "ne"'      => sub { 0 },
174     'Subject NOT LIKE "ne"'  => sub { 1 },
175     'Subject = "r:x;c:y;"'   => sub { $_[0] eq 'r:x;c:y;' },
176     'Subject LIKE "x"'       => sub { $_[0] =~ /x/ },
177 );
178
179 @tickets = generate_tix();
180 $total += scalar @tickets;
181 {
182     my $tix = RT::Tickets->new(RT->SystemUser);
183     $tix->FromSQL("Queue = '$queue'");
184     is($tix->Count, $total, "found $total tickets");
185 }
186 run_auto_tests();
187
188 # owner is special watcher because reference is duplicated in two places,
189 # owner was an ENUM field now it's WATCHERFIELD, but should support old
190 # style ENUM searches for backward compatibility
191 my $nobody = RT::Nobody();
192 {
193     my $tix = RT::Tickets->new(RT->SystemUser);
194     $tix->FromSQL("Queue = '$queue' AND Owner = '". $nobody->id ."'");
195     ok($tix->Count, "found ticket(s)");
196 }
197 {
198     my $tix = RT::Tickets->new(RT->SystemUser);
199     $tix->FromSQL("Queue = '$queue' AND Owner = '". $nobody->Name ."'");
200     ok($tix->Count, "found ticket(s)");
201 }
202 {
203     my $tix = RT::Tickets->new(RT->SystemUser);
204     $tix->FromSQL("Queue = '$queue' AND Owner != '". $nobody->id ."'");
205     is($tix->Count, 0, "found ticket(s)");
206 }
207 {
208     my $tix = RT::Tickets->new(RT->SystemUser);
209     $tix->FromSQL("Queue = '$queue' AND Owner != '". $nobody->Name ."'");
210     is($tix->Count, 0, "found ticket(s)");
211 }
212
213 {
214     my $tix = RT::Tickets->new(RT->SystemUser);
215     $tix->FromSQL("Queue = '$queue' AND Owner.Name LIKE 'nob'");
216     ok($tix->Count, "found ticket(s)");
217 }
218
219 {
220     # create ticket and force type to not a 'ticket' value
221     # bug #6898@rt3.fsck.com
222     # and http://marc.theaimsgroup.com/?l=rt-devel&m=112662934627236&w=2
223     my($t) = RT::Test->create_tickets( { Queue => $q->id }, { Subject => 'not a ticket' } );
224     $t->_Set( Field             => 'Type',
225               Value             => 'not a ticket',
226               CheckACL          => 0,
227               RecordTransaction => 0,
228             );
229
230     my $tix = RT::Tickets->new(RT->SystemUser);
231     $tix->FromSQL("Queue = '$queue' AND Owner = 'Nobody'");
232     is($tix->Count, $total, "found ticket(s)");
233 }
234
235 {
236     my $everyone = RT::Group->new( RT->SystemUser );
237     $everyone->LoadSystemInternalGroup('Everyone');
238     ok($everyone->id, "loaded 'everyone' group");
239     my($id, $msg) = $everyone->PrincipalObj->GrantRight( Right => 'OwnTicket',
240                                                          Object => $q
241                                                        );
242     ok($id, "granted OwnTicket right to Everyone on '$queue'") or diag("error: $msg");
243
244     my $u = RT::User->new( RT->SystemUser );
245     $u->LoadOrCreateByEmail('alpha@e.com');
246     ok($u->id, "loaded user");
247     my($t) = RT::Test->create_tickets(
248         { Queue => $q->id }, { Subject => '4', Owner => $u->id },
249     );
250     my $u_alpha_id = $u->id;
251
252     $u = RT::User->new( RT->SystemUser );
253     $u->LoadOrCreateByEmail('bravo@e.com');
254     ok($u->id, "loaded user");
255     ($t) = RT::Test->create_tickets(
256         { Queue => $q->id }, { Subject => '5', Owner => $u->id },
257     );
258     my $u_bravo_id = $u->id;
259
260     my $tix = RT::Tickets->new(RT->SystemUser);
261     $tix->FromSQL("Queue = '$queue' AND
262                    ( Owner = '$u_alpha_id' OR
263                      Owner = '$u_bravo_id' )"
264                  );
265     is($tix->Count, 2, "found ticket(s)");
266 }
267
268 @tickets = ();
269