rt/sbin/rt-dump-database

   1 #!/usr/bin/perl -w
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2009 Best Practical Solutions, LLC
   7 #                                          <jesse@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 use strict;
  50
  51 # fix lib paths, some may be relative
  52 BEGIN {
  53     require File::Spec;
  54     my @libs = ("lib", "local/lib");
  55     my $bin_path;
  56
  57     for my $lib (@libs) {
  58         unless ( File::Spec->file_name_is_absolute($lib) ) {
  59             unless ($bin_path) {
  60                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
  61                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
  62                 }
  63                 else {
  64                     require FindBin;
  65                     no warnings "once";
  66                     $bin_path = $FindBin::Bin;
  67                 }
  68             }
  69             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
  70         }
  71         unshift @INC, $lib;
  72     }
  73
  74 }
  75
  76 use RT;
  77 use XML::Simple;
  78
  79 RT::LoadConfig();
  80 RT::Init();
  81
  82 my $LocalOnly = @ARGV ? shift(@ARGV) : 1;
  83
  84 my %RV;
  85 my %Ignore = (
  86     All => [qw(
  87         id Created Creator LastUpdated LastUpdatedBy
  88     )],
  89     Templates => [qw(
  90         TranslationOf
  91     )],
  92 );
  93
  94 my $SystemUserId = $RT::SystemUser->Id;
  95 my @classes = qw(
  96     Users Groups Queues ScripActions ScripConditions
  97     Templates Scrips ACL CustomFields
  98 );
  99 foreach my $class (@classes) {
 100     require "RT/$class.pm";
 101     my $objects = "RT::$class"->new($RT::SystemUser);
 102     $objects->{find_disabled_rows} = 1;
 103     $objects->UnLimit;
 104
 105     if ($class eq 'CustomFields') {
 106         $objects->OrderByCols(
 107             { FIELD => 'LookupType' },
 108             { FIELD => 'SortOrder' },
 109             { FIELD => 'Id' },
 110         );
 111     }
 112     else {
 113         $objects->OrderBy( FIELD => 'Id' );
 114     }
 115
 116     if ($LocalOnly) {
 117         next if $class eq 'ACL'; # XXX - would go into infinite loop - XXX
 118         $objects->Limit( FIELD => 'LastUpdatedBy', OPERATOR => '!=', VALUE => $SystemUserId )
 119             unless $class eq 'Groups';
 120         $objects->Limit( FIELD => 'Id', OPERATOR => '!=', VALUE => $SystemUserId )
 121             if $class eq 'Users';
 122         $objects->Limit( FIELD => 'Domain', OPERATOR => '=', VALUE => 'UserDefined' )
 123             if $class eq 'Groups';
 124     }
 125
 126     my %fields;
 127     while (my $obj = $objects->Next) {
 128         next if $obj->can('LastUpdatedBy') and $obj->LastUpdatedBy == $SystemUserId;
 129
 130         if (!%fields) {
 131             %fields = map { $_ => 1 } keys %{$obj->_ClassAccessible};
 132             delete @fields{
 133                 @{$Ignore{$class}||=[]},
 134                 @{$Ignore{All}||=[]},
 135             };
 136         }
 137
 138         my $rv;
 139         # next if $obj-> # skip default names
 140         foreach my $field (sort keys %fields) {
 141             my $value = $obj->__Value($field);
 142             $rv->{$field} = $value if ( defined ($value) && length($value) );
 143         }
 144         delete $rv->{Disabled} unless $rv->{Disabled};
 145
 146         foreach my $record (map { /ACL/ ? 'ACE' : substr($_, 0, -1) } @classes) {
 147             foreach my $key (map "$record$_", ('', 'Id')) {
 148                 next unless exists $rv->{$key};
 149                 my $id = $rv->{$key} or next;
 150                 my $obj = "RT::$record"->new($RT::SystemUser);
 151                 $obj->LoadByCols( Id => $id ) or next;
 152                 $rv->{$key} = $obj->__Value('Name') || 0;
 153             }
 154         }
 155
 156         if ($class eq 'Users' and defined $obj->Privileged) {
 157             $rv->{Privileged} = int($obj->Privileged);
 158         }
 159         elsif ($class eq 'CustomFields') {
 160             my $values = $obj->Values;
 161             while (my $value = $values->Next) {
 162                 push @{$rv->{Values}}, {
 163                     map { ($_ => $value->__Value($_)) } qw(
 164                         Name Description SortOrder
 165                     ),
 166                 };
 167             }
 168         }
 169
 170         if (eval { require RT::Attributes; 1 }) {
 171             my $attributes = $obj->Attributes;
 172             while (my $attribute = $attributes->Next) {
 173                 my $content = $attribute->Content;
 174                 $rv->{Attributes}{$attribute->Name} = $content if length($content);
 175             }
 176         }
 177
 178         push @{$RV{$class}}, $rv;
 179     }
 180 }
 181
 182 print(<< ".");
 183 no strict; use XML::Simple; *_ = XMLin(do { local \$/; readline(DATA) }, ForceArray => [qw(
 184  @classes Values
 185 )], NoAttr => 1, SuppressEmpty => ''); *\$_ = (\$_{\$_} || []) for keys \%_; 1; # vim: ft=xml
 186 __DATA__
 187 .
 188
 189 print XMLout(
 190     { map { ($_ => ($RV{$_} || [])) } @classes },
 191     RootName => 'InitialData',
 192     NoAttr => 1,
 193     SuppressEmpty => '',
 194     XMLDecl => '<?xml version="1.0" encoding="UTF-8"?>',
 195 );