rt/sbin/standalone_httpd

   1 #!/usr/bin/perl -w
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 use warnings;
  50 use strict;
  51
  52 # fix lib paths, some may be relative
  53 BEGIN {
  54     die <<EOT if ${^TAINT};
  55 RT does not run under Perl's "taint mode".  Remove -T from the command
  56 line, or remove the PerlTaintCheck parameter from your mod_perl
  57 configuration.
  58 EOT
  59
  60     require File::Spec;
  61     my @libs = ("/opt/rt3/lib", "/opt/rt3/local/lib");
  62     my $bin_path;
  63
  64     for my $lib (@libs) {
  65         unless ( File::Spec->file_name_is_absolute($lib) ) {
  66             unless ($bin_path) {
  67                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
  68                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
  69                 }
  70                 else {
  71                     require FindBin;
  72                     no warnings "once";
  73                     $bin_path = $FindBin::Bin;
  74                 }
  75             }
  76             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
  77         }
  78         unshift @INC, $lib;
  79     }
  80
  81 }
  82
  83 use Getopt::Long;
  84 no warnings 'once';
  85
  86 if (grep { m/help/ } @ARGV) {
  87     require Pod::Usage;
  88     print Pod::Usage::pod2usage( { verbose => 2 } );
  89     exit;
  90 }
  91
  92 require RT;
  93 RT->LoadConfig();
  94 require Module::Refresh if RT->Config->Get('DevelMode');
  95
  96 require RT::Handle;
  97 my ($integrity, $state, $msg) = RT::Handle->CheckIntegrity;
  98
  99 unless ( $integrity ) {
 100     print STDERR <<EOF;
 101
 102 RT couldn't connect to the database where tickets are stored.
 103 If this is a new installation of RT, you should visit the URL below
 104 to configure RT and initialize your database.
 105
 106 If this is an existing RT installation, this may indicate a database
 107 connectivity problem.
 108
 109 The error RT got back when trying to connect to your database was:
 110
 111 $msg
 112
 113 EOF
 114
 115     require RT::Installer;
 116     # don't enter install mode if the file exists but is unwritable
 117     if (-e RT::Installer->ConfigFile && !-w _) {
 118         die 'Since your configuration exists ('
 119           . RT::Installer->ConfigFile
 120           . ") but is not writable, I'm refusing to do anything.\n";
 121     }
 122
 123     RT->Config->Set( 'LexiconLanguages' => '*' );
 124     RT::I18N->Init;
 125
 126     RT->InstallMode(1);
 127 } else {
 128     RT->Init();
 129
 130     my ($status, $msg) = RT::Handle->CheckCompatibility( $RT::Handle->dbh, 'post');
 131     unless ( $status ) {
 132         print STDERR $msg, "\n\n";
 133         exit -1;
 134     }
 135 }
 136
 137 # we must disconnect DB before fork
 138 if ($RT::Handle) {
 139     $RT::Handle->dbh(undef);
 140     undef $RT::Handle;
 141 }
 142
 143 require RT::Interface::Web::Handler;
 144 my $app = RT::Interface::Web::Handler->PSGIApp;
 145
 146 if ($ENV{RT_TESTING}) {
 147     my $screen_logger = $RT::Logger->remove('screen');
 148     require Log::Dispatch::Perl;
 149     $RT::Logger->add(
 150         Log::Dispatch::Perl->new(
 151             name      => 'rttest',
 152             min_level => $screen_logger->min_level,
 153             action    => {
 154                 error    => 'warn',
 155                 critical => 'warn'
 156             }
 157         )
 158     );
 159     require Plack::Middleware::Test::StashWarnings;
 160     $app = Plack::Middleware::Test::StashWarnings->wrap($app);
 161 }
 162
 163 # when used as a psgi file
 164 if (caller) {
 165     return $app;
 166 }
 167
 168
 169 # load appropriate server
 170
 171 require Plack::Runner;
 172
 173 my $is_fastcgi = $0 =~ m/fcgi$/;
 174 my $r = Plack::Runner->new( $0 =~ 'standalone' ? ( server => 'Standalone' ) :
 175                             $is_fastcgi        ? ( server => 'FCGI' )
 176                                                : (),
 177                             env => 'deployment' );
 178
 179 # figure out the port
 180 my $port;
 181
 182 # handle "rt-server 8888" for back-compat, but complain about it
 183 if ($ARGV[0] && $ARGV[0] =~ m/^\d+$/) {
 184     warn "Deprecated: please run $0 --port $ARGV[0] instead\n";
 185     unshift @ARGV, '--port';
 186 }
 187
 188 my @args = @ARGV;
 189
 190 use List::MoreUtils 'last_index';
 191 my $last_index = last_index { $_ eq '--port' } @args;
 192
 193 my $explicit_port;
 194
 195 if ( $last_index != -1 && $args[$last_index+1] =~ /^\d+$/ ) {
 196     $explicit_port = $args[$last_index+1];
 197     $port = $explicit_port;
 198
 199     # inform the rest of the system what port we manually chose
 200     my $old_app = $app;
 201     $app = sub {
 202         my $env = shift;
 203
 204         $env->{'rt.explicit_port'} = $port;
 205
 206         $old_app->($env, @_);
 207     };
 208 }
 209 else {
 210     # default to the configured WebPort and inform Plack::Runner
 211     $port = RT->Config->Get('WebPort') || '8080';
 212     push @args, '--port', $port;
 213 }
 214
 215 push @args, '--server', 'Standalone' if RT->InstallMode;
 216 push @args, '--server', 'Starlet' unless $r->{server} || grep { m/--server/ } @args;
 217
 218 $r->parse_options(@args);
 219
 220 delete $r->{options} if $is_fastcgi; ### mangle_host_port_socket ruins everything
 221
 222 unless ($r->{env} eq 'development') {
 223     push @{$r->{options}}, server_ready => sub {
 224         my($args) = @_;
 225         my $name  = $args->{server_software} || ref($args); # $args is $server
 226         my $host  = $args->{host} || 0;
 227         my $proto = $args->{proto} || 'http';
 228         print STDERR "$name: Accepting connections at $proto://$host:$args->{port}/\n";
 229     };
 230 }
 231 eval { $r->run($app) };
 232 if (my $err = $@) {
 233     handle_startup_error($err);
 234 }
 235
 236 exit 0;
 237
 238 sub handle_startup_error {
 239     my $err = shift;
 240     if ( $err =~ /listen/ ) {
 241         handle_bind_error();
 242     } else {
 243         die
 244             "Something went wrong while trying to run RT's standalone web server:\n\t"
 245             . $err;
 246     }
 247 }
 248
 249
 250 sub handle_bind_error {
 251
 252     print STDERR <<EOF;
 253 WARNING: RT couldn't start up a web server on port @{[$port]}.
 254 This is often the case if the port is already in use or you're running @{[$0]}
 255 as someone other than your system's "root" user.  You may also specify a
 256 temporary port with: $0 --port <port>
 257 EOF
 258
 259     if ($explicit_port) {
 260         print STDERR
 261             "Please check your system configuration or choose another port\n\n";
 262     }
 263 }
 264
 265 __END__
 266
 267 =head1 NAME
 268
 269 rt-server - RT standalone server
 270
 271 =head1 SYNOPSIS
 272
 273     # runs prefork server listening on port 8080, requires Starlet
 274     rt-server --port 8080
 275
 276     # runs server listening on port 8080
 277     rt-server --server Standalone --port 8080
 278     # or
 279     standalone_httpd --port 8080
 280
 281     # runs other PSGI server on port 8080
 282     rt-server --server Starman --port 8080