rt/t/mail/mime_decoding.t

   1 use strict;
   2 use warnings;
   3 use RT::Test nodb => 1, tests => 14;
   4
   5 use_ok('RT::I18N');
   6
   7 diag q{'=' char in a leading part before an encoded part};
   8 {
   9     my $str = 'key="plain"; key="=?UTF-8?B?0LzQvtC5X9GE0LDQudC7LmJpbg==?="';
  10     is(
  11         RT::I18N::DecodeMIMEWordsToUTF8($str),
  12         'key="plain"; key="мой_файл.bin"',
  13         "right decoding"
  14     );
  15 }
  16
  17 diag q{not compliant with standards, but MUAs send such field when attachment has non-ascii in name};
  18 {
  19     my $str = 'attachment; filename="=?UTF-8?B?0LzQvtC5X9GE0LDQudC7LmJpbg==?="';
  20     is(
  21         RT::I18N::DecodeMIMEWordsToUTF8($str),
  22         'attachment; filename="мой_файл.bin"',
  23         "right decoding"
  24     );
  25 }
  26
  27 diag q{'=' char in a trailing part after an encoded part};
  28 {
  29     my $str = 'attachment; filename="=?UTF-8?B?0LzQvtC5X9GE0LDQudC7LmJpbg==?="; some_prop="value"';
  30     is(
  31         RT::I18N::DecodeMIMEWordsToUTF8($str),
  32         'attachment; filename="мой_файл.bin"; some_prop="value"',
  33         "right decoding"
  34     );
  35 }
  36
  37 diag q{adding quotes around mime words containing specials when word is already quoted};
  38 {
  39     my $str = <<"END";
  40 Content-Disposition: attachment; filename="=?iso-8859-1?Q?foobar,_?=
  41  =?iso-8859-1?Q?barfoo.docx?="
  42 END
  43     my $decoded = 'Content-Disposition: attachment; filename="foobar, barfoo.docx"';
  44     is( RT::I18N::DecodeMIMEWordsToUTF8($str), $decoded, "No added quotes" );
  45 }
  46
  47 diag q{regression test for #5248 from rt3.fsck.com};
  48 {
  49     my $str = qq{Subject: =?ISO-8859-1?Q?Re=3A_=5BXXXXXX=23269=5D_=5BComment=5D_Frag?=}
  50         . qq{\n =?ISO-8859-1?Q?e_zu_XXXXXX--xxxxxx_/_Xxxxx=FCxxxxxxxxxx?=};
  51     is(
  52         RT::I18N::DecodeMIMEWordsToUTF8($str),
  53         qq{Subject: Re: [XXXXXX#269] [Comment] Frage zu XXXXXX--xxxxxx / Xxxxxüxxxxxxxxxx},
  54         "right decoding"
  55     );
  56 }
  57
  58 diag q{newline and encoded file name};
  59 {
  60     my $str = qq{application/vnd.ms-powerpoint;\n\tname="=?ISO-8859-1?Q?Main_presentation.ppt?="};
  61     is(
  62         RT::I18N::DecodeMIMEWordsToUTF8($str),
  63         qq{application/vnd.ms-powerpoint;\tname="Main presentation.ppt"},
  64         "right decoding"
  65     );
  66 }
  67
  68 diag q{rfc2231};
  69 {
  70     my $str =
  71 "attachment; filename*=ISO-8859-1''%74%E9%73%74%2E%74%78%74";
  72     is(
  73         RT::I18N::DecodeMIMEWordsToEncoding( $str, 'utf-8', 'Content-Disposition' ),
  74         'attachment; filename="tést.txt"',
  75         'right decoding'
  76     );
  77 }
  78
  79 diag q{rfc2231 param continuations};
  80 {
  81     # XXX TODO: test various forms of the continuation stuff
  82     #       quotes around the values
  83     my $hdr = <<'.';
  84 inline;
  85  filename*0*=ISO-2022-JP'ja'%1b$B%3f7$7$$%25F%25%2d%259%25H%1b%28B;
  86  filename*1*=%20;
  87  filename*2*=%1b$B%25I%25%2d%25e%25a%25s%25H%1b%28B;
  88  filename*3=.txt
  89 .
  90     is(
  91         RT::I18N::DecodeMIMEWordsToEncoding( $hdr, 'utf-8', 'Content-Disposition' ),
  92         'inline; filename="新しいテキスト ドキュメント.txt"',
  93         'decoded continuations as one string'
  94     );
  95 }
  96
  97 diag q{canonicalize mime word encodings like gb2312};
  98 {
  99     my $str = qq{Subject: =?gb2312?B?1NrKwL3nuPe12Lmy09CzrN9eX1NpbXBsaWZpZWRfQ05fR0IyMzEyYQ==?=
 100         =?gb2312?B?dHRhY2hlbWVudCB0ZXN0IGluIENOIHNpbXBsaWZpZWQ=?=};
 101
 102     is(
 103         RT::I18N::DecodeMIMEWordsToUTF8($str),
 104         qq{Subject: 在世界各地共有超過_Simplified_CN_GB2312attachement test in CN simplified},
 105         "right decoding"
 106     );
 107 }
 108
 109
 110 diag q{Whitespace between encoded words should be removed};
 111 {
 112     my $str = "=?utf-8?Q?=E3=82=AD?=    =?utf-8?Q?=E3=83=A3?=";
 113     is(
 114         RT::I18N::DecodeMIMEWordsToUTF8($str),
 115         "キャ",
 116         "whitespace between encoded words is removed",
 117     );
 118
 119     $str = "=?utf-8?Q?=E3=82=AD?=  \n   =?utf-8?Q?=E3=83=A3?=";
 120     is(
 121         RT::I18N::DecodeMIMEWordsToUTF8($str),
 122         "キャ",
 123         "newlines between encoded words also removed",
 124     );
 125 }
 126
 127 diag q{Multiple octets split across QP hunks are correctly reassembled};
 128 {
 129     # This passes even without explicit code to handle it because utf8
 130     # is perl's internal string encoding.
 131     my $str = "=?utf-8?Q?=E3?=    =?utf-8?Q?=82?=    =?utf-8?Q?=AD?=";
 132     is(
 133         RT::I18N::DecodeMIMEWordsToUTF8($str),
 134         "キ",
 135         "UTF8 character split in three is successfully reassembled",
 136     );
 137
 138     # Non-utf8 encodings thus also must be checked
 139     $str = <<EOT; chomp $str;
 140 =?gb2312?q?Chinese(gb2312)=20=20=C3=C0=B9=FA=C7=B0=CB=BE=B7=A8=B2=BF=B3?=
 141  =?gb2312?q?=A4=C3=E6=BC=FB=C8=F8=B4=EF=C4=B7=BA=F3=B3=C6=C6=E4=D7=B4=CC=AC?=
 142  =?gb2312?q?=BA=DC=BA=C3=20=20Chinese=20(gb2312)?=
 143 EOT
 144     is(
 145         RT::I18N::DecodeMIMEWordsToUTF8($str),
 146         "Chinese(gb2312)  美国前司法部长面见萨达姆后称其状态很好  Chinese (gb2312)",
 147         "gb2312 character is successfully reassembled",
 148     );
 149
 150 }