rt/lib/RT.pm

   1 # BEGIN BPS TAGGED BLOCK {{{
   2 #
   3 # COPYRIGHT:
   4 #
   5 # This software is Copyright (c) 1996-2012 Best Practical Solutions, LLC
   6 #                                          <sales@bestpractical.com>
   7 #
   8 # (Except where explicitly superseded by other copyright notices)
   9 #
  10 #
  11 # LICENSE:
  12 #
  13 # This work is made available to you under the terms of Version 2 of
  14 # the GNU General Public License. A copy of that license should have
  15 # been provided with this software, but in any event can be snarfed
  16 # from www.gnu.org.
  17 #
  18 # This work is distributed in the hope that it will be useful, but
  19 # WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  21 # General Public License for more details.
  22 #
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  26 # 02110-1301 or visit their web page on the internet at
  27 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  28 #
  29 #
  30 # CONTRIBUTION SUBMISSION POLICY:
  31 #
  32 # (The following paragraph is not intended to limit the rights granted
  33 # to you to modify and distribute this software under the terms of
  34 # the GNU General Public License and is only of importance to you if
  35 # you choose to contribute your changes and enhancements to the
  36 # community by submitting them to Best Practical Solutions, LLC.)
  37 #
  38 # By intentionally submitting any modifications, corrections or
  39 # derivatives to this work, or any other work intended for use with
  40 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  41 # you are the copyright holder for those contributions and you grant
  42 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  43 # royalty-free, perpetual, license to use, copy, create derivative
  44 # works based on those contributions, and sublicense and distribute
  45 # those contributions and any derivatives thereof.
  46 #
  47 # END BPS TAGGED BLOCK }}}
  48
  49 use strict;
  50 use warnings;
  51
  52 package RT;
  53
  54
  55 use File::Spec ();
  56 use Cwd ();
  57
  58 use vars qw($Config $System $SystemUser $Nobody $Handle $Logger $_Privileged $_Unprivileged $_INSTALL_MODE);
  59
  60 use vars qw($BasePath
  61  $EtcPath
  62  $BinPath
  63  $SbinPath
  64  $VarPath
  65  $LexiconPath
  66  $PluginPath
  67  $LocalPath
  68  $LocalEtcPath
  69  $LocalLibPath
  70  $LocalLexiconPath
  71  $LocalPluginPath
  72  $MasonComponentRoot
  73  $MasonLocalComponentRoot
  74  $MasonDataDir
  75  $MasonSessionDir);
  76
  77
  78 RT->LoadGeneratedData();
  79
  80 =head1 NAME
  81
  82 RT - Request Tracker
  83
  84 =head1 SYNOPSIS
  85
  86 A fully featured request tracker package
  87
  88 =head1 DESCRIPTION
  89
  90 =head2 INITIALIZATION
  91
  92 =head2 LoadConfig
  93
  94 Load RT's config file.  First, the site configuration file
  95 (F<RT_SiteConfig.pm>) is loaded, in order to establish overall site
  96 settings like hostname and name of RT instance.  Then, the core
  97 configuration file (F<RT_Config.pm>) is loaded to set fallback values
  98 for all settings; it bases some values on settings from the site
  99 configuration file.
 100
 101 In order for the core configuration to not override the site's
 102 settings, the function C<Set> is used; it only sets values if they
 103 have not been set already.
 104
 105 =cut
 106
 107 sub LoadConfig {
 108     require RT::Config;
 109     $Config = RT::Config->new;
 110     $Config->LoadConfigs;
 111     require RT::I18N;
 112
 113     # RT::Essentials mistakenly recommends that WebPath be set to '/'.
 114     # If the user does that, do what they mean.
 115     $RT::WebPath = '' if ($RT::WebPath eq '/');
 116
 117     # fix relative LogDir and GnuPG homedir
 118     unless ( File::Spec->file_name_is_absolute( $Config->Get('LogDir') ) ) {
 119         $Config->Set( LogDir =>
 120               File::Spec->catfile( $BasePath, $Config->Get('LogDir') ) );
 121     }
 122
 123     my $gpgopts = $Config->Get('GnuPGOptions');
 124     unless ( File::Spec->file_name_is_absolute( $gpgopts->{homedir} ) ) {
 125         $gpgopts->{homedir} = File::Spec->catfile( $BasePath, $gpgopts->{homedir} );
 126     }
 127
 128     return $Config;
 129 }
 130
 131 =head2 Init
 132
 133 L<Connects to the database|/ConnectToDatabase>, L<initilizes system
 134 objects|/InitSystemObjects>, L<preloads classes|/InitClasses>, L<sets
 135 up logging|/InitLogging>, and L<loads plugins|/InitPlugins>.
 136
 137 =cut
 138
 139 sub Init {
 140
 141     my @arg = @_;
 142
 143     CheckPerlRequirements();
 144
 145     InitPluginPaths();
 146
 147     #Get a database connection
 148     ConnectToDatabase();
 149     InitSystemObjects();
 150     InitClasses();
 151     InitLogging(@arg);
 152     InitPlugins();
 153     RT::I18N->Init;
 154     RT->Config->PostLoadCheck;
 155
 156 }
 157
 158 =head2 ConnectToDatabase
 159
 160 Get a database connection. See also L</Handle>.
 161
 162 =cut
 163
 164 sub ConnectToDatabase {
 165     require RT::Handle;
 166     $Handle = RT::Handle->new unless $Handle;
 167     $Handle->Connect;
 168     return $Handle;
 169 }
 170
 171 =head2 InitLogging
 172
 173 Create the Logger object and set up signal handlers.
 174
 175 =cut
 176
 177 sub InitLogging {
 178
 179     my %arg = @_;
 180
 181     # We have to set the record separator ($, man perlvar)
 182     # or Log::Dispatch starts getting
 183     # really pissy, as some other module we use unsets it.
 184     $, = '';
 185     use Log::Dispatch 1.6;
 186
 187     my %level_to_num = (
 188         map( { $_ => } 0..7 ),
 189         debug     => 0,
 190         info      => 1,
 191         notice    => 2,
 192         warning   => 3,
 193         error     => 4, 'err' => 4,
 194         critical  => 5, crit  => 5,
 195         alert     => 6,
 196         emergency => 7, emerg => 7,
 197     );
 198
 199     unless ( $RT::Logger ) {
 200
 201         $RT::Logger = Log::Dispatch->new;
 202
 203         my $stack_from_level;
 204         if ( $stack_from_level = RT->Config->Get('LogStackTraces') ) {
 205             # if option has old style '\d'(true) value
 206             $stack_from_level = 0 if $stack_from_level =~ /^\d+$/;
 207             $stack_from_level = $level_to_num{ $stack_from_level } || 0;
 208         } else {
 209             $stack_from_level = 99; # don't log
 210         }
 211
 212         my $simple_cb = sub {
 213             # if this code throw any warning we can get segfault
 214             no warnings;
 215             my %p = @_;
 216
 217             # skip Log::* stack frames
 218             my $frame = 0;
 219             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 220             my ($package, $filename, $line) = caller($frame);
 221
 222             $p{'message'} =~ s/(?:\r*\n)+$//;
 223             return "[". gmtime(time) ."] [". $p{'level'} ."]: "
 224                 . $p{'message'} ." ($filename:$line)\n";
 225         };
 226
 227         my $syslog_cb = sub {
 228             # if this code throw any warning we can get segfault
 229             no warnings;
 230             my %p = @_;
 231
 232             my $frame = 0; # stack frame index
 233             # skip Log::* stack frames
 234             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 235             my ($package, $filename, $line) = caller($frame);
 236
 237             # syswrite() cannot take utf8; turn it off here.
 238             Encode::_utf8_off($p{message});
 239
 240             $p{message} =~ s/(?:\r*\n)+$//;
 241             if ($p{level} eq 'debug') {
 242                 return "$p{message}\n";
 243             } else {
 244                 return "$p{message} ($filename:$line)\n";
 245             }
 246         };
 247
 248         my $stack_cb = sub {
 249             no warnings;
 250             my %p = @_;
 251             return $p{'message'} unless $level_to_num{ $p{'level'} } >= $stack_from_level;
 252
 253             require Devel::StackTrace;
 254             my $trace = Devel::StackTrace->new( ignore_class => [ 'Log::Dispatch', 'Log::Dispatch::Base' ] );
 255             return $p{'message'} . $trace->as_string;
 256
 257             # skip calling of the Log::* subroutins
 258             my $frame = 0;
 259             $frame++ while caller($frame) && caller($frame) =~ /^Log::/;
 260             $frame++ while caller($frame) && (caller($frame))[3] =~ /^Log::/;
 261
 262             $p{'message'} .= "\nStack trace:\n";
 263             while( my ($package, $filename, $line, $sub) = caller($frame++) ) {
 264                 $p{'message'} .= "\t$sub(...) called at $filename:$line\n";
 265             }
 266             return $p{'message'};
 267         };
 268
 269         if ( $Config->Get('LogToFile') ) {
 270             my ($filename, $logdir) = (
 271                 $Config->Get('LogToFileNamed') || 'rt.log',
 272                 $Config->Get('LogDir') || File::Spec->catdir( $VarPath, 'log' ),
 273             );
 274             if ( $filename =~ m![/\\]! ) { # looks like an absolute path.
 275                 ($logdir) = $filename =~ m{^(.*[/\\])};
 276             }
 277             else {
 278                 $filename = File::Spec->catfile( $logdir, $filename );
 279             }
 280
 281             unless ( -d $logdir && ( ( -f $filename && -w $filename ) || -w $logdir ) ) {
 282                 # localizing here would be hard when we don't have a current user yet
 283                 die "Log file '$filename' couldn't be written or created.\n RT can't run.";
 284             }
 285
 286             require Log::Dispatch::File;
 287             $RT::Logger->add( Log::Dispatch::File->new
 288                            ( name=>'file',
 289                              min_level=> $Config->Get('LogToFile'),
 290                              filename=> $filename,
 291                              mode=>'append',
 292                              callbacks => [ $simple_cb, $stack_cb ],
 293                            ));
 294         }
 295         if ( $Config->Get('LogToScreen') ) {
 296             require Log::Dispatch::Screen;
 297             $RT::Logger->add( Log::Dispatch::Screen->new
 298                          ( name => 'screen',
 299                            min_level => $Config->Get('LogToScreen'),
 300                            callbacks => [ $simple_cb, $stack_cb ],
 301                            stderr => 1,
 302                          ));
 303         }
 304         if ( $Config->Get('LogToSyslog') ) {
 305             require Log::Dispatch::Syslog;
 306             $RT::Logger->add(Log::Dispatch::Syslog->new
 307                          ( name => 'syslog',
 308                            ident => 'RT',
 309                            min_level => $Config->Get('LogToSyslog'),
 310                            callbacks => [ $syslog_cb, $stack_cb ],
 311                            stderr => 1,
 312                            $Config->Get('LogToSyslogConf'),
 313                          ));
 314         }
 315     }
 316     InitSignalHandlers(%arg);
 317 }
 318
 319 sub InitSignalHandlers {
 320
 321     my %arg = @_;
 322
 323 # Signal handlers
 324 ## This is the default handling of warnings and die'ings in the code
 325 ## (including other used modules - maybe except for errors catched by
 326 ## Mason).  It will log all problems through the standard logging
 327 ## mechanism (see above).
 328
 329     unless ( $arg{'NoSignalHandlers'} ) {
 330
 331         $SIG{__WARN__} = sub {
 332             # The 'wide character' warnings has to be silenced for now, at least
 333             # until HTML::Mason offers a sane way to process both raw output and
 334             # unicode strings.
 335             # use 'goto &foo' syntax to hide ANON sub from stack
 336             if( index($_[0], 'Wide character in ') != 0 ) {
 337                 unshift @_, $RT::Logger, qw(level warning message);
 338                 goto &Log::Dispatch::log;
 339             }
 340         };
 341
 342         #When we call die, trap it and log->crit with the value of the die.
 343
 344         $SIG{__DIE__}  = sub {
 345             # if we are not in eval and perl is not parsing code
 346             # then rollback transactions and log RT error
 347             unless ($^S || !defined $^S ) {
 348                 $RT::Handle->Rollback(1) if $RT::Handle;
 349                 $RT::Logger->crit("$_[0]") if $RT::Logger;
 350             }
 351             die $_[0];
 352         };
 353
 354     }
 355 }
 356
 357
 358 sub CheckPerlRequirements {
 359     if ($^V < 5.008003) {
 360         die sprintf "RT requires Perl v5.8.3 or newer.  Your current Perl is v%vd\n", $^V;
 361     }
 362
 363     # use $error here so the following "die" can still affect the global $@
 364     my $error;
 365     {
 366         local $@;
 367         eval {
 368             my $x = '';
 369             my $y = \$x;
 370             require Scalar::Util;
 371             Scalar::Util::weaken($y);
 372         };
 373         $error = $@;
 374     }
 375
 376     if ($error) {
 377         die <<"EOF";
 378
 379 RT requires the Scalar::Util module be built with support for  the 'weaken'
 380 function.
 381
 382 It is sometimes the case that operating system upgrades will replace
 383 a working Scalar::Util with a non-working one. If your system was working
 384 correctly up until now, this is likely the cause of the problem.
 385
 386 Please reinstall Scalar::Util, being careful to let it build with your C
 387 compiler. Usually this is as simple as running the following command as
 388 root.
 389
 390     perl -MCPAN -e'install Scalar::Util'
 391
 392 EOF
 393
 394     }
 395 }
 396
 397 =head2 InitClasses
 398
 399 Load all modules that define base classes.
 400
 401 =cut
 402
 403 sub InitClasses {
 404     shift if @_%2; # so we can call it as a function or method
 405     my %args = (@_);
 406     require RT::Tickets;
 407     require RT::Transactions;
 408     require RT::Attachments;
 409     require RT::Users;
 410     require RT::Principals;
 411     require RT::CurrentUser;
 412     require RT::Templates;
 413     require RT::Queues;
 414     require RT::ScripActions;
 415     require RT::ScripConditions;
 416     require RT::Scrips;
 417     require RT::Groups;
 418     require RT::GroupMembers;
 419     require RT::CustomFields;
 420     require RT::CustomFieldValues;
 421     require RT::ObjectCustomFields;
 422     require RT::ObjectCustomFieldValues;
 423     require RT::Attributes;
 424     require RT::Dashboard;
 425     require RT::Approval;
 426     require RT::Lifecycle;
 427     require RT::Link;
 428     require RT::Article;
 429     require RT::Articles;
 430     require RT::Class;
 431     require RT::Classes;
 432     require RT::ObjectClass;
 433     require RT::ObjectClasses;
 434     require RT::ObjectTopic;
 435     require RT::ObjectTopics;
 436     require RT::Topic;
 437     require RT::Topics;
 438
 439     # on a cold server (just after restart) people could have an object
 440     # in the session, as we deserialize it so we never call constructor
 441     # of the class, so the list of accessible fields is empty and we die
 442     # with "Method xxx is not implemented in RT::SomeClass"
 443
 444     # without this, we also can never call _ClassAccessible, because we
 445     # won't have filled RT::Record::_TABLE_ATTR
 446     $_->_BuildTableAttributes foreach qw(
 447         RT::Ticket
 448         RT::Transaction
 449         RT::Attachment
 450         RT::User
 451         RT::Principal
 452         RT::Template
 453         RT::Queue
 454         RT::ScripAction
 455         RT::ScripCondition
 456         RT::Scrip
 457         RT::Group
 458         RT::GroupMember
 459         RT::CustomField
 460         RT::CustomFieldValue
 461         RT::ObjectCustomField
 462         RT::ObjectCustomFieldValue
 463         RT::Attribute
 464         RT::ACE
 465         RT::Link
 466         RT::Article
 467         RT::Class
 468         RT::ObjectClass
 469         RT::ObjectTopic
 470         RT::Topic
 471     );
 472
 473     if ( $args{'Heavy'} ) {
 474         # load scrips' modules
 475         my $scrips = RT::Scrips->new(RT->SystemUser);
 476         $scrips->Limit( FIELD => 'Stage', OPERATOR => '!=', VALUE => 'Disabled' );
 477         while ( my $scrip = $scrips->Next ) {
 478             local $@;
 479             eval { $scrip->LoadModules } or
 480                 $RT::Logger->error("Invalid Scrip ".$scrip->Id.".  Unable to load the Action or Condition.  ".
 481                                    "You should delete or repair this Scrip in the admin UI.\n$@\n");
 482         }
 483
 484         foreach my $class ( grep $_, RT->Config->Get('CustomFieldValuesSources') ) {
 485             local $@;
 486             eval "require $class; 1" or $RT::Logger->error(
 487                 "Class '$class' is listed in CustomFieldValuesSources option"
 488                 ." in the config, but we failed to load it:\n$@\n"
 489             );
 490         }
 491
 492     }
 493 }
 494
 495 =head2 InitSystemObjects
 496
 497 Initializes system objects: C<$RT::System>, C<< RT->SystemUser >>
 498 and C<< RT->Nobody >>.
 499
 500 =cut
 501
 502 sub InitSystemObjects {
 503
 504     #RT's system user is a genuine database user. its id lives here
 505     require RT::CurrentUser;
 506     $SystemUser = RT::CurrentUser->new;
 507     $SystemUser->LoadByName('RT_System');
 508
 509     #RT's "nobody user" is a genuine database user. its ID lives here.
 510     $Nobody = RT::CurrentUser->new;
 511     $Nobody->LoadByName('Nobody');
 512
 513     require RT::System;
 514     $System = RT::System->new( $SystemUser );
 515 }
 516
 517 =head1 CLASS METHODS
 518
 519 =head2 Config
 520
 521 Returns the current L<config object|RT::Config>, but note that
 522 you must L<load config|/LoadConfig> first otherwise this method
 523 returns undef.
 524
 525 Method can be called as class method.
 526
 527 =cut
 528
 529 sub Config { return $Config || shift->LoadConfig(); }
 530
 531 =head2 DatabaseHandle
 532
 533 Returns the current L<database handle object|RT::Handle>.
 534
 535 See also L</ConnectToDatabase>.
 536
 537 =cut
 538
 539 sub DatabaseHandle { return $Handle }
 540
 541 =head2 Logger
 542
 543 Returns the logger. See also L</InitLogging>.
 544
 545 =cut
 546
 547 sub Logger { return $Logger }
 548
 549 =head2 System
 550
 551 Returns the current L<system object|RT::System>. See also
 552 L</InitSystemObjects>.
 553
 554 =cut
 555
 556 sub System { return $System }
 557
 558 =head2 SystemUser
 559
 560 Returns the system user's object, it's object of
 561 L<RT::CurrentUser> class that represents the system. See also
 562 L</InitSystemObjects>.
 563
 564 =cut
 565
 566 sub SystemUser { return $SystemUser }
 567
 568 =head2 Nobody
 569
 570 Returns object of Nobody. It's object of L<RT::CurrentUser> class
 571 that represents a user who can own ticket and nothing else. See
 572 also L</InitSystemObjects>.
 573
 574 =cut
 575
 576 sub Nobody { return $Nobody }
 577
 578 sub PrivilegedUsers {
 579     if (!$_Privileged) {
 580     $_Privileged = RT::Group->new(RT->SystemUser);
 581     $_Privileged->LoadSystemInternalGroup('Privileged');
 582     }
 583     return $_Privileged;
 584 }
 585
 586 sub UnprivilegedUsers {
 587     if (!$_Unprivileged) {
 588     $_Unprivileged = RT::Group->new(RT->SystemUser);
 589     $_Unprivileged->LoadSystemInternalGroup('Unprivileged');
 590     }
 591     return $_Unprivileged;
 592 }
 593
 594
 595 =head2 Plugins
 596
 597 Returns a listref of all Plugins currently configured for this RT instance.
 598 You can define plugins by adding them to the @Plugins list in your RT_SiteConfig
 599
 600 =cut
 601
 602 our @PLUGINS = ();
 603 sub Plugins {
 604     my $self = shift;
 605     unless (@PLUGINS) {
 606         $self->InitPluginPaths;
 607         @PLUGINS = $self->InitPlugins;
 608     }
 609     return \@PLUGINS;
 610 }
 611
 612 =head2 PluginDirs
 613
 614 Takes an optional subdir (e.g. po, lib, etc.) and returns a list of
 615 directories from plugins where that subdirectory exists.
 616
 617 This code does not check plugin names, plugin validitity, or load
 618 plugins (see L</InitPlugins>) in any way, and requires that RT's
 619 configuration have been already loaded.
 620
 621 =cut
 622
 623 sub PluginDirs {
 624     my $self = shift;
 625     my $subdir = shift;
 626
 627     require RT::Plugin;
 628
 629     my @res;
 630     foreach my $plugin (grep $_, RT->Config->Get('Plugins')) {
 631         my $path = RT::Plugin->new( name => $plugin )->Path( $subdir );
 632         next unless -d $path;
 633         push @res, $path;
 634     }
 635     return @res;
 636 }
 637
 638 =head2 InitPluginPaths
 639
 640 Push plugins' lib paths into @INC right after F<local/lib>.
 641 In case F<local/lib> isn't in @INC, append them to @INC
 642
 643 =cut
 644
 645 sub InitPluginPaths {
 646     my $self = shift || __PACKAGE__;
 647
 648     my @lib_dirs = $self->PluginDirs('lib');
 649
 650     my @tmp_inc;
 651     my $added;
 652     for (@INC) {
 653         if ( Cwd::realpath($_) eq $RT::LocalLibPath) {
 654             push @tmp_inc, $_, @lib_dirs;
 655             $added = 1;
 656         } else {
 657             push @tmp_inc, $_;
 658         }
 659     }
 660
 661     # append @lib_dirs in case $RT::LocalLibPath isn't in @INC
 662     push @tmp_inc, @lib_dirs unless $added;
 663
 664     my %seen;
 665     @INC = grep !$seen{$_}++, @tmp_inc;
 666 }
 667
 668 =head2 InitPlugins
 669
 670 Initialize all Plugins found in the RT configuration file, setting up
 671 their lib and L<HTML::Mason> component roots.
 672
 673 =cut
 674
 675 sub InitPlugins {
 676     my $self    = shift;
 677     my @plugins;
 678     require RT::Plugin;
 679     foreach my $plugin (grep $_, RT->Config->Get('Plugins')) {
 680         $plugin->require;
 681         die $UNIVERSAL::require::ERROR if ($UNIVERSAL::require::ERROR);
 682         push @plugins, RT::Plugin->new(name =>$plugin);
 683     }
 684     return @plugins;
 685 }
 686
 687
 688 sub InstallMode {
 689     my $self = shift;
 690     if (@_) {
 691          $_INSTALL_MODE = shift;
 692          if($_INSTALL_MODE) {
 693              require RT::CurrentUser;
 694             $SystemUser = RT::CurrentUser->new();
 695          }
 696     }
 697     return $_INSTALL_MODE;
 698 }
 699
 700 sub LoadGeneratedData {
 701     my $class = shift;
 702     my $pm_path = ( File::Spec->splitpath( $INC{'RT.pm'} ) )[1];
 703
 704     require "$pm_path/RT/Generated.pm" || die "Couldn't load RT::Generated: $@";
 705     $class->CanonicalizeGeneratedPaths();
 706 }
 707
 708 sub CanonicalizeGeneratedPaths {
 709     my $class = shift;
 710     unless ( File::Spec->file_name_is_absolute($EtcPath) ) {
 711
 712    # if BasePath exists and is absolute, we won't infer it from $INC{'RT.pm'}.
 713    # otherwise RT.pm will make the source dir(where we configure RT) be the
 714    # BasePath instead of the one specified by --prefix
 715         unless ( -d $BasePath
 716                  && File::Spec->file_name_is_absolute($BasePath) )
 717         {
 718             my $pm_path = ( File::Spec->splitpath( $INC{'RT.pm'} ) )[1];
 719
 720      # need rel2abs here is to make sure path is absolute, since $INC{'RT.pm'}
 721      # is not always absolute
 722             $BasePath = File::Spec->rel2abs(
 723                           File::Spec->catdir( $pm_path, File::Spec->updir ) );
 724         }
 725
 726         $BasePath = Cwd::realpath($BasePath);
 727
 728         for my $path (
 729                     qw/EtcPath BinPath SbinPath VarPath LocalPath LocalEtcPath
 730                     LocalLibPath LexiconPath LocalLexiconPath PluginPath
 731                     LocalPluginPath MasonComponentRoot MasonLocalComponentRoot
 732                     MasonDataDir MasonSessionDir/
 733                      )
 734         {
 735             no strict 'refs';
 736
 737             # just change relative ones
 738             $$path = File::Spec->catfile( $BasePath, $$path )
 739                 unless File::Spec->file_name_is_absolute($$path);
 740         }
 741     }
 742
 743 }
 744
 745 =head2 AddJavaScript
 746
 747 helper method to add js files to C<JSFiles> config.
 748 to add extra css files, you can add the following line
 749 in the plugin's main file:
 750
 751     RT->AddJavaScript( 'foo.js', 'bar.js' );
 752
 753 =cut
 754
 755 sub AddJavaScript {
 756     my $self = shift;
 757
 758     my @old = RT->Config->Get('JSFiles');
 759     RT->Config->Set( 'JSFiles', @old, @_ );
 760     return RT->Config->Get('JSFiles');
 761 }
 762
 763 =head2 AddStyleSheets
 764
 765 helper method to add css files to C<CSSFiles> config
 766
 767 to add extra css files, you can add the following line
 768 in the plugin's main file:
 769
 770     RT->AddStyleSheets( 'foo.css', 'bar.css' );
 771
 772 =cut
 773
 774 sub AddStyleSheets {
 775     my $self = shift;
 776     my @old = RT->Config->Get('CSSFiles');
 777     RT->Config->Set( 'CSSFiles', @old, @_ );
 778     return RT->Config->Get('CSSFiles');
 779 }
 780
 781 =head2 JavaScript
 782
 783 helper method of RT->Config->Get('JSFiles')
 784
 785 =cut
 786
 787 sub JavaScript {
 788     return RT->Config->Get('JSFiles');
 789 }
 790
 791 =head2 StyleSheets
 792
 793 helper method of RT->Config->Get('CSSFiles')
 794
 795 =cut
 796
 797 sub StyleSheets {
 798     return RT->Config->Get('CSSFiles');
 799 }
 800
 801 =head1 BUGS
 802
 803 Please report them to rt-bugs@bestpractical.com, if you know what's
 804 broken and have at least some idea of what needs to be fixed.
 805
 806 If you're not sure what's going on, report them rt-devel@lists.bestpractical.com.
 807
 808 =head1 SEE ALSO
 809
 810 L<RT::StyleGuide>
 811 L<DBIx::SearchBuilder>
 812
 813 =cut
 814
 815 require RT::Base;
 816 RT::Base->_ImportOverlays();
 817
 818 1;