rt/lib/RT/Shredder/Record.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2015 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 package RT::Record;
  50 use RT::Record ();
  51
  52 use strict;
  53 use warnings;
  54 use warnings FATAL => 'redefine';
  55
  56 use RT::Shredder::Constants;
  57 use RT::Shredder::Exceptions;
  58
  59 =head2 _AsInsertQuery
  60
  61 Returns INSERT query string that duplicates current record and
  62 can be used to insert record back into DB after delete.
  63
  64 =cut
  65
  66 sub _AsInsertQuery
  67 {
  68     my $self = shift;
  69
  70     my $dbh = $RT::Handle->dbh;
  71
  72     my $res = "INSERT INTO ". $dbh->quote_identifier( $self->Table );
  73     my $values = $self->{'values'};
  74     $res .= "(". join( ",", map { $dbh->quote_identifier( $_ ) } sort keys %$values ) .")";
  75     $res .= " VALUES";
  76     $res .= "(". join( ",", map { $dbh->quote( $values->{$_} ) } sort keys %$values ) .")";
  77     $res .= ";";
  78
  79     return $res;
  80 }
  81
  82 sub BeforeWipeout { return 1 }
  83
  84 =head2 Dependencies
  85
  86 Returns L<RT::Shredder::Dependencies> object.
  87
  88 =cut
  89
  90 sub Dependencies
  91 {
  92     my $self = shift;
  93     my %args = (
  94             Shredder => undef,
  95             Flags => RT::Shredder::Constants::DEPENDS_ON,
  96             @_,
  97            );
  98
  99     unless( $self->id ) {
 100         RT::Shredder::Exception->throw('Object is not loaded');
 101     }
 102
 103     my $deps = RT::Shredder::Dependencies->new();
 104     if( $args{'Flags'} & RT::Shredder::Constants::DEPENDS_ON ) {
 105         $self->__DependsOn( %args, Dependencies => $deps );
 106     }
 107     return $deps;
 108 }
 109
 110 sub __DependsOn
 111 {
 112     my $self = shift;
 113     my %args = (
 114             Shredder => undef,
 115             Dependencies => undef,
 116             @_,
 117            );
 118     my $deps = $args{'Dependencies'};
 119     my $list = [];
 120
 121 # Object custom field values
 122     my $objs = $self->CustomFieldValues;
 123     $objs->{'find_expired_rows'} = 1;
 124     push( @$list, $objs );
 125
 126 # Object attributes
 127     $objs = $self->Attributes;
 128     push( @$list, $objs );
 129
 130 # Transactions
 131     $objs = RT::Transactions->new( $self->CurrentUser );
 132     $objs->Limit( FIELD => 'ObjectType', VALUE => ref $self );
 133     $objs->Limit( FIELD => 'ObjectId', VALUE => $self->id );
 134     push( @$list, $objs );
 135
 136 # Links
 137     if ( $self->can('Links') ) {
 138         # make sure we don't skip any record
 139         no warnings 'redefine';
 140         local *RT::Links::IsValidLink = sub { 1 };
 141
 142         foreach ( qw(Base Target) ) {
 143             my $objs = $self->Links( $_ );
 144             $objs->_DoSearch;
 145             push @$list, $objs->ItemsArrayRef;
 146         }
 147     }
 148
 149 # ACE records
 150     $objs = RT::ACL->new( $self->CurrentUser );
 151     $objs->LimitToObject( $self );
 152     push( @$list, $objs );
 153
 154     $deps->_PushDependencies(
 155             BaseObject => $self,
 156             Flags => RT::Shredder::Constants::DEPENDS_ON,
 157             TargetObjects => $list,
 158             Shredder => $args{'Shredder'}
 159         );
 160     return;
 161 }
 162
 163 # implement proxy method because some RT classes
 164 # override Delete method
 165 sub __Wipeout
 166 {
 167     my $self = shift;
 168     my $msg = $self->UID ." wiped out";
 169     $self->SUPER::Delete;
 170     $RT::Logger->info( $msg );
 171     return;
 172 }
 173
 174 1;