rt/lib/RT.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 use strict;
  50 use warnings;
  51
  52 package RT;
  53
  54
  55 use File::Spec ();
  56 use Cwd ();
  57
  58 use vars qw($Config $System $SystemUser $Nobody $Handle $Logger $_Privileged $_Unprivileged $_INSTALL_MODE);
  59
  60 use vars qw($BasePath
  61  $EtcPath
  62  $BinPath
  63  $SbinPath
  64  $VarPath
  65  $LexiconPath
  66  $PluginPath
  67  $LocalPath
  68  $LocalEtcPath
  69  $LocalLibPath
  70  $LocalLexiconPath
  71  $LocalPluginPath
  72  $MasonComponentRoot
  73  $MasonLocalComponentRoot
  74  $MasonDataDir
  75  $MasonSessionDir);
  76
  77
  78 RT->LoadGeneratedData();
  79
  80 =head1 NAME
  81
  82 RT - Request Tracker
  83
  84 =head1 SYNOPSIS
  85
  86 A fully featured request tracker package
  87
  88 =head1 DESCRIPTION
  89
  90 =head2 INITIALIZATION
  91
  92 =head2 LoadConfig
  93
  94 Load RT's config file.  First, the site configuration file
  95 (F<RT_SiteConfig.pm>) is loaded, in order to establish overall site
  96 settings like hostname and name of RT instance.  Then, the core
  97 configuration file (F<RT_Config.pm>) is loaded to set fallback values
  98 for all settings; it bases some values on settings from the site
  99 configuration file.
 100
 101 In order for the core configuration to not override the site's
 102 settings, the function C<Set> is used; it only sets values if they
 103 have not been set already.
 104
 105 =cut
 106
 107 sub LoadConfig {
 108     require RT::Config;
 109     $Config = RT::Config->new;
 110     $Config->LoadConfigs;
 111     require RT::I18N;
 112
 113     # RT::Essentials mistakenly recommends that WebPath be set to '/'.
 114     # If the user does that, do what they mean.
 115     $RT::WebPath = '' if ($RT::WebPath eq '/');
 116
 117     # fix relative LogDir and GnuPG homedir
 118     unless ( File::Spec->file_name_is_absolute( $Config->Get('LogDir') ) ) {
 119         $Config->Set( LogDir =>
 120               File::Spec->catfile( $BasePath, $Config->Get('LogDir') ) );
 121     }
 122
 123     my $gpgopts = $Config->Get('GnuPGOptions');
 124     unless ( File::Spec->file_name_is_absolute( $gpgopts->{homedir} ) ) {
 125         $gpgopts->{homedir} = File::Spec->catfile( $BasePath, $gpgopts->{homedir} );
 126     }
 127
 128     return $Config;
 129 }
 130
 131 =head2 Init
 132
 133 L<Connects to the database|/ConnectToDatabase>, L<initilizes system
 134 objects|/InitSystemObjects>, L<preloads classes|/InitClasses>, L<sets
 135 up logging|/InitLogging>, and L<loads plugins|/InitPlugins>.
 136
 137 =cut
 138
 139 sub Init {
 140
 141     CheckPerlRequirements();
 142
 143     InitPluginPaths();
 144
 145     #Get a database connection
 146     ConnectToDatabase();
 147     InitSystemObjects();
 148     InitClasses();
 149     InitLogging();
 150     InitPlugins();
 151     RT::I18N->Init;
 152     RT->Config->PostLoadCheck;
 153
 154 }
 155
 156 =head2 ConnectToDatabase
 157
 158 Get a database connection. See also L</Handle>.
 159
 160 =cut
 161
 162 sub ConnectToDatabase {
 163     require RT::Handle;
 164     $Handle = RT::Handle->new unless $Handle;
 165     $Handle->Connect;
 166     return $Handle;
 167 }
 168
 169 =head2 InitLogging
 170
 171 Create the Logger object and set up signal handlers.
 172
 173 =cut
 174
 175 sub InitLogging {
 176
 177     # We have to set the record separator ($, man perlvar)
 178     # or Log::Dispatch starts getting
 179     # really pissy, as some other module we use unsets it.
 180     $, = '';
 181     use Log::Dispatch 1.6;
 182
 183     my %level_to_num = (
 184         map( { $_ => } 0..7 ),
 185         debug     => 0,
 186         info      => 1,
 187         notice    => 2,
 188         warning   => 3,
 189         error     => 4, 'err' => 4,
 190         critical  => 5, crit  => 5,
 191         alert     => 6,
 192         emergency => 7, emerg => 7,
 193     );
 194
 195     unless ( $RT::Logger ) {
 196
 197         $RT::Logger = Log::Dispatch->new;
 198
 199         my $stack_from_level;
 200         if ( $stack_from_level = RT->Config->Get('LogStackTraces') ) {
 201             # if option has old style '\d'(true) value
 202             $stack_from_level = 0 if $stack_from_level =~ /^\d+$/;
 203             $stack_from_level = $level_to_num{ $stack_from_level } || 0;
 204         } else {
 205             $stack_from_level = 99; # don't log
 206         }
 207
 208         my $simple_cb = sub {
 209             # if this code throw any warning we can get segfault
 210             no warnings;
 211             my %p = @_;
 212
 213             # skip Log::* stack frames
 214             my $frame = 0;
 215             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 216             my ($package, $filename, $line) = caller($frame);
 217
 218             $p{'message'} =~ s/(?:\r*\n)+$//;
 219             return "[". gmtime(time) ."] [". $p{'level'} ."]: "
 220                 . $p{'message'} ." ($filename:$line)\n";
 221         };
 222
 223         my $syslog_cb = sub {
 224             # if this code throw any warning we can get segfault
 225             no warnings;
 226             my %p = @_;
 227
 228             my $frame = 0; # stack frame index
 229             # skip Log::* stack frames
 230             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 231             my ($package, $filename, $line) = caller($frame);
 232
 233             # syswrite() cannot take utf8; turn it off here.
 234             Encode::_utf8_off($p{message});
 235
 236             $p{message} =~ s/(?:\r*\n)+$//;
 237             if ($p{level} eq 'debug') {
 238                 return "$p{message}\n";
 239             } else {
 240                 return "$p{message} ($filename:$line)\n";
 241             }
 242         };
 243
 244         my $stack_cb = sub {
 245             no warnings;
 246             my %p = @_;
 247             return $p{'message'} unless $level_to_num{ $p{'level'} } >= $stack_from_level;
 248
 249             require Devel::StackTrace;
 250             my $trace = Devel::StackTrace->new( ignore_class => [ 'Log::Dispatch', 'Log::Dispatch::Base' ] );
 251             return $p{'message'} . $trace->as_string;
 252
 253             # skip calling of the Log::* subroutins
 254             my $frame = 0;
 255             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 256             $frame++ while caller($frame) && (caller($frame))[3] =~ /^Log::/;
 257
 258             $p{'message'} .= "\nStack trace:\n";
 259             while( my ($package, $filename, $line, $sub) = caller($frame++) ) {
 260                 $p{'message'} .= "\t$sub(...) called at $filename:$line\n";
 261             }
 262             return $p{'message'};
 263         };
 264
 265         if ( $Config->Get('LogToFile') ) {
 266             my ($filename, $logdir) = (
 267                 $Config->Get('LogToFileNamed') || 'rt.log',
 268                 $Config->Get('LogDir') || File::Spec->catdir( $VarPath, 'log' ),
 269             );
 270             if ( $filename =~ m![/\\]! ) { # looks like an absolute path.
 271                 ($logdir) = $filename =~ m{^(.*[/\\])};
 272             }
 273             else {
 274                 $filename = File::Spec->catfile( $logdir, $filename );
 275             }
 276
 277             unless ( -d $logdir && ( ( -f $filename && -w $filename ) || -w $logdir ) ) {
 278                 # localizing here would be hard when we don't have a current user yet
 279                 die "Log file '$filename' couldn't be written or created.\n RT can't run.";
 280             }
 281
 282             require Log::Dispatch::File;
 283             $RT::Logger->add( Log::Dispatch::File->new
 284                            ( name=>'file',
 285                              min_level=> $Config->Get('LogToFile'),
 286                              filename=> $filename,
 287                              mode=>'append',
 288                              callbacks => [ $simple_cb, $stack_cb ],
 289                            ));
 290         }
 291         if ( $Config->Get('LogToScreen') ) {
 292             require Log::Dispatch::Screen;
 293             $RT::Logger->add( Log::Dispatch::Screen->new
 294                          ( name => 'screen',
 295                            min_level => $Config->Get('LogToScreen'),
 296                            callbacks => [ $simple_cb, $stack_cb ],
 297                            stderr => 1,
 298                          ));
 299         }
 300         if ( $Config->Get('LogToSyslog') ) {
 301             require Log::Dispatch::Syslog;
 302             $RT::Logger->add(Log::Dispatch::Syslog->new
 303                          ( name => 'syslog',
 304                            ident => 'RT',
 305                            min_level => $Config->Get('LogToSyslog'),
 306                            callbacks => [ $syslog_cb, $stack_cb ],
 307                            stderr => 1,
 308                            $Config->Get('LogToSyslogConf'),
 309                          ));
 310         }
 311     }
 312     InitSignalHandlers();
 313 }
 314
 315 sub InitSignalHandlers {
 316
 317 # Signal handlers
 318 ## This is the default handling of warnings and die'ings in the code
 319 ## (including other used modules - maybe except for errors catched by
 320 ## Mason).  It will log all problems through the standard logging
 321 ## mechanism (see above).
 322
 323     $SIG{__WARN__} = sub {
 324         # The 'wide character' warnings has to be silenced for now, at least
 325         # until HTML::Mason offers a sane way to process both raw output and
 326         # unicode strings.
 327         # use 'goto &foo' syntax to hide ANON sub from stack
 328         if( index($_[0], 'Wide character in ') != 0 ) {
 329             unshift @_, $RT::Logger, qw(level warning message);
 330             goto &Log::Dispatch::log;
 331         }
 332     };
 333
 334 #When we call die, trap it and log->crit with the value of the die.
 335
 336     $SIG{__DIE__}  = sub {
 337         # if we are not in eval and perl is not parsing code
 338         # then rollback transactions and log RT error
 339         unless ($^S || !defined $^S ) {
 340             $RT::Handle->Rollback(1) if $RT::Handle;
 341             $RT::Logger->crit("$_[0]") if $RT::Logger;
 342         }
 343         die $_[0];
 344     };
 345 }
 346
 347
 348 sub CheckPerlRequirements {
 349     if ($^V < 5.008003) {
 350         die sprintf "RT requires Perl v5.8.3 or newer.  Your current Perl is v%vd\n", $^V;
 351     }
 352
 353     # use $error here so the following "die" can still affect the global $@
 354     my $error;
 355     {
 356         local $@;
 357         eval {
 358             my $x = '';
 359             my $y = \$x;
 360             require Scalar::Util;
 361             Scalar::Util::weaken($y);
 362         };
 363         $error = $@;
 364     }
 365
 366     if ($error) {
 367         die <<"EOF";
 368
 369 RT requires the Scalar::Util module be built with support for  the 'weaken'
 370 function.
 371
 372 It is sometimes the case that operating system upgrades will replace
 373 a working Scalar::Util with a non-working one. If your system was working
 374 correctly up until now, this is likely the cause of the problem.
 375
 376 Please reinstall Scalar::Util, being careful to let it build with your C
 377 compiler. Usually this is as simple as running the following command as
 378 root.
 379
 380     perl -MCPAN -e'install Scalar::Util'
 381
 382 EOF
 383
 384     }
 385 }
 386
 387 =head2 InitClasses
 388
 389 Load all modules that define base classes.
 390
 391 =cut
 392
 393 sub InitClasses {
 394     shift if @_%2; # so we can call it as a function or method
 395     my %args = (@_);
 396     require RT::Tickets;
 397     require RT::Transactions;
 398     require RT::Attachments;
 399     require RT::Users;
 400     require RT::Principals;
 401     require RT::CurrentUser;
 402     require RT::Templates;
 403     require RT::Queues;
 404     require RT::ScripActions;
 405     require RT::ScripConditions;
 406     require RT::Scrips;
 407     require RT::Groups;
 408     require RT::GroupMembers;
 409     require RT::CustomFields;
 410     require RT::CustomFieldValues;
 411     require RT::ObjectCustomFields;
 412     require RT::ObjectCustomFieldValues;
 413     require RT::Attributes;
 414     require RT::Dashboard;
 415     require RT::Approval;
 416     require RT::Lifecycle;
 417     require RT::Link;
 418     require RT::Links;
 419     require RT::Article;
 420     require RT::Articles;
 421     require RT::Class;
 422     require RT::Classes;
 423     require RT::ObjectClass;
 424     require RT::ObjectClasses;
 425     require RT::ObjectTopic;
 426     require RT::ObjectTopics;
 427     require RT::Topic;
 428     require RT::Topics;
 429
 430     # on a cold server (just after restart) people could have an object
 431     # in the session, as we deserialize it so we never call constructor
 432     # of the class, so the list of accessible fields is empty and we die
 433     # with "Method xxx is not implemented in RT::SomeClass"
 434
 435     # without this, we also can never call _ClassAccessible, because we
 436     # won't have filled RT::Record::_TABLE_ATTR
 437     $_->_BuildTableAttributes foreach qw(
 438         RT::Ticket
 439         RT::Transaction
 440         RT::Attachment
 441         RT::User
 442         RT::Principal
 443         RT::Template
 444         RT::Queue
 445         RT::ScripAction
 446         RT::ScripCondition
 447         RT::Scrip
 448         RT::Group
 449         RT::GroupMember
 450         RT::CustomField
 451         RT::CustomFieldValue
 452         RT::ObjectCustomField
 453         RT::ObjectCustomFieldValue
 454         RT::Attribute
 455         RT::ACE
 456         RT::Link
 457         RT::Article
 458         RT::Class
 459         RT::ObjectClass
 460         RT::ObjectTopic
 461         RT::Topic
 462     );
 463
 464     if ( $args{'Heavy'} ) {
 465         # load scrips' modules
 466         my $scrips = RT::Scrips->new(RT->SystemUser);
 467         $scrips->Limit( FIELD => 'Stage', OPERATOR => '!=', VALUE => 'Disabled' );
 468         while ( my $scrip = $scrips->Next ) {
 469             local $@;
 470             eval { $scrip->LoadModules } or
 471                 $RT::Logger->error("Invalid Scrip ".$scrip->Id.".  Unable to load the Action or Condition.  ".
 472                                    "You should delete or repair this Scrip in the admin UI.\n$@\n");
 473         }
 474
 475         foreach my $class ( grep $_, RT->Config->Get('CustomFieldValuesSources') ) {
 476             local $@;
 477             eval "require $class; 1" or $RT::Logger->error(
 478                 "Class '$class' is listed in CustomFieldValuesSources option"
 479                 ." in the config, but we failed to load it:\n$@\n"
 480             );
 481         }
 482
 483     }
 484 }
 485
 486 =head2 InitSystemObjects
 487
 488 Initializes system objects: C<$RT::System>, C<< RT->SystemUser >>
 489 and C<< RT->Nobody >>.
 490
 491 =cut
 492
 493 sub InitSystemObjects {
 494
 495     #RT's system user is a genuine database user. its id lives here
 496     require RT::CurrentUser;
 497     $SystemUser = RT::CurrentUser->new;
 498     $SystemUser->LoadByName('RT_System');
 499
 500     #RT's "nobody user" is a genuine database user. its ID lives here.
 501     $Nobody = RT::CurrentUser->new;
 502     $Nobody->LoadByName('Nobody');
 503
 504     require RT::System;
 505     $System = RT::System->new( $SystemUser );
 506 }
 507
 508 =head1 CLASS METHODS
 509
 510 =head2 Config
 511
 512 Returns the current L<config object|RT::Config>, but note that
 513 you must L<load config|/LoadConfig> first otherwise this method
 514 returns undef.
 515
 516 Method can be called as class method.
 517
 518 =cut
 519
 520 sub Config { return $Config || shift->LoadConfig(); }
 521
 522 =head2 DatabaseHandle
 523
 524 Returns the current L<database handle object|RT::Handle>.
 525
 526 See also L</ConnectToDatabase>.
 527
 528 =cut
 529
 530 sub DatabaseHandle { return $Handle }
 531
 532 =head2 Logger
 533
 534 Returns the logger. See also L</InitLogging>.
 535
 536 =cut
 537
 538 sub Logger { return $Logger }
 539
 540 =head2 System
 541
 542 Returns the current L<system object|RT::System>. See also
 543 L</InitSystemObjects>.
 544
 545 =cut
 546
 547 sub System { return $System }
 548
 549 =head2 SystemUser
 550
 551 Returns the system user's object, it's object of
 552 L<RT::CurrentUser> class that represents the system. See also
 553 L</InitSystemObjects>.
 554
 555 =cut
 556
 557 sub SystemUser { return $SystemUser }
 558
 559 =head2 Nobody
 560
 561 Returns object of Nobody. It's object of L<RT::CurrentUser> class
 562 that represents a user who can own ticket and nothing else. See
 563 also L</InitSystemObjects>.
 564
 565 =cut
 566
 567 sub Nobody { return $Nobody }
 568
 569 sub PrivilegedUsers {
 570     if (!$_Privileged) {
 571     $_Privileged = RT::Group->new(RT->SystemUser);
 572     $_Privileged->LoadSystemInternalGroup('Privileged');
 573     }
 574     return $_Privileged;
 575 }
 576
 577 sub UnprivilegedUsers {
 578     if (!$_Unprivileged) {
 579     $_Unprivileged = RT::Group->new(RT->SystemUser);
 580     $_Unprivileged->LoadSystemInternalGroup('Unprivileged');
 581     }
 582     return $_Unprivileged;
 583 }
 584
 585
 586 =head2 Plugins
 587
 588 Returns a listref of all Plugins currently configured for this RT instance.
 589 You can define plugins by adding them to the @Plugins list in your RT_SiteConfig
 590
 591 =cut
 592
 593 our @PLUGINS = ();
 594 sub Plugins {
 595     my $self = shift;
 596     unless (@PLUGINS) {
 597         $self->InitPluginPaths;
 598         @PLUGINS = $self->InitPlugins;
 599     }
 600     return \@PLUGINS;
 601 }
 602
 603 =head2 PluginDirs
 604
 605 Takes an optional subdir (e.g. po, lib, etc.) and returns a list of
 606 directories from plugins where that subdirectory exists.
 607
 608 This code does not check plugin names, plugin validitity, or load
 609 plugins (see L</InitPlugins>) in any way, and requires that RT's
 610 configuration have been already loaded.
 611
 612 =cut
 613
 614 sub PluginDirs {
 615     my $self = shift;
 616     my $subdir = shift;
 617
 618     require RT::Plugin;
 619
 620     my @res;
 621     foreach my $plugin (grep $_, RT->Config->Get('Plugins')) {
 622         my $path = RT::Plugin->new( name => $plugin )->Path( $subdir );
 623         next unless -d $path;
 624         push @res, $path;
 625     }
 626     return @res;
 627 }
 628
 629 =head2 InitPluginPaths
 630
 631 Push plugins' lib paths into @INC right after F<local/lib>.
 632 In case F<local/lib> isn't in @INC, append them to @INC
 633
 634 =cut
 635
 636 sub InitPluginPaths {
 637     my $self = shift || __PACKAGE__;
 638
 639     my @lib_dirs = $self->PluginDirs('lib');
 640
 641     my @tmp_inc;
 642     my $added;
 643     for (@INC) {
 644         if ( Cwd::realpath($_) eq $RT::LocalLibPath) {
 645             push @tmp_inc, $_, @lib_dirs;
 646             $added = 1;
 647         } else {
 648             push @tmp_inc, $_;
 649         }
 650     }
 651
 652     # append @lib_dirs in case $RT::LocalLibPath isn't in @INC
 653     push @tmp_inc, @lib_dirs unless $added;
 654
 655     my %seen;
 656     @INC = grep !$seen{$_}++, @tmp_inc;
 657 }
 658
 659 =head2 InitPlugins
 660
 661 Initialize all Plugins found in the RT configuration file, setting up
 662 their lib and L<HTML::Mason> component roots.
 663
 664 =cut
 665
 666 sub InitPlugins {
 667     my $self    = shift;
 668     my @plugins;
 669     require RT::Plugin;
 670     foreach my $plugin (grep $_, RT->Config->Get('Plugins')) {
 671         $plugin->require;
 672         die $UNIVERSAL::require::ERROR if ($UNIVERSAL::require::ERROR);
 673         push @plugins, RT::Plugin->new(name =>$plugin);
 674     }
 675     return @plugins;
 676 }
 677
 678
 679 sub InstallMode {
 680     my $self = shift;
 681     if (@_) {
 682         my ($integrity, $state, $msg) = RT::Handle->CheckIntegrity;
 683         if ($_[0] and $integrity) {
 684             # Trying to turn install mode on but we have a good DB!
 685             require Carp;
 686             $RT::Logger->error(
 687                 Carp::longmess("Something tried to turn on InstallMode but we have DB integrity!")
 688             );
 689         }
 690         else {
 691             $_INSTALL_MODE = shift;
 692             if($_INSTALL_MODE) {
 693                 require RT::CurrentUser;
 694                $SystemUser = RT::CurrentUser->new();
 695             }
 696         }
 697     }
 698     return $_INSTALL_MODE;
 699 }
 700
 701 sub LoadGeneratedData {
 702     my $class = shift;
 703     my $pm_path = ( File::Spec->splitpath( $INC{'RT.pm'} ) )[1];
 704
 705     require "$pm_path/RT/Generated.pm" || die "Couldn't load RT::Generated: $@";
 706     $class->CanonicalizeGeneratedPaths();
 707 }
 708
 709 sub CanonicalizeGeneratedPaths {
 710     my $class = shift;
 711     unless ( File::Spec->file_name_is_absolute($EtcPath) ) {
 712
 713    # if BasePath exists and is absolute, we won't infer it from $INC{'RT.pm'}.
 714    # otherwise RT.pm will make the source dir(where we configure RT) be the
 715    # BasePath instead of the one specified by --prefix
 716         unless ( -d $BasePath
 717                  && File::Spec->file_name_is_absolute($BasePath) )
 718         {
 719             my $pm_path = ( File::Spec->splitpath( $INC{'RT.pm'} ) )[1];
 720
 721      # need rel2abs here is to make sure path is absolute, since $INC{'RT.pm'}
 722      # is not always absolute
 723             $BasePath = File::Spec->rel2abs(
 724                           File::Spec->catdir( $pm_path, File::Spec->updir ) );
 725         }
 726
 727         $BasePath = Cwd::realpath($BasePath);
 728
 729         for my $path (
 730                     qw/EtcPath BinPath SbinPath VarPath LocalPath LocalEtcPath
 731                     LocalLibPath LexiconPath LocalLexiconPath PluginPath
 732                     LocalPluginPath MasonComponentRoot MasonLocalComponentRoot
 733                     MasonDataDir MasonSessionDir/
 734                      )
 735         {
 736             no strict 'refs';
 737
 738             # just change relative ones
 739             $$path = File::Spec->catfile( $BasePath, $$path )
 740                 unless File::Spec->file_name_is_absolute($$path);
 741         }
 742     }
 743
 744 }
 745
 746 =head2 AddJavaScript
 747
 748 helper method to add js files to C<JSFiles> config.
 749 to add extra js files, you can add the following line
 750 in the plugin's main file:
 751
 752     RT->AddJavaScript( 'foo.js', 'bar.js' );
 753
 754 =cut
 755
 756 sub AddJavaScript {
 757     my $self = shift;
 758
 759     my @old = RT->Config->Get('JSFiles');
 760     RT->Config->Set( 'JSFiles', @old, @_ );
 761     return RT->Config->Get('JSFiles');
 762 }
 763
 764 =head2 AddStyleSheets
 765
 766 helper method to add css files to C<CSSFiles> config
 767
 768 to add extra css files, you can add the following line
 769 in the plugin's main file:
 770
 771     RT->AddStyleSheets( 'foo.css', 'bar.css' );
 772
 773 =cut
 774
 775 sub AddStyleSheets {
 776     my $self = shift;
 777     my @old = RT->Config->Get('CSSFiles');
 778     RT->Config->Set( 'CSSFiles', @old, @_ );
 779     return RT->Config->Get('CSSFiles');
 780 }
 781
 782 =head2 JavaScript
 783
 784 helper method of RT->Config->Get('JSFiles')
 785
 786 =cut
 787
 788 sub JavaScript {
 789     return RT->Config->Get('JSFiles');
 790 }
 791
 792 =head2 StyleSheets
 793
 794 helper method of RT->Config->Get('CSSFiles')
 795
 796 =cut
 797
 798 sub StyleSheets {
 799     return RT->Config->Get('CSSFiles');
 800 }
 801
 802 =head1 BUGS
 803
 804 Please report them to rt-bugs@bestpractical.com, if you know what's
 805 broken and have at least some idea of what needs to be fixed.
 806
 807 If you're not sure what's going on, report them rt-devel@lists.bestpractical.com.
 808
 809 =head1 SEE ALSO
 810
 811 L<RT::StyleGuide>
 812 L<DBIx::SearchBuilder>
 813
 814 =cut
 815
 816 require RT::Base;
 817 RT::Base->_ImportOverlays();
 818
 819 1;