rt/bin/webmux.pl.in

   1 #!@PERL@
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2013 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 use strict;
  50 local $ENV{'PATH'}   = '/bin:/usr/bin';                   # or whatever you need
  51 local $ENV{'CDPATH'} = '' if defined $ENV{'CDPATH'};
  52 local $ENV{'SHELL'}  = '/bin/sh' if defined $ENV{'SHELL'};
  53 local $ENV{'ENV'}    = '' if defined $ENV{'ENV'};
  54 local $ENV{'IFS'}    = '' if defined $ENV{'IFS'};
  55
  56 package HTML::Mason::Commands;
  57 our %session;
  58
  59 package RT::Mason;
  60
  61 our ($Nobody, $SystemUser, $Handler, $r);
  62
  63 my $protect_fds;
  64
  65 sub handler {
  66     ($r) = @_;
  67
  68     if ( !$protect_fds && $ENV{'MOD_PERL'} && exists $ENV{'MOD_PERL_API_VERSION'}
  69         && $ENV{'MOD_PERL_API_VERSION'} >= 2
  70     ) {
  71         # under mod_perl2, STDIN and STDOUT get closed and re-opened,
  72         # however they are not on FD 0 and 1.  In this case, the next
  73         # socket that gets opened will occupy one of these FDs, and make
  74         # all system() and open "|-" calls dangerous; for example, the
  75         # DBI handle can get this FD, which later system() calls will
  76         # close by putting garbage into the socket.
  77         $protect_fds = [];
  78         push @{$protect_fds}, IO::Handle->new_from_fd(0, "r")
  79             if fileno(STDIN) != 0;
  80         push @{$protect_fds}, IO::Handle->new_from_fd(1, "w")
  81             if fileno(STDOUT) != 1;
  82     }
  83
  84     local $SIG{__WARN__};
  85     local $SIG{__DIE__};
  86     RT::InitSignalHandlers();
  87
  88     if ($r->content_type =~ m/^httpd\b.*\bdirectory/i) {
  89         use File::Spec::Unix;
  90         # Our DirectoryIndex is always index.html, regardless of httpd settings
  91         $r->filename( File::Spec::Unix->catfile( $r->filename, 'index.html' ) );
  92     }
  93
  94     Module::Refresh->refresh if RT->Config->Get('DevelMode');
  95
  96     RT::ConnectToDatabase();
  97
  98     # none of the methods in $r gives us the information we want (most
  99     # canonicalize /foo/../bar to /bar which is exactly what we want to avoid)
 100     my (undef, $requested) = split ' ', $r->the_request, 3;
 101     my $uri = URI->new("http://".$r->hostname.$requested);
 102     my $path = URI::Escape::uri_unescape($uri->path);
 103
 104     ## Each environment has its own way of handling .. and so on in paths,
 105     ## so RT consistently forbids such paths.
 106     if ( $path =~ m{/\.} ) {
 107         $RT::Logger->crit("Invalid request for ".$path." aborting");
 108         RT::Interface::Web::Handler->CleanupRequest();
 109         return 400;
 110     }
 111
 112     my (%session, $status);
 113     {
 114         local $@;
 115         $status = eval { $Handler->handle_request($r) };
 116         $RT::Logger->crit( $@ ) if $@;
 117     }
 118     undef %session;
 119
 120     RT::Interface::Web::Handler->CleanupRequest();
 121
 122     return $status;
 123 }
 124
 125 package main;
 126
 127 # check mod_perl version if it's mod_perl
 128 BEGIN {
 129     die "RT does not support mod_perl 1.99. Please upgrade to mod_perl 2.0"
 130         if $ENV{'MOD_PERL'}
 131         and $ENV{'MOD_PERL'} =~ m{mod_perl/(?:1\.9)};
 132 }
 133
 134 require CGI;
 135 CGI->import(qw(-private_tempfiles));
 136
 137 # fix lib paths, some may be relative
 138 BEGIN {
 139     require File::Spec;
 140     my @libs = ("@RT_LIB_PATH@", "@LOCAL_LIB_PATH@");
 141     my $bin_path;
 142
 143     for my $lib (@libs) {
 144         unless ( File::Spec->file_name_is_absolute($lib) ) {
 145             unless ($bin_path) {
 146                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
 147                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
 148                 }
 149                 else {
 150                     require FindBin;
 151                     no warnings "once";
 152                     $bin_path = $FindBin::Bin;
 153                 }
 154             }
 155             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
 156         }
 157         unshift @INC, $lib;
 158     }
 159
 160 }
 161
 162 require RT;
 163 die "Wrong version of RT $RT::Version found; need @RT_VERSION_MAJOR@.@RT_VERSION_MINOR@.*"
 164     unless $RT::VERSION =~ /^@RT_VERSION_MAJOR@\.@RT_VERSION_MINOR@\./;
 165 RT::LoadConfig();
 166 if ( RT->Config->Get('DevelMode') ) {
 167     require Module::Refresh;
 168 }
 169 RT::Init();
 170
 171 # check compatibility of the DB
 172 {
 173     my $dbh = $RT::Handle->dbh;
 174     if ( $dbh ) {
 175         my ($status, $msg) = $RT::Handle->CheckCompatibility( $dbh, 'post' );
 176         die $msg unless $status;
 177     }
 178 }
 179
 180 require RT::Interface::Web::Handler;
 181 $RT::Mason::Handler = RT::Interface::Web::Handler->new(
 182     RT->Config->Get('MasonParameters')
 183 );
 184
 185 # load more for mod_perl before forking
 186 RT::InitClasses( Heavy => 1 ) if $ENV{'MOD_PERL'} || $ENV{RT_WEBMUX_HEAVY_LOAD};
 187
 188 # we must disconnect DB before fork
 189 $RT::Handle->dbh(undef);
 190 undef $RT::Handle;
 191
 192 if ( $ENV{'MOD_PERL'} && !RT->Config->Get('DevelMode')) {
 193     # Under static_source, we need to purge the component cache
 194     # each time we restart, so newer components may be reloaded.
 195     #
 196     # We can't do this in FastCGI or we'll blow away the component
 197     # root _every_ time a new server starts which happens every few
 198     # hits.
 199
 200     require File::Path;
 201     require File::Glob;
 202     my @files = File::Glob::bsd_glob("$RT::MasonDataDir/obj/*");
 203     File::Path::rmtree([ @files ], 0, 1) if @files;
 204 }
 205
 206 1;