rt/lib/RT/Action/Notify.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2011 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 #
  50 package RT::Action::Notify;
  51
  52 use strict;
  53 use warnings;
  54
  55 use base qw(RT::Action::SendEmail);
  56
  57 use Email::Address;
  58
  59 =head2 Prepare
  60
  61 Set up the relevant recipients, then call our parent.
  62
  63 =cut
  64
  65
  66 sub Prepare {
  67     my $self = shift;
  68     $self->SetRecipients();
  69     $self->SUPER::Prepare();
  70 }
  71
  72 =head2 SetRecipients
  73
  74 Sets the recipients of this meesage to Owner, Requestor, AdminCc, Cc or All.
  75 Explicitly B<does not> notify the creator of the transaction by default
  76
  77 =cut
  78
  79 sub SetRecipients {
  80     my $self = shift;
  81
  82     my $ticket = $self->TicketObj;
  83
  84     my $arg = $self->Argument;
  85     $arg =~ s/\bAll\b/Owner,Requestor,AdminCc,Cc/;
  86
  87     my ( @To, @PseudoTo, @Cc, @Bcc );
  88
  89
  90     if ( $arg =~ /\bOtherRecipients\b/ ) {
  91         if ( my $attachment = $self->TransactionObj->Attachments->First ) {
  92             push @Cc, map { $_->address } Email::Address->parse(
  93                 $attachment->GetHeader('RT-Send-Cc')
  94             );
  95             push @Bcc, map { $_->address } Email::Address->parse(
  96                 $attachment->GetHeader('RT-Send-Bcc')
  97             );
  98         }
  99     }
 100
 101     if ( $arg =~ /\bRequestor\b/ ) {
 102         push @To, $ticket->Requestors->MemberEmailAddresses;
 103     }
 104
 105     if ( $arg =~ /\bCc\b/ ) {
 106
 107         #If we have a To, make the Ccs, Ccs, otherwise, promote them to To
 108         if (@To) {
 109             push ( @Cc, $ticket->Cc->MemberEmailAddresses );
 110             push ( @Cc, $ticket->QueueObj->Cc->MemberEmailAddresses  );
 111         }
 112         else {
 113             push ( @Cc, $ticket->Cc->MemberEmailAddresses  );
 114             push ( @To, $ticket->QueueObj->Cc->MemberEmailAddresses  );
 115         }
 116     }
 117
 118     if ( $arg =~ /\bOwner\b/ && $ticket->OwnerObj->id != $RT::Nobody->id ) {
 119         # If we're not sending to Ccs or requestors,
 120         # then the Owner can be the To.
 121         if (@To) {
 122             push ( @Bcc, $ticket->OwnerObj->EmailAddress );
 123         }
 124         else {
 125             push ( @To, $ticket->OwnerObj->EmailAddress );
 126         }
 127
 128     }
 129
 130     if ( $arg =~ /\bAdminCc\b/ ) {
 131         push ( @Bcc, $ticket->AdminCc->MemberEmailAddresses  );
 132         push ( @Bcc, $ticket->QueueObj->AdminCc->MemberEmailAddresses  );
 133     }
 134
 135     if ( RT->Config->Get('UseFriendlyToLine') ) {
 136         unless (@To) {
 137             push @PseudoTo,
 138                 sprintf RT->Config->Get('FriendlyToLineFormat'), $arg, $ticket->id;
 139         }
 140     }
 141
 142     my $creatorObj = $self->TransactionObj->CreatorObj;
 143     my $creator = $creatorObj->EmailAddress();
 144
 145     #Strip the sender out of the To, Cc and AdminCc and set the
 146     # recipients fields used to build the message by the superclass.
 147     # unless a flag is set
 148     my $TransactionCurrentUser = RT::CurrentUser->new;
 149     $TransactionCurrentUser->LoadByName($creatorObj->Name);
 150     if (RT->Config->Get('NotifyActor',$TransactionCurrentUser)) {
 151         @{ $self->{'To'} }  = @To;
 152         @{ $self->{'Cc'} }  = @Cc;
 153         @{ $self->{'Bcc'} } = @Bcc;
 154     }
 155     else {
 156         @{ $self->{'To'} }  = grep ( lc $_ ne lc $creator, @To );
 157         @{ $self->{'Cc'} }  = grep ( lc $_ ne lc $creator, @Cc );
 158         @{ $self->{'Bcc'} } = grep ( lc $_ ne lc $creator, @Bcc );
 159     }
 160     @{ $self->{'PseudoTo'} } = @PseudoTo;
 161
 162
 163 }
 164
 165 eval "require RT::Action::Notify_Vendor";
 166 die $@ if ($@ && $@ !~ qr{^Can't locate RT/Action/Notify_Vendor.pm});
 167 eval "require RT::Action::Notify_Local";
 168 die $@ if ($@ && $@ !~ qr{^Can't locate RT/Action/Notify_Local.pm});
 169
 170 1;