rt/bin/webmux.pl.in

   1 #!@PERL@
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2009 Best Practical Solutions, LLC
   7 #                                          <jesse@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 use strict;
  50
  51 package HTML::Mason::Commands;
  52 our %session;
  53
  54 package RT::Mason;
  55
  56 our ($Nobody, $SystemUser, $Handler, $r);
  57
  58 sub handler {
  59     ($r) = @_;
  60
  61     local $SIG{__WARN__};
  62     local $SIG{__DIE__};
  63     RT::InitSignalHandlers();
  64
  65     if ($r->content_type =~ m/^httpd\b.*\bdirectory/i) {
  66         use File::Spec::Unix;
  67         # Our DirectoryIndex is always index.html, regardless of httpd settings
  68         $r->filename( File::Spec::Unix->catfile( $r->filename, 'index.html' ) );
  69     }
  70
  71     Module::Refresh->refresh if RT->Config->Get('DevelMode');
  72
  73     RT::ConnectToDatabase();
  74
  75     my (%session, $status);
  76     {
  77         local $@;
  78         $status = eval { $Handler->handle_request($r) };
  79         $RT::Logger->crit( $@ ) if $@;
  80     }
  81     undef %session;
  82
  83     RT::Interface::Web::Handler->CleanupRequest();
  84
  85     return $status;
  86 }
  87
  88 package main;
  89
  90 # check mod_perl version if it's mod_perl
  91 BEGIN {
  92     die "RT does not support mod_perl 1.99. Please upgrade to mod_perl 2.0"
  93         if $ENV{'MOD_PERL'}
  94         and $ENV{'MOD_PERL'} =~ m{mod_perl/(?:1\.9)};
  95 }
  96
  97 BEGIN {
  98     $ENV{'PATH'}   = '/bin:/usr/bin'; # or whatever you need
  99     $ENV{'CDPATH'} = '' if defined $ENV{'CDPATH'};
 100     $ENV{'SHELL'}  = '/bin/sh' if defined $ENV{'SHELL'};
 101     $ENV{'ENV'}    = '' if defined $ENV{'ENV'};
 102     $ENV{'IFS'}    = '' if defined $ENV{'IFS'};
 103
 104     # bring this in before mason, to make sure we
 105     # use private tempfiles
 106     use CGI qw(-private_tempfiles);
 107 }
 108
 109 # fix lib paths, some may be relative
 110 BEGIN {
 111     require File::Spec;
 112     my @libs = ("@RT_LIB_PATH@", "@LOCAL_LIB_PATH@");
 113     my $bin_path;
 114
 115     for my $lib (@libs) {
 116         unless ( File::Spec->file_name_is_absolute($lib) ) {
 117             unless ($bin_path) {
 118                 if ( File::Spec->file_name_is_absolute(__FILE__) ) {
 119                     $bin_path = ( File::Spec->splitpath(__FILE__) )[1];
 120                 }
 121                 else {
 122                     require FindBin;
 123                     no warnings "once";
 124                     $bin_path = $FindBin::Bin;
 125                 }
 126             }
 127             $lib = File::Spec->catfile( $bin_path, File::Spec->updir, $lib );
 128         }
 129         unshift @INC, $lib;
 130     }
 131
 132 }
 133
 134 require RT;
 135 RT::LoadConfig();
 136 if ( RT->Config->Get('DevelMode') ) {
 137     require Module::Refresh;
 138 }
 139 RT::Init();
 140
 141 # check compatibility of the DB
 142 {
 143     my $dbh = $RT::Handle->dbh;
 144     if ( $dbh ) {
 145         my ($status, $msg) = $RT::Handle->CheckCompatibility( $dbh, 'post' );
 146         die $msg unless $status;
 147     }
 148 }
 149
 150 require RT::Interface::Web::Handler;
 151 $RT::Mason::Handler = RT::Interface::Web::Handler->new(
 152     RT->Config->Get('MasonParameters')
 153 );
 154
 155 # load more for mod_perl before forking
 156 RT::InitClasses( Heavy => 1 ) if $ENV{'MOD_PERL'} || $ENV{RT_WEBMUX_HEAVY_LOAD};
 157
 158 # we must disconnect DB before fork
 159 $RT::Handle->dbh(undef);
 160 undef $RT::Handle;
 161
 162 if ( $ENV{'MOD_PERL'} && !RT->Config->Get('DevelMode')) {
 163     # Under static_source, we need to purge the component cache
 164     # each time we restart, so newer components may be reloaded.
 165     #
 166     # We can't do this in FastCGI or we'll blow away the component
 167     # root _every_ time a new server starts which happens every few
 168     # hits.
 169
 170     require File::Path;
 171     require File::Glob;
 172     my @files = File::Glob::bsd_glob("$RT::MasonDataDir/obj/*");
 173     File::Path::rmtree([ @files ], 0, 1) if @files;
 174 }
 175
 176 1;