rt/lib/RT/Interface/REST.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2009 Best Practical Solutions, LLC
   6 #                                          <jesse@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48 # lib/RT/Interface/REST.pm
  49 #
  50
  51 package RT::Interface::REST;
  52 use strict;
  53 use RT;
  54
  55 BEGIN {
  56     use Exporter ();
  57     use vars qw($VERSION @ISA @EXPORT);
  58
  59     $VERSION = do { my @r = (q$Revision: 1.1.1.7 $ =~ /\d+/g); sprintf "%d."."%02d"x$#r, @r };
  60
  61     @ISA = qw(Exporter);
  62     @EXPORT = qw(expand_list form_parse form_compose vpush vsplit);
  63 }
  64
  65 my $field = '(?i:[a-z][a-z0-9_-]*|C(?:ustom)?F(?:ield)?-(?:[a-z0-9_ -]|\s)+)';
  66
  67 # WARN: this code is duplicated in bin/rt.in,
  68 # change both functions at once
  69 sub expand_list {
  70     my ($list) = @_;
  71
  72     my @elts;
  73     foreach (split /,/, $list) {
  74         push @elts, /^(\d+)-(\d+)$/? ($1..$2): $_;
  75     }
  76
  77     return map $_->[0], # schwartzian transform
  78         sort {
  79             defined $a->[1] && defined $b->[1]?
  80                 # both numbers
  81                 $a->[1] <=> $b->[1]
  82                 :!defined $a->[1] && !defined $b->[1]?
  83                     # both letters
  84                     $a->[2] cmp $b->[2]
  85                     # mix, number must be first
  86                     :defined $a->[1]? -1: 1
  87         }
  88         map [ $_, (defined( /^(\d+)$/ )? $1: undef), lc($_) ],
  89         @elts;
  90 }
  91
  92 # Returns a reference to an array of parsed forms.
  93 sub form_parse {
  94     my $state = 0;
  95     my @forms = ();
  96     my @lines = split /\n/, $_[0];
  97     my ($c, $o, $k, $e) = ("", [], {}, "");
  98
  99     LINE:
 100     while (@lines) {
 101         my $line = shift @lines;
 102
 103         next LINE if $line eq '';
 104
 105         if ($line eq '--') {
 106             # We reached the end of one form. We'll ignore it if it was
 107             # empty, and store it otherwise, errors and all.
 108             if ($e || $c || @$o) {
 109                 push @forms, [ $c, $o, $k, $e ];
 110                 $c = ""; $o = []; $k = {}; $e = "";
 111             }
 112             $state = 0;
 113         }
 114         elsif ($state != -1) {
 115             if ($state == 0 && $line =~ /^#/) {
 116                 # Read an optional block of comments (only) at the start
 117                 # of the form.
 118                 $state = 1;
 119                 $c = $line;
 120                 while (@lines && $lines[0] =~ /^#/) {
 121                     $c .= "\n".shift @lines;
 122                 }
 123                 $c .= "\n";
 124             }
 125             elsif ($state <= 1 && $line =~ /^($field):(?:\s+(.*))?$/i) {
 126                 # Read a field: value specification.
 127                 my $f  = $1;
 128                 my @v  = ($2);
 129                 $v[0] = '' unless defined $v[0];
 130
 131                 # Read continuation lines, if any.
 132                 while (@lines && ($lines[0] eq '' || $lines[0] =~ /^\s+/)) {
 133                     push @v, shift @lines;
 134                 }
 135                 pop @v while (@v && $v[-1] eq '');
 136
 137                 # Strip longest common leading indent from text.
 138                 my ($ws, $ls) = ("");
 139                 foreach $ls (map {/^(\s+)/} @v[1..$#v]) {
 140                     $ws = $ls if (!$ws || length($ls) < length($ws));
 141                 }
 142                 s/^$ws// foreach @v;
 143
 144                 shift @v while (@v && $v[0] eq '');
 145
 146                 push(@$o, $f) unless exists $k->{$f};
 147                 vpush($k, $f, join("\n", @v));
 148
 149                 $state = 1;
 150             }
 151             elsif ($line !~ /^#/) {
 152                 # We've found a syntax error, so we'll reconstruct the
 153                 # form parsed thus far, and add an error marker. (>>)
 154                 $state = -1;
 155                 $e = form_compose([[ "", $o, $k, "" ]]);
 156                 $e.= $line =~ /^>>/ ? "$line\n" : ">> $line\n";
 157             }
 158         }
 159         else {
 160             # We saw a syntax error earlier, so we'll accumulate the
 161             # contents of this form until the end.
 162             $e .= "$line\n";
 163         }
 164     }
 165     push(@forms, [ $c, $o, $k, $e ]) if ($e || $c || @$o);
 166
 167     my $l;
 168     foreach $l (keys %$k) {
 169         $k->{$l} = vsplit($k->{$l}) if (ref $k->{$l} eq 'ARRAY');
 170     }
 171
 172     return \@forms;
 173 }
 174
 175 # Returns text representing a set of forms.
 176 sub form_compose {
 177     my ($forms) = @_;
 178     my (@text, $form);
 179
 180     foreach $form (@$forms) {
 181         my ($c, $o, $k, $e) = @$form;
 182         my $text = "";
 183
 184         if ($c) {
 185             $c =~ s/\n*$/\n/;
 186             $text = "$c\n";
 187         }
 188         if ($e) {
 189             $text .= $e;
 190         }
 191         elsif ($o) {
 192             my (@lines, $key);
 193
 194             foreach $key (@$o) {
 195                 my ($line, $sp, $v);
 196                 my @values = (ref $k->{$key} eq 'ARRAY') ?
 197                                @{ $k->{$key} } :
 198                                   $k->{$key};
 199
 200                 $sp = " "x(length("$key: "));
 201                 $sp = " "x4 if length($sp) > 16;
 202
 203                 foreach $v (@values) {
 204                     if ($v =~ /\n/) {
 205                         $v =~ s/^/$sp/gm;
 206                         $v =~ s/^$sp//;
 207
 208                         if ($line) {
 209                             push @lines, "$line\n\n";
 210                             $line = "";
 211                         }
 212                         elsif (@lines && $lines[-1] !~ /\n\n$/) {
 213                             $lines[-1] .= "\n";
 214                         }
 215                         push @lines, "$key: $v\n\n";
 216                     }
 217                     elsif ($line &&
 218                            length($line)+length($v)-rindex($line, "\n") >= 70)
 219                     {
 220                         $line .= ",\n$sp$v";
 221                     }
 222                     else {
 223                         $line = $line ? "$line, $v" : "$key: $v";
 224                     }
 225                 }
 226
 227                 $line = "$key:" unless @values;
 228                 if ($line) {
 229                     if ($line =~ /\n/) {
 230                         if (@lines && $lines[-1] !~ /\n\n$/) {
 231                             $lines[-1] .= "\n";
 232                         }
 233                         $line .= "\n";
 234                     }
 235                     push @lines, "$line\n";
 236                 }
 237             }
 238
 239             $text .= join "", @lines;
 240         }
 241         else {
 242             chomp $text;
 243         }
 244         push @text, $text;
 245     }
 246
 247     return join "\n--\n\n", @text;
 248 }
 249
 250 # Add a value to a (possibly multi-valued) hash key.
 251 sub vpush {
 252     my ($hash, $key, $val) = @_;
 253     my @val = ref $val eq 'ARRAY' ? @$val : $val;
 254
 255     if (exists $hash->{$key}) {
 256         unless (ref $hash->{$key} eq 'ARRAY') {
 257             my @v = $hash->{$key} ne '' ? $hash->{$key} : ();
 258             $hash->{$key} = \@v;
 259         }
 260         push @{ $hash->{$key} }, @val;
 261     }
 262     else {
 263         $hash->{$key} = $val;
 264     }
 265 }
 266
 267 # "Normalise" a hash key that's known to be multi-valued.
 268 sub vsplit {
 269     my ($val) = @_;
 270     my ($line, $word, @words);
 271
 272     foreach $line (map {split /\n/} (ref $val eq 'ARRAY') ? @$val : $val)
 273     {
 274         # XXX: This should become a real parser, à la Text::ParseWords.
 275         $line =~ s/^\s+//;
 276         $line =~ s/\s+$//;
 277         push @words, split /\s*,\s*/, $line;
 278     }
 279
 280     return \@words;
 281 }
 282
 283 1;
 284
 285 =head1 NAME
 286
 287   RT::Interface::REST - helper functions for the REST interface.
 288
 289 =head1 SYNOPSIS
 290
 291   Only the REST should use this module.