rt/lib/RT/Reminders.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 package RT::Reminders;
  50
  51 use strict;
  52 use warnings;
  53
  54 use base 'RT::Base';
  55
  56 sub new {
  57     my $class = shift;
  58     my $self = {};
  59     bless $self, $class;
  60     $self->CurrentUser(@_);
  61     return($self);
  62 }
  63
  64 sub Ticket {
  65     my $self = shift;
  66     $self->{'_ticket'} = shift if (@_);
  67     return ($self->{'_ticket'});
  68 }
  69
  70 sub TicketObj {
  71     my $self = shift;
  72     unless ($self->{'_ticketobj'}) {
  73         $self->{'_ticketobj'} = RT::Ticket->new($self->CurrentUser);
  74         $self->{'_ticketobj'}->Load($self->Ticket);
  75     }
  76     return $self->{'_ticketobj'};
  77 }
  78
  79 =head2 Collection
  80
  81 Returns an RT::Tickets object containing reminders for this object's "Ticket"
  82
  83 =cut
  84
  85 sub Collection {
  86     my $self = shift;
  87     my $col = RT::Tickets->new($self->CurrentUser);
  88
  89     my $query = 'Type = "reminder" AND RefersTo = "'.$self->Ticket.'"';
  90
  91     $col->FromSQL($query);
  92
  93     $col->OrderBy( FIELD => 'Due' );
  94
  95     return($col);
  96 }
  97
  98 =head2 Add
  99
 100 Add a reminder for this ticket.
 101
 102 Takes
 103
 104     Subject
 105     Owner
 106     Due
 107
 108 =cut
 109
 110 sub Add {
 111     my $self = shift;
 112     my %args = (
 113         Subject => undef,
 114         Owner => undef,
 115         Due => undef,
 116         @_
 117     );
 118
 119     my $reminder = RT::Ticket->new($self->CurrentUser);
 120     my ( $status, $msg ) = $reminder->Create(
 121         Subject => $args{'Subject'},
 122         Owner => $args{'Owner'},
 123         Due => $args{'Due'},
 124         RefersTo => $self->Ticket,
 125         Type => 'reminder',
 126         Queue => $self->TicketObj->Queue,
 127     );
 128     $self->TicketObj->_NewTransaction(
 129         Type => 'AddReminder',
 130         Field => 'RT::Ticket',
 131         NewValue => $reminder->id
 132     ) if $status;
 133     return ( $status, $msg );
 134 }
 135
 136 sub Open {
 137     my $self = shift;
 138     my $reminder = shift;
 139
 140     my ( $status, $msg ) =
 141       $reminder->SetStatus( $reminder->QueueObj->Lifecycle->ReminderStatusOnOpen );
 142     $self->TicketObj->_NewTransaction(
 143         Type => 'OpenReminder',
 144         Field => 'RT::Ticket',
 145         NewValue => $reminder->id
 146     ) if $status;
 147     return ( $status, $msg );
 148 }
 149
 150 sub Resolve {
 151     my $self = shift;
 152     my $reminder = shift;
 153     my ( $status, $msg ) =
 154       $reminder->SetStatus( $reminder->QueueObj->Lifecycle->ReminderStatusOnResolve );
 155     $self->TicketObj->_NewTransaction(
 156         Type => 'ResolveReminder',
 157         Field => 'RT::Ticket',
 158         NewValue => $reminder->id
 159     ) if $status;
 160     return ( $status, $msg );
 161 }
 162
 163 RT::Base->_ImportOverlays();
 164
 165 1;