rt/sbin/rt-dump-metadata.in

   1 #!@PERL@ -w
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2013 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 use strict;
  50 use warnings;
  51
  52 # As we specify that XML is UTF-8 and we output it to STDOUT, we must be sure
  53 # it is UTF-8 so further XMLin will not break
  54 binmode( STDOUT, ":utf8" );
  55
  56 # fix lib paths, some may be relative
  57 BEGIN {
  58     require File::Spec;
  59     my @libs = ( "@RT_LIB_PATH@", "@LOCAL_LIB_PATH@" );
  60     my $bin_path;
  61
  62     for my $lib (@libs) {
  63         unless ( File::Spec->file_name_is_absolute($lib) ) {
  64             unless ($bin_path) {
  65                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
  66                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
  67                 } else {
  68                     require FindBin;
  69                     no warnings "once";
  70                     $bin_path = $FindBin::Bin;
  71                 }
  72             }
  73             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
  74         }
  75         unshift @INC, $lib;
  76     }
  77
  78 }
  79
  80 use Getopt::Long;
  81 my %opt;
  82 GetOptions( \%opt, "help|h" );
  83
  84 if ( $opt{help} ) {
  85     require Pod::Usage;
  86     Pod::Usage::pod2usage( { verbose => 2 } );
  87     exit;
  88 }
  89
  90 require RT;
  91 require XML::Simple;
  92
  93 RT::LoadConfig();
  94 RT::Init();
  95
  96 my $LocalOnly = @ARGV ? shift(@ARGV) : 1;
  97
  98 my %RV;
  99 my %Ignore = (
 100     All => [
 101         qw(
 102             id Created Creator LastUpdated LastUpdatedBy
 103             )
 104            ],
 105     Templates => [
 106         qw(
 107             TranslationOf
 108             )
 109     ],
 110 );
 111
 112 my $SystemUserId = RT->SystemUser->Id;
 113 my @classes      = qw(
 114     Users Groups Queues ScripActions ScripConditions
 115     Templates Scrips ACL CustomFields
 116     );
 117 foreach my $class (@classes) {
 118     require "RT/$class.pm";
 119     my $objects = "RT::$class"->new( RT->SystemUser );
 120     $objects->{find_disabled_rows} = 1;
 121     $objects->UnLimit;
 122
 123     if ( $class eq 'CustomFields' ) {
 124         $objects->OrderByCols(
 125             { FIELD => 'LookupType' },
 126             { FIELD => 'SortOrder' },
 127             { FIELD => 'Id' },
 128         );
 129     } else {
 130         $objects->OrderBy( FIELD => 'Id' );
 131     }
 132
 133     if ($LocalOnly) {
 134         next if $class eq 'ACL';    # XXX - would go into infinite loop - XXX
 135         $objects->Limit(
 136             FIELD    => 'LastUpdatedBy',
 137             OPERATOR => '!=',
 138             VALUE    => $SystemUserId
 139         ) unless $class eq 'Groups';
 140         $objects->Limit(
 141             FIELD    => 'Id',
 142             OPERATOR => '!=',
 143             VALUE    => $SystemUserId
 144         ) if $class eq 'Users';
 145         $objects->Limit(
 146             FIELD    => 'Domain',
 147             OPERATOR => '=',
 148             VALUE    => 'UserDefined'
 149         ) if $class eq 'Groups';
 150     }
 151
 152     my %fields;
 153     while ( my $obj = $objects->Next ) {
 154         next
 155             if $obj->can('LastUpdatedBy')
 156                 and $obj->LastUpdatedBy == $SystemUserId;
 157
 158         if ( !%fields ) {
 159             %fields = map { $_ => 1 } keys %{ $obj->_ClassAccessible };
 160             delete @fields{ @{ $Ignore{$class} ||= [] },
 161                 @{ $Ignore{All} ||= [] }, };
 162         }
 163
 164         my $rv;
 165
 166         # next if $obj-> # skip default names
 167         foreach my $field ( sort keys %fields ) {
 168             my $value = $obj->__Value($field);
 169             $rv->{$field} = $value if ( defined($value) && length($value) );
 170         }
 171         delete $rv->{Disabled} unless $rv->{Disabled};
 172
 173         foreach my $record ( map { /ACL/ ? 'ACE' : substr( $_, 0, -1 ) }
 174             @classes )
 175         {
 176             foreach my $key ( map "$record$_", ( '', 'Id' ) ) {
 177                 next unless exists $rv->{$key};
 178                 my $id = $rv->{$key} or next;
 179                 my $obj = "RT::$record"->new( RT->SystemUser );
 180                 $obj->LoadByCols( Id => $id ) or next;
 181                 $rv->{$key} = $obj->__Value('Name') || 0;
 182             }
 183         }
 184
 185         if ( $class eq 'Users' and defined $obj->Privileged ) {
 186             $rv->{Privileged} = int( $obj->Privileged );
 187         } elsif ( $class eq 'CustomFields' ) {
 188             my $values = $obj->Values;
 189             while ( my $value = $values->Next ) {
 190                 push @{ $rv->{Values} }, {
 191                     map { ( $_ => $value->__Value($_) ) }
 192                         qw(
 193                         Name Description SortOrder
 194                         ),
 195                 };
 196             }
 197         }
 198
 199         if ( eval { require RT::Attributes; 1 } ) {
 200             my $attributes = $obj->Attributes;
 201             while ( my $attribute = $attributes->Next ) {
 202                 my $content = $attribute->Content;
 203                 $rv->{Attributes}{ $attribute->Name } = $content
 204                     if length($content);
 205             }
 206         }
 207
 208         push @{ $RV{$class} }, $rv;
 209     }
 210 }
 211
 212 print(<< ".");
 213 no strict; use XML::Simple; *_ = XMLin(do { local \$/; readline(DATA) }, ForceArray => [qw(
 214  @classes Values
 215 )], NoAttr => 1, SuppressEmpty => ''); *\$_ = (\$_{\$_} || []) for keys \%_; 1; # vim: ft=xml
 216 __DATA__
 217 .
 218
 219 print XML::Simple::XMLout(
 220     { map { ( $_ => ( $RV{$_} || [] ) ) } @classes },
 221     RootName      => 'InitialData',
 222     NoAttr        => 1,
 223     SuppressEmpty => '',
 224     XMLDecl       => '<?xml version="1.0" encoding="UTF-8"?>',
 225 );
 226
 227 __END__
 228
 229 =head1 NAME
 230
 231 rt-dump-metadata - dump configuration metadata from an RT database
 232
 233 =head1 SYNOPSIS
 234
 235     rt-dump-metdata [ 0 ]
 236
 237 =head1 DESCRIPTION
 238
 239 C<rt-dump-metadata> is a tool that dumps configuration metadata from the
 240 Request Tracker database into XML format, suitable for feeding into
 241 C<rt-setup-database>. To dump and load a full RT database, you should generally
 242 use the native database tools instead, as well as performing any necessary
 243 steps from UPGRADING.
 244
 245 When run without arguments, the metadata dump will only include 'local'
 246 configuration changes, i.e. those done manually in the web interface.
 247
 248 When run with the argument '0', the dump will include all configuration
 249 metadata.
 250
 251 This is NOT a tool for backing up an RT database.
 252