rt/lib/RT/Date.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2011 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 =head1 NAME
  50
  51   RT::Date - a simple Object Oriented date.
  52
  53 =head1 SYNOPSIS
  54
  55   use RT::Date
  56
  57 =head1 DESCRIPTION
  58
  59 RT Date is a simple Date Object designed to be speedy and easy for RT to use
  60
  61 The fact that it assumes that a time of 0 means "never" is probably a bug.
  62
  63
  64 =head1 METHODS
  65
  66 =cut
  67
  68
  69 package RT::Date;
  70
  71 use Time::Local;
  72 use POSIX qw(tzset);
  73
  74 use strict;
  75 use warnings;
  76 use base qw/RT::Base/;
  77
  78 use vars qw($MINUTE $HOUR $DAY $WEEK $MONTH $YEAR);
  79
  80 $MINUTE = 60;
  81 $HOUR   = 60 * $MINUTE;
  82 $DAY    = 24 * $HOUR;
  83 $WEEK   = 7 * $DAY;
  84 $MONTH  = 30.4375 * $DAY;
  85 $YEAR   = 365.25 * $DAY;
  86
  87 our @MONTHS = (
  88     'Jan', # loc
  89     'Feb', # loc
  90     'Mar', # loc
  91     'Apr', # loc
  92     'May', # loc
  93     'Jun', # loc
  94     'Jul', # loc
  95     'Aug', # loc
  96     'Sep', # loc
  97     'Oct', # loc
  98     'Nov', # loc
  99     'Dec', # loc
 100 );
 101
 102 our @DAYS_OF_WEEK = (
 103     'Sun', # loc
 104     'Mon', # loc
 105     'Tue', # loc
 106     'Wed', # loc
 107     'Thu', # loc
 108     'Fri', # loc
 109     'Sat', # loc
 110 );
 111
 112 our @FORMATTERS = (
 113     'DefaultFormat', # loc
 114     'ISO',           # loc
 115     'W3CDTF',        # loc
 116     'RFC2822',       # loc
 117     'RFC2616',       # loc
 118     'iCal',          # loc
 119 );
 120 if ( eval 'use DateTime qw(); 1;' && eval 'use DateTime::Locale qw(); 1;' &&
 121      DateTime->can('format_cldr') && DateTime::Locale::root->can('date_format_full') ) {
 122     push @FORMATTERS, 'LocalizedDateTime'; # loc
 123 }
 124
 125 =head2 new
 126
 127 Object constructor takes one argument C<RT::CurrentUser> object.
 128
 129 =cut
 130
 131 sub new {
 132     my $proto = shift;
 133     my $class = ref($proto) || $proto;
 134     my $self  = {};
 135     bless ($self, $class);
 136     $self->CurrentUser(@_);
 137     $self->Unix(0);
 138     return $self;
 139 }
 140
 141 =head2 Set
 142
 143 Takes a param hash with the fields C<Format>, C<Value> and C<Timezone>.
 144
 145 If $args->{'Format'} is 'unix', takes the number of seconds since the epoch.
 146
 147 If $args->{'Format'} is ISO, tries to parse an ISO date.
 148
 149 If $args->{'Format'} is 'unknown', require Time::ParseDate and make it figure
 150 things out. This is a heavyweight operation that should never be called from
 151 within RT's core. But it's really useful for something like the textbox date
 152 entry where we let the user do whatever they want.
 153
 154 If $args->{'Value'} is 0, assumes you mean never.
 155
 156 =cut
 157
 158 sub Set {
 159     my $self = shift;
 160     my %args = (
 161         Format   => 'unix',
 162         Value    => time,
 163         Timezone => 'user',
 164         @_
 165     );
 166
 167     return $self->Unix(0) unless $args{'Value'};
 168
 169     if ( $args{'Format'} =~ /^unix$/i ) {
 170         return $self->Unix( $args{'Value'} );
 171     }
 172     elsif ( $args{'Format'} =~ /^(sql|datemanip|iso)$/i ) {
 173         $args{'Value'} =~ s!/!-!g;
 174
 175         if (   ( $args{'Value'} =~ /^(\d{4})?(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)$/ )
 176             || ( $args{'Value'} =~ /^(\d{4})?(\d\d)(\d\d)(\d\d):(\d\d):(\d\d)$/ )
 177             || ( $args{'Value'} =~ /^(?:(\d{4})-)?(\d\d)-(\d\d) (\d\d):(\d\d):(\d\d)$/ )
 178             || ( $args{'Value'} =~ /^(?:(\d{4})-)?(\d\d)-(\d\d) (\d\d):(\d\d):(\d\d)\+00$/ )
 179           ) {
 180
 181             my ($year, $mon, $mday, $hours, $min, $sec)  = ($1, $2, $3, $4, $5, $6);
 182
 183             # use current year if string has no value
 184             $year ||= (localtime time)[5] + 1900;
 185
 186             #timegm expects month as 0->11
 187             $mon--;
 188
 189             #now that we've parsed it, deal with the case where everything was 0
 190             return $self->Unix(0) if $mon < 0 || $mon > 11;
 191
 192             my $tz = lc $args{'Format'} eq 'datemanip'? 'user': 'utc';
 193             $self->Unix( $self->Timelocal( $tz, $sec, $min, $hours, $mday, $mon, $year ) );
 194
 195             $self->Unix(0) unless $self->Unix > 0;
 196         }
 197         else {
 198             $RT::Logger->warning(
 199                 "Couldn't parse date '$args{'Value'}' as a $args{'Format'} format"
 200             );
 201             return $self->Unix(0);
 202         }
 203     }
 204     elsif ( $args{'Format'} =~ /^unknown$/i ) {
 205         require Time::ParseDate;
 206         # the module supports only legacy timezones like PDT or EST...
 207         # so we parse date as GMT and later apply offset, this only
 208         # should be applied to absolute times, so compensate shift in NOW
 209         my $now = time;
 210         $now += ($self->Localtime( $args{Timezone}, $now ))[9];
 211         my $date = Time::ParseDate::parsedate(
 212             $args{'Value'},
 213             GMT           => 1,
 214             NOW           => $now,
 215             UK            => RT->Config->Get('DateDayBeforeMonth'),
 216             PREFER_PAST   => RT->Config->Get('AmbiguousDayInPast'),
 217             PREFER_FUTURE => RT->Config->Get('AmbiguousDayInFuture'),
 218         );
 219         # apply timezone offset
 220         $date -= ($self->Localtime( $args{Timezone}, $date ))[9];
 221
 222         $RT::Logger->debug(
 223             "RT::Date used Time::ParseDate to make '$args{'Value'}' $date\n"
 224         );
 225
 226         return $self->Set( Format => 'unix', Value => $date);
 227     }
 228     else {
 229         $RT::Logger->error(
 230             "Unknown Date format: $args{'Format'}\n"
 231         );
 232         return $self->Unix(0);
 233     }
 234
 235     return $self->Unix;
 236 }
 237
 238 =head2 SetToNow
 239
 240 Set the object's time to the current time. Takes no arguments
 241 and returns unix time.
 242
 243 =cut
 244
 245 sub SetToNow {
 246     return $_[0]->Unix(time);
 247 }
 248
 249 =head2 SetToMidnight [Timezone => 'utc']
 250
 251 Sets the date to midnight (at the beginning of the day).
 252 Returns the unixtime at midnight.
 253
 254 Arguments:
 255
 256 =over 4
 257
 258 =item Timezone
 259
 260 Timezone context C<user>, C<server> or C<UTC>. See also L</Timezone>.
 261
 262 =back
 263
 264 =cut
 265
 266 sub SetToMidnight {
 267     my $self = shift;
 268     my %args = ( Timezone => '', @_ );
 269     my $new = $self->Timelocal(
 270         $args{'Timezone'},
 271         0,0,0,($self->Localtime( $args{'Timezone'} ))[3..9]
 272     );
 273     return $self->Unix( $new );
 274 }
 275
 276 =head2 SetToStart PERIOD[, Timezone => 'utc' ]
 277
 278 Set to the beginning of the current PERIOD, which can be
 279 "year", "month", "day", "hour", or "minute".
 280
 281 =cut
 282
 283 sub SetToStart {
 284     my $self = shift;
 285     my $p = uc(shift);
 286     my %args = @_;
 287     my $tz = $args{'Timezone'} || '';
 288     my @localtime = $self->Localtime($tz);
 289     #remove 'offset' so that DST is figured based on the resulting time.
 290     pop @localtime;
 291
 292     # This is the cleanest way to implement it, I swear.
 293     {
 294         $localtime[0]=0;
 295         last if ($p eq 'MINUTE');
 296         $localtime[1]=0;
 297         last if ($p eq 'HOUR');
 298         $localtime[2]=0;
 299         last if ($p eq 'DAY');
 300         $localtime[3]=1;
 301         last if ($p eq 'MONTH');
 302         $localtime[4]=0;
 303         last if ($p eq 'YEAR');
 304         $RT::Logger->warning("Couldn't find start date of '$p'.");
 305         return;
 306     }
 307     my $new = $self->Timelocal($tz, @localtime);
 308     return $self->Unix($new);
 309 }
 310
 311 =head2 Diff
 312
 313 Takes either an C<RT::Date> object or the date in unixtime format as a string,
 314 if nothing is specified uses the current time.
 315
 316 Returns the differnce between the time in the current object and that time
 317 as a number of seconds. Returns C<undef> if any of two compared values is
 318 incorrect or not set.
 319
 320 =cut
 321
 322 sub Diff {
 323     my $self = shift;
 324     my $other = shift;
 325     $other = time unless defined $other;
 326     if ( UNIVERSAL::isa( $other, 'RT::Date' ) ) {
 327         $other = $other->Unix;
 328     }
 329     return undef unless $other=~ /^\d+$/ && $other > 0;
 330
 331     my $unix = $self->Unix;
 332     return undef unless $unix > 0;
 333
 334     return $unix - $other;
 335 }
 336
 337 =head2 DiffAsString
 338
 339 Takes either an C<RT::Date> object or the date in unixtime format as a string,
 340 if nothing is specified uses the current time.
 341
 342 Returns the differnce between C<$self> and that time as a number of seconds as
 343 a localized string fit for human consumption. Returns empty string if any of
 344 two compared values is incorrect or not set.
 345
 346 =cut
 347
 348 sub DiffAsString {
 349     my $self = shift;
 350     my $diff = $self->Diff( @_ );
 351     return '' unless defined $diff;
 352
 353     return $self->DurationAsString( $diff );
 354 }
 355
 356 =head2 DurationAsString
 357
 358 Takes a number of seconds. Returns a localized string describing
 359 that duration.
 360
 361 =cut
 362
 363 sub DurationAsString {
 364     my $self     = shift;
 365     my $duration = int shift;
 366
 367     my ( $negative, $s, $time_unit );
 368     $negative = 1 if $duration < 0;
 369     $duration = abs $duration;
 370
 371     if ( $duration < $MINUTE ) {
 372         $s         = $duration;
 373         $time_unit = $self->loc("sec");
 374     }
 375     elsif ( $duration < ( 2 * $HOUR ) ) {
 376         $s         = int( $duration / $MINUTE + 0.5 );
 377         $time_unit = $self->loc("min");
 378     }
 379     elsif ( $duration < ( 2 * $DAY ) ) {
 380         $s         = int( $duration / $HOUR + 0.5 );
 381         $time_unit = $self->loc("hours");
 382     }
 383     elsif ( $duration < ( 2 * $WEEK ) ) {
 384         $s         = int( $duration / $DAY + 0.5 );
 385         $time_unit = $self->loc("days");
 386     }
 387     elsif ( $duration < ( 2 * $MONTH ) ) {
 388         $s         = int( $duration / $WEEK + 0.5 );
 389         $time_unit = $self->loc("weeks");
 390     }
 391     elsif ( $duration < $YEAR ) {
 392         $s         = int( $duration / $MONTH + 0.5 );
 393         $time_unit = $self->loc("months");
 394     }
 395     else {
 396         $s         = int( $duration / $YEAR + 0.5 );
 397         $time_unit = $self->loc("years");
 398     }
 399
 400     if ( $negative ) {
 401         return $self->loc( "[_1] [_2] ago", $s, $time_unit );
 402     }
 403     else {
 404         return $self->loc( "[_1] [_2]", $s, $time_unit );
 405     }
 406 }
 407
 408 =head2 AgeAsString
 409
 410 Takes nothing. Returns a string that's the differnce between the
 411 time in the object and now.
 412
 413 =cut
 414
 415 sub AgeAsString { return $_[0]->DiffAsString }
 416
 417
 418
 419 =head2 AsString
 420
 421 Returns the object's time as a localized string with curent user's prefered
 422 format and timezone.
 423
 424 If the current user didn't choose prefered format then system wide setting is
 425 used or L</DefaultFormat> if the latter is not specified. See config option
 426 C<DateTimeFormat>.
 427
 428 =cut
 429
 430 sub AsString {
 431     my $self = shift;
 432     my %args = (@_);
 433
 434     return $self->loc("Not set") unless $self->Unix > 0;
 435
 436     my $format = RT->Config->Get( 'DateTimeFormat', $self->CurrentUser ) || 'DefaultFormat';
 437     $format = { Format => $format } unless ref $format;
 438     %args = (%$format, %args);
 439
 440     return $self->Get( Timezone => 'user', %args );
 441 }
 442
 443 =head2 GetWeekday DAY
 444
 445 Takes an integer day of week and returns a localized string for
 446 that day of week. Valid values are from range 0-6, Note that B<0
 447 is sunday>.
 448
 449 =cut
 450
 451 sub GetWeekday {
 452     my $self = shift;
 453     my $dow = shift;
 454
 455     return $self->loc($DAYS_OF_WEEK[$dow])
 456         if $DAYS_OF_WEEK[$dow];
 457     return '';
 458 }
 459
 460 =head2 GetMonth MONTH
 461
 462 Takes an integer month and returns a localized string for that month.
 463 Valid values are from from range 0-11.
 464
 465 =cut
 466
 467 sub GetMonth {
 468     my $self = shift;
 469     my $mon = shift;
 470
 471     return $self->loc($MONTHS[$mon])
 472         if $MONTHS[$mon];
 473     return '';
 474 }
 475
 476 =head2 AddSeconds SECONDS
 477
 478 Takes a number of seconds and returns the new unix time.
 479
 480 Negative value can be used to substract seconds.
 481
 482 =cut
 483
 484 sub AddSeconds {
 485     my $self = shift;
 486     my $delta = shift or return $self->Unix;
 487
 488     $self->Set(Format => 'unix', Value => ($self->Unix + $delta));
 489
 490     return ($self->Unix);
 491 }
 492
 493 =head2 AddDays [DAYS]
 494
 495 Adds C<24 hours * DAYS> to the current time. Adds one day when
 496 no argument is specified. Negative value can be used to substract
 497 days.
 498
 499 Returns new unix time.
 500
 501 =cut
 502
 503 sub AddDays {
 504     my $self = shift;
 505     my $days = shift || 1;
 506     return $self->AddSeconds( $days * $DAY );
 507 }
 508
 509 =head2 AddDay
 510
 511 Adds 24 hours to the current time. Returns new unix time.
 512
 513 =cut
 514
 515 sub AddDay { return $_[0]->AddSeconds($DAY) }
 516
 517 =head2 AddMonth
 518
 519 Adds one month to the current time. Returns new
 520 unix time.
 521
 522 =cut
 523
 524 sub AddMonth {
 525     my $self = shift;
 526     my %args = @_;
 527     my @localtime = $self->Localtime($args{'Timezone'});
 528     # remove offset, as with SetToStart
 529     pop @localtime;
 530
 531     $localtime[4]++; #month
 532     if ( $localtime[4] == 12 ) {
 533       $localtime[4] = 0;
 534       $localtime[5]++; #year
 535     }
 536
 537     my $new = $self->Timelocal($args{'Timezone'}, @localtime);
 538     return $self->Unix($new);
 539 }
 540
 541 =head2 Unix [unixtime]
 542
 543 Optionally takes a date in unix seconds since the epoch format.
 544 Returns the number of seconds since the epoch
 545
 546 =cut
 547
 548 sub Unix {
 549     my $self = shift;
 550     $self->{'time'} = int(shift || 0) if @_;
 551     return $self->{'time'};
 552 }
 553
 554 =head2 DateTime
 555
 556 Alias for L</Get> method. Arguments C<Date> and <Time>
 557 are fixed to true values, other arguments could be used
 558 as described in L</Get>.
 559
 560 =cut
 561
 562 sub DateTime {
 563     my $self = shift;
 564     unless (defined $self) {
 565         use Carp; Carp::confess("undefined $self");
 566     }
 567     return $self->Get( @_, Date => 1, Time => 1 );
 568 }
 569
 570 =head2 Date
 571
 572 Takes Format argument which allows you choose date formatter.
 573 Pass throught other arguments to the formatter method.
 574
 575 Returns the object's formatted date. Default formatter is ISO.
 576
 577 =cut
 578
 579 sub Date {
 580     my $self = shift;
 581     return $self->Get( @_, Date => 1, Time => 0 );
 582 }
 583
 584 =head2 Time
 585
 586
 587 =cut
 588
 589 sub Time {
 590     my $self = shift;
 591     return $self->Get( @_, Date => 0, Time => 1 );
 592 }
 593
 594 =head2 Get
 595
 596 Returnsa a formatted and localized string that represets time of
 597 the current object.
 598
 599
 600 =cut
 601
 602 sub Get
 603 {
 604     my $self = shift;
 605     my %args = (Format => 'ISO', @_);
 606     my $formatter = $args{'Format'};
 607     $formatter = 'ISO' unless $self->can($formatter);
 608     return $self->$formatter( %args );
 609 }
 610
 611 =head2 Output formatters
 612
 613 Fomatter is a method that returns date and time in different configurable
 614 format.
 615
 616 Each method takes several arguments:
 617
 618 =over 1
 619
 620 =item Date
 621
 622 =item Time
 623
 624 =item Timezone - Timezone context C<server>, C<user> or C<UTC>
 625
 626 =back
 627
 628 Formatters may also add own arguments to the list, for example
 629 in RFC2822 format day of time in output is optional so it
 630 understand boolean argument C<DayOfTime>.
 631
 632 =head3 Formatters
 633
 634 Returns an array of available formatters.
 635
 636 =cut
 637
 638 sub Formatters
 639 {
 640     my $self = shift;
 641
 642     return @FORMATTERS;
 643 }
 644
 645 =head3 DefaultFormat
 646
 647 =cut
 648
 649 sub DefaultFormat
 650 {
 651     my $self = shift;
 652     my %args = ( Date => 1,
 653                  Time => 1,
 654                  Timezone => '',
 655                  Seconds => 1,
 656                  @_,
 657                );
 658
 659        #  0    1    2     3     4    5     6     7      8      9
 660     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
 661                             $self->Localtime($args{'Timezone'});
 662     $wday = $self->GetWeekday($wday);
 663     $mon = $self->GetMonth($mon);
 664     ($mday, $hour, $min, $sec) = map { sprintf "%02d", $_ } ($mday, $hour, $min, $sec);
 665
 666     if( $args{'Date'} && !$args{'Time'} ) {
 667         return $self->loc('[_1] [_2] [_3] [_4]',
 668                           $wday,$mon,$mday,$year);
 669     } elsif( !$args{'Date'} && $args{'Time'} ) {
 670         if( $args{'Seconds'} ) {
 671             return $self->loc('[_1]:[_2]:[_3]',
 672                               $hour,$min,$sec);
 673         } else {
 674             return $self->loc('[_1]:[_2]',
 675                               $hour,$min);
 676         }
 677     } else {
 678         if( $args{'Seconds'} ) {
 679             return $self->loc('[_1] [_2] [_3] [_4]:[_5]:[_6] [_7]',
 680                               $wday,$mon,$mday,$hour,$min,$sec,$year);
 681         } else {
 682             return $self->loc('[_1] [_2] [_3] [_4]:[_5] [_6]',
 683                               $wday,$mon,$mday,$hour,$min,$year);
 684         }
 685     }
 686 }
 687
 688 =head3 LocalizedDateTime
 689
 690 Returns date and time as string, with user localization.
 691
 692 Supports arguments: C<DateFormat> and C<TimeFormat> which may contains date and
 693 time format as specified in DateTime::Locale (default to full_date_format and
 694 medium_time_format), C<AbbrDay> and C<AbbrMonth> which may be set to 0 if
 695 you want full Day/Month names instead of abbreviated ones.
 696
 697 Require optionnal DateTime::Locale module.
 698
 699 =cut
 700
 701 sub LocalizedDateTime
 702 {
 703     my $self = shift;
 704     my %args = ( Date => 1,
 705                  Time => 1,
 706                  Timezone => '',
 707                  DateFormat => 'date_format_full',
 708                  TimeFormat => 'time_format_medium',
 709                  AbbrDay => 1,
 710                  AbbrMonth => 1,
 711                  @_,
 712                );
 713
 714     return $self->loc("DateTime module missing") unless ( eval 'use DateTime qw(); 1;' );
 715     return $self->loc("DateTime::Locale module missing") unless ( eval 'use DateTime::Locale qw(); 1;' );
 716     return $self->loc("DateTime doesn't support format_cldr, you must upgrade to use this feature")
 717         unless can DateTime::('format_cldr');
 718
 719
 720     my $date_format = $args{'DateFormat'};
 721     my $time_format = $args{'TimeFormat'};
 722
 723     my $lang = $self->CurrentUser->UserObj->Lang;
 724     unless ($lang) {
 725         require I18N::LangTags::Detect;
 726         $lang = ( I18N::LangTags::Detect::detect(), 'en' )[0];
 727     }
 728
 729
 730     my $formatter = DateTime::Locale->load($lang);
 731     return $self->loc("DateTime::Locale doesn't support date_format_full, you must upgrade to use this feature")
 732         unless $formatter->can('date_format_full');
 733     $date_format = $formatter->$date_format;
 734     $time_format = $formatter->$time_format;
 735     $date_format =~ s/EEEE/EEE/g if ( $args{'AbbrDay'} );
 736     $date_format =~ s/MMMM/MMM/g if ( $args{'AbbrMonth'} );
 737
 738     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
 739                             $self->Localtime($args{'Timezone'});
 740     $mon++;
 741     my $tz = $self->Timezone($args{'Timezone'});
 742
 743     # FIXME : another way to call this module without conflict with local
 744     # DateTime method?
 745     my $dt = new DateTime::( locale => $lang,
 746                             time_zone => $tz,
 747                             year => $year,
 748                             month => $mon,
 749                             day => $mday,
 750                             hour => $hour,
 751                             minute => $min,
 752                             second => $sec,
 753                             nanosecond => 0,
 754                           );
 755
 756     if ( $args{'Date'} && !$args{'Time'} ) {
 757         return $dt->format_cldr($date_format);
 758     } elsif ( !$args{'Date'} && $args{'Time'} ) {
 759         return $dt->format_cldr($time_format);
 760     } else {
 761         return $dt->format_cldr($date_format) . " " . $dt->format_cldr($time_format);
 762     }
 763 }
 764
 765 =head3 ISO
 766
 767 Returns the object's date in ISO format C<YYYY-MM-DD mm:hh:ss>.
 768 ISO format is locale independant, but adding timezone offset info
 769 is not implemented yet.
 770
 771 Supports arguments: C<Timezone>, C<Date>, C<Time> and C<Seconds>.
 772 See </Output formatters> for description of arguments.
 773
 774 =cut
 775
 776 sub ISO {
 777     my $self = shift;
 778     my %args = ( Date => 1,
 779                  Time => 1,
 780                  Timezone => '',
 781                  Seconds => 1,
 782                  @_,
 783                );
 784        #  0    1    2     3     4    5     6     7      8      9
 785     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
 786                             $self->Localtime($args{'Timezone'});
 787
 788     #the month needs incrementing, as gmtime returns 0-11
 789     $mon++;
 790
 791     my $res = '';
 792     $res .= sprintf("%04d-%02d-%02d", $year, $mon, $mday) if $args{'Date'};
 793     $res .= sprintf(' %02d:%02d', $hour, $min) if $args{'Time'};
 794     $res .= sprintf(':%02d', $sec, $min) if $args{'Time'} && $args{'Seconds'};
 795     $res =~ s/^\s+//;
 796
 797     return $res;
 798 }
 799
 800 =head3 W3CDTF
 801
 802 Returns the object's date and time in W3C date time format
 803 (L<http://www.w3.org/TR/NOTE-datetime>).
 804
 805 Format is locale independand and is close enought to ISO, but
 806 note that date part is B<not optional> and output string
 807 has timezone offset mark in C<[+-]hh:mm> format.
 808
 809 Supports arguments: C<Timezone>, C<Time> and C<Seconds>.
 810 See </Output formatters> for description of arguments.
 811
 812 =cut
 813
 814 sub W3CDTF {
 815     my $self = shift;
 816     my %args = (
 817         Time => 1,
 818         Timezone => '',
 819         Seconds => 1,
 820         @_,
 821         Date => 1,
 822     );
 823        #  0    1    2     3     4    5     6     7      8      9
 824     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
 825                             $self->Localtime( $args{'Timezone'} );
 826
 827     #the month needs incrementing, as gmtime returns 0-11
 828     $mon++;
 829
 830     my $res = '';
 831     $res .= sprintf("%04d-%02d-%02d", $year, $mon, $mday);
 832     if ( $args{'Time'} ) {
 833         $res .= sprintf('T%02d:%02d', $hour, $min);
 834         $res .= sprintf(':%02d', $sec, $min) if $args{'Seconds'};
 835         if ( $offset ) {
 836             $res .= sprintf "%s%02d:%02d", $self->_SplitOffset( $offset );
 837         } else {
 838             $res .= 'Z';
 839         }
 840     }
 841
 842     return $res;
 843 };
 844
 845
 846 =head3 RFC2822 (MIME)
 847
 848 Returns the object's date and time in RFC2822 format,
 849 for example C<Sun, 06 Nov 1994 08:49:37 +0000>.
 850 Format is locale independand as required by RFC. Time
 851 part always has timezone offset in digits with sign prefix.
 852
 853 Supports arguments: C<Timezone>, C<Date>, C<Time>, C<DayOfWeek>
 854 and C<Seconds>. See </Output formatters> for description of
 855 arguments.
 856
 857 =cut
 858
 859 sub RFC2822 {
 860     my $self = shift;
 861     my %args = ( Date => 1,
 862                  Time => 1,
 863                  Timezone => '',
 864                  DayOfWeek => 1,
 865                  Seconds => 1,
 866                  @_,
 867                );
 868
 869        #  0    1    2     3     4    5     6     7      8     9
 870     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
 871                             $self->Localtime($args{'Timezone'});
 872
 873     my ($date, $time) = ('','');
 874     $date .= "$DAYS_OF_WEEK[$wday], " if $args{'DayOfWeek'} && $args{'Date'};
 875     $date .= "$mday $MONTHS[$mon] $year" if $args{'Date'};
 876
 877     if ( $args{'Time'} ) {
 878         $time .= sprintf("%02d:%02d", $hour, $min);
 879         $time .= sprintf(":%02d", $sec) if $args{'Seconds'};
 880         $time .= sprintf " %s%02d%02d", $self->_SplitOffset( $offset );
 881     }
 882
 883     return join ' ', grep $_, ($date, $time);
 884 }
 885
 886 =head3 RFC2616 (HTTP)
 887
 888 Returns the object's date and time in RFC2616 (HTTP/1.1) format,
 889 for example C<Sun, 06 Nov 1994 08:49:37 GMT>. While the RFC describes
 890 version 1.1 of HTTP, but the same form date can be used in version 1.0.
 891
 892 Format is fixed length, locale independand and always represented in GMT
 893 what makes it quite useless for users, but any date in HTTP transfers
 894 must be presented using this format.
 895
 896     HTTP-date = rfc1123 | ...
 897     rfc1123   = wkday "," SP date SP time SP "GMT"
 898     date      = 2DIGIT SP month SP 4DIGIT
 899                 ; day month year (e.g., 02 Jun 1982)
 900     time      = 2DIGIT ":" 2DIGIT ":" 2DIGIT
 901                 ; 00:00:00 - 23:59:59
 902     wkday     = "Mon" | "Tue" | "Wed" | "Thu" | "Fri" | "Sat" | "Sun"
 903     month     = "Jan" | "Feb" | "Mar" | "Apr" | "May" | "Jun"
 904               | "Jul" | "Aug" | "Sep" | "Oct" | "Nov" | "Dec"
 905
 906 Supports arguments: C<Date> and C<Time>, but you should use them only for
 907 some personal reasons, RFC2616 doesn't define any optional parts.
 908 See </Output formatters> for description of arguments.
 909
 910 =cut
 911
 912 sub RFC2616 {
 913     my $self = shift;
 914     my %args = ( Date => 1, Time => 1,
 915                  @_,
 916                  Timezone => 'utc',
 917                  Seconds => 1, DayOfWeek => 1,
 918                );
 919
 920     my $res = $self->RFC2822( %args );
 921     $res =~ s/\s*[+-]\d\d\d\d$/ GMT/ if $args{'Time'};
 922     return $res;
 923 }
 924
 925 =head4 iCal
 926
 927 Returns the object's date and time in iCalendar format,
 928
 929 Supports arguments: C<Date> and C<Time>.
 930 See </Output formatters> for description of arguments.
 931
 932 =cut
 933
 934 sub iCal {
 935     my $self = shift;
 936     my %args = (
 937         Date => 1, Time => 1,
 938         @_,
 939     );
 940     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$ydaym,$isdst,$offset) =
 941         $self->Localtime( 'utc' );
 942
 943     #the month needs incrementing, as gmtime returns 0-11
 944     $mon++;
 945
 946     my $res;
 947     if ( $args{'Date'} && !$args{'Time'} ) {
 948         $res = sprintf( '%04d%02d%02d', $year, $mon, $mday );
 949     }
 950     elsif ( !$args{'Date'} && $args{'Time'} ) {
 951         $res = sprintf( 'T%02d%02d%02dZ', $hour, $min, $sec );
 952     }
 953     else {
 954         $res = sprintf( '%04d%02d%02dT%02d%02d%02dZ', $year, $mon, $mday, $hour, $min, $sec );
 955     }
 956     return $res;
 957 }
 958
 959 # it's been added by mistake in 3.8.0
 960 sub iCalDate { return (shift)->iCal( Time => 0, @_ ) }
 961
 962 sub _SplitOffset {
 963     my ($self, $offset) = @_;
 964     my $sign = $offset < 0? '-': '+';
 965     $offset = int( (abs $offset) / 60 + 0.001 );
 966     my $mins = $offset % 60;
 967     my $hours = int( $offset/60 + 0.001 );
 968     return $sign, $hours, $mins;
 969 }
 970
 971 =head2 Timezones handling
 972
 973 =head3 Localtime $context [$time]
 974
 975 Takes one mandatory argument C<$context>, which determines whether
 976 we want "user local", "system" or "UTC" time. Also, takes optional
 977 argument unix C<$time>, default value is the current unix time.
 978
 979 Returns object's date and time in the format provided by perl's
 980 builtin functions C<localtime> and C<gmtime> with two exceptions:
 981
 982 1) "Year" is a four-digit year, rather than "years since 1900"
 983
 984 2) The last element of the array returned is C<offset>, which
 985 represents timezone offset against C<UTC> in seconds.
 986
 987 =cut
 988
 989 sub Localtime
 990 {
 991     my $self = shift;
 992     my $tz = $self->Timezone(shift);
 993
 994     my $unix = shift || $self->Unix;
 995     $unix = 0 unless $unix >= 0;
 996
 997     my @local;
 998     if ($tz eq 'UTC') {
 999         @local = gmtime($unix);
1000     } else {
1001         {
1002             local $ENV{'TZ'} = $tz;
1003             ## Using POSIX::tzset fixes a bug where the TZ environment variable
1004             ## is cached.
1005             POSIX::tzset();
1006             @local = localtime($unix);
1007         }
1008         POSIX::tzset(); # return back previouse value
1009     }
1010     $local[5] += 1900; # change year to 4+ digits format
1011     my $offset = Time::Local::timegm_nocheck(@local) - $unix;
1012     return @local, $offset;
1013 }
1014
1015 =head3 Timelocal $context @time
1016
1017 Takes argument C<$context>, which determines whether we should
1018 treat C<@time> as "user local", "system" or "UTC" time.
1019
1020 C<@time> is array returned by L<Localtime> functions. Only first
1021 six elements are mandatory - $sec, $min, $hour, $mday, $mon and $year.
1022 You may pass $wday, $yday and $isdst, these are ignored.
1023
1024 If you pass C<$offset> as ninth argument, it's used instead of
1025 C<$context>. It's done such way as code
1026 C<$self->Timelocal('utc', $self->Localtime('server'))> doesn't
1027 makes much sense and most probably would produce unexpected
1028 result, so the method ignore 'utc' context and uses offset
1029 returned by L<Localtime> method.
1030
1031 =cut
1032
1033 sub Timelocal {
1034     my $self = shift;
1035     my $tz = shift;
1036     if ( defined $_[9] ) {
1037         return timegm(@_[0..5]) - $_[9];
1038     } else {
1039         $tz = $self->Timezone( $tz );
1040         if ( $tz eq 'UTC' ) {
1041             return Time::Local::timegm(@_[0..5]);
1042         } else {
1043             my $rv;
1044             {
1045                 local $ENV{'TZ'} = $tz;
1046                 ## Using POSIX::tzset fixes a bug where the TZ environment variable
1047                 ## is cached.
1048                 POSIX::tzset();
1049                 $rv = Time::Local::timelocal(@_[0..5]);
1050             };
1051             POSIX::tzset(); # switch back to previouse value
1052             return $rv;
1053         }
1054     }
1055 }
1056
1057
1058 =head3 Timezone $context
1059
1060 Returns the timezone name.
1061
1062 Takes one argument, C<$context> argument which could be C<user>, C<server> or C<utc>.
1063
1064 =over
1065
1066 =item user
1067
1068 Default value is C<user> that mean it returns current user's Timezone value.
1069
1070 =item server
1071
1072 If context is C<server> it returns value of the C<Timezone> RT config option.
1073
1074 =item  utc
1075
1076 If both server's and user's timezone names are undefined returns 'UTC'.
1077
1078 =back
1079
1080 =cut
1081
1082 sub Timezone {
1083     my $self = shift;
1084     my $context = lc(shift);
1085
1086     $context = 'utc' unless $context =~ /^(?:utc|server|user)$/i;
1087
1088     my $tz;
1089     if( $context eq 'user' ) {
1090         $tz = $self->CurrentUser->UserObj->Timezone;
1091     } elsif( $context eq 'server') {
1092         $tz = RT->Config->Get('Timezone');
1093     } else {
1094         $tz = 'UTC';
1095     }
1096     $tz ||= RT->Config->Get('Timezone') || 'UTC';
1097     $tz = 'UTC' if lc $tz eq 'gmt';
1098     return $tz;
1099 }
1100
1101
1102 eval "require RT::Date_Vendor";
1103 die $@ if ($@ && $@ !~ qr{^Can't locate RT/Date_Vendor.pm});
1104 eval "require RT::Date_Local";
1105 die $@ if ($@ && $@ !~ qr{^Can't locate RT/Date_Local.pm});
1106
1107 1;