rt/lib/RT/Condition/StatusChange.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 package RT::Condition::StatusChange;
  50 use base 'RT::Condition';
  51 use strict;
  52
  53 =head2 DESCRIPTION
  54
  55 This condition check passes if the current transaction is a status change.
  56
  57 The argument can be used to apply additional conditions on old and new values.
  58
  59 If argument is empty then the check passes for any change of the status field.
  60
  61 If argument is equal to new value then check is passed. This is behavior
  62 is close to RT 3.8 and older. For example, setting the argument to 'resolved' means
  63 'fire scrip when status changed from any to resolved'.
  64
  65 The following extended format is supported:
  66
  67     old: comma separated list; new: comma separated list
  68
  69 For example:
  70
  71     old: open; new: resolved
  72
  73 You can omit old or new part, for example:
  74
  75     old: open
  76
  77     new: resolved
  78
  79 You can specify multiple values, for example:
  80
  81     old: new, open; new: resolved, rejected
  82
  83 Status sets ('initial', 'active' or 'inactive') can be used, for example:
  84
  85     old: active; new: inactive
  86
  87     old: initial, active; new: resolved
  88
  89 =cut
  90
  91 sub IsApplicable {
  92     my $self = shift;
  93     my $txn = $self->TransactionObj;
  94     my ($type, $field) = ($txn->Type, $txn->Field);
  95     return 0 unless $type eq 'Status' || ($type eq 'Set' && $field eq 'Status');
  96
  97     my $argument = $self->Argument;
  98     return 1 unless $argument;
  99
 100     my $new = $txn->NewValue || '';
 101     return 1 if $argument eq $new;
 102
 103     # let's parse argument
 104     my ($old_must_be, $new_must_be) = ('', '');
 105     if ( $argument =~ /^\s*old:\s*(.*);\s*new:\s*(.*)\s*$/i ) {
 106         ($old_must_be, $new_must_be) = ($1, $2);
 107     }
 108     elsif ( $argument =~ /^\s*new:\s*(.*)\s*$/i ) {
 109         $new_must_be = $1;
 110     }
 111     elsif ( $argument =~ /^\s*old:\s*(.*)\s*$/i ) {
 112         $old_must_be = $1;
 113     }
 114     else {
 115         $RT::Logger->error("Argument '$argument' is incorrect.")
 116             unless RT::Lifecycle->Load('')->IsValid( $argument );
 117         return 0;
 118     }
 119
 120     my $lifecycle = $self->TicketObj->QueueObj->Lifecycle;
 121     if ( $new_must_be ) {
 122         return 0 unless grep lc($new) eq lc($_),
 123             map {m/^(initial|active|inactive)$/i? $lifecycle->Valid(lc $_): $_ }
 124             grep defined && length,
 125             map { s/^\s+//; s/\s+$//; $_ }
 126             split /,/, $new_must_be;
 127     }
 128     if ( $old_must_be ) {
 129         my $old = lc($txn->OldValue || '');
 130         return 0 unless grep $old eq lc($_),
 131             map {m/^(initial|active|inactive)$/i? $lifecycle->Valid(lc $_): $_ }
 132             grep defined && length,
 133             map { s/^\s+//; s/\s+$//; $_ }
 134             split /,/, $old_must_be;
 135     }
 136     return 1;
 137 }
 138
 139 RT::Base->_ImportOverlays();
 140
 141 1;
 142