rt/bin/rt-mailgate.in

   1 #!@PERL@
   2 # BEGIN BPS TAGGED BLOCK {{{
   3 #
   4 # COPYRIGHT:
   5 #
   6 # This software is Copyright (c) 1996-2013 Best Practical Solutions, LLC
   7 #                                          <sales@bestpractical.com>
   8 #
   9 # (Except where explicitly superseded by other copyright notices)
  10 #
  11 #
  12 # LICENSE:
  13 #
  14 # This work is made available to you under the terms of Version 2 of
  15 # the GNU General Public License. A copy of that license should have
  16 # been provided with this software, but in any event can be snarfed
  17 # from www.gnu.org.
  18 #
  19 # This work is distributed in the hope that it will be useful, but
  20 # WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  22 # General Public License for more details.
  23 #
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program; if not, write to the Free Software
  26 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  27 # 02110-1301 or visit their web page on the internet at
  28 # http://www.gnu.org/licenses/old-licenses/gpl-2.0.html.
  29 #
  30 #
  31 # CONTRIBUTION SUBMISSION POLICY:
  32 #
  33 # (The following paragraph is not intended to limit the rights granted
  34 # to you to modify and distribute this software under the terms of
  35 # the GNU General Public License and is only of importance to you if
  36 # you choose to contribute your changes and enhancements to the
  37 # community by submitting them to Best Practical Solutions, LLC.)
  38 #
  39 # By intentionally submitting any modifications, corrections or
  40 # derivatives to this work, or any other work intended for use with
  41 # Request Tracker, to Best Practical Solutions, LLC, you confirm that
  42 # you are the copyright holder for those contributions and you grant
  43 # Best Practical Solutions,  LLC a nonexclusive, worldwide, irrevocable,
  44 # royalty-free, perpetual, license to use, copy, create derivative
  45 # works based on those contributions, and sublicense and distribute
  46 # those contributions and any derivatives thereof.
  47 #
  48 # END BPS TAGGED BLOCK }}}
  49 =head1 NAME
  50
  51 rt-mailgate - Mail interface to RT3.
  52
  53 =cut
  54
  55 use strict;
  56 use warnings;
  57
  58 use Getopt::Long;
  59 use LWP::UserAgent;
  60 use HTTP::Request::Common qw($DYNAMIC_FILE_UPLOAD);
  61 $DYNAMIC_FILE_UPLOAD = 1;
  62
  63 use constant EX_TEMPFAIL => 75;
  64 use constant BUFFER_SIZE => 8192;
  65
  66 my %opts;
  67 GetOptions( \%opts, "queue=s", "action=s", "url=s", "jar=s", "help", "debug", "extension=s", "timeout=i" );
  68
  69 if ( $opts{'help'} ) {
  70     require Pod::Usage;
  71     import Pod::Usage;
  72     pod2usage("RT Mail Gateway\n");
  73     exit 1;    # Don't want to succeed if this is really an email!
  74 }
  75
  76 unless ( $opts{'url'} ) {
  77     print STDERR "$0 invoked improperly\n\nNo 'url' provided to mail gateway!\n";
  78     exit 1;
  79 }
  80
  81 my $ua = new LWP::UserAgent;
  82 $ua->cookie_jar( { file => $opts{'jar'} } ) if $opts{'jar'};
  83
  84 my %args;
  85 foreach ( qw(queue action) ) {
  86     $args{$_} = $opts{$_} if defined $opts{$_};
  87 };
  88
  89 if ( ($opts{'extension'} || '') =~ /^(?:action|queue|ticket)$/i ) {
  90     $args{ lc $opts{'extension'} } = $ENV{'EXTENSION'} || $opts{$opts{'extension'}};
  91 } elsif ( $opts{'extension'} && $ENV{'EXTENSION'} ) {
  92     print STDERR "Value of the --extension argument is not action, queue or ticket"
  93         .", but environment variable EXTENSION is also defined. The former is ignored.\n";
  94 }
  95
  96 # add ENV{'EXTENSION'} as X-RT-MailExtension to the message header
  97 if ( my $value = ( $ENV{'EXTENSION'} || $opts{'extension'} ) ) {
  98     # prepare value to avoid MIME format breakage
  99     # strip trailing newline symbols
 100     $value =~ s/(\r*\n)+$//;
 101     # make a correct multiline header field,
 102     # with tabs in the beginning of each line
 103     $value =~ s/(\r*\n)/$1\t/g;
 104     $opts{'headers'} .= "X-RT-Mail-Extension: $value\n";
 105 }
 106
 107 # Read the message in from STDIN
 108 my %message = write_down_message();
 109 unless( $message{'filename'} ) {
 110     $args{'message'} = [
 111         undef, '',
 112         'Content-Type' => 'application/octet-stream',
 113         Content => ${ $message{'content'} },
 114     ];
 115 } else {
 116     $args{'message'} = [
 117         $message{'filename'}, '',
 118         'Content-Type' => 'application/octet-stream',
 119     ];
 120 }
 121
 122 my $full_url = $opts{'url'}. "/REST/1.0/NoAuth/mail-gateway";
 123 print STDERR "$0: connecting to $full_url\n" if $opts{'debug'};
 124
 125 $ua->timeout( exists( $opts{'timeout'} )? $opts{'timeout'}: 180 );
 126 my $r = $ua->post( $full_url, \%args, Content_Type => 'form-data' );
 127 check_failure($r);
 128
 129 my $content = $r->content;
 130 print STDERR $content ."\n" if $opts{'debug'};
 131
 132 if ( $content !~ /^(ok|not ok)/ ) {
 133
 134     # It's not the server's fault if the mail is bogus. We just want to know that
 135     # *something* came out of the server.
 136     print STDERR <<EOF;
 137 RT server error.
 138
 139 The RT server which handled your email did not behave as expected. It
 140 said:
 141
 142 $content
 143 EOF
 144
 145     exit EX_TEMPFAIL;
 146 }
 147
 148 exit;
 149
 150 END {
 151     unlink $message{'filename'} if $message{'filename'};
 152 }
 153
 154
 155 sub check_failure {
 156     my $r = shift;
 157     return if $r->is_success;
 158
 159     # This ordinarily oughtn't to be able to happen, suggests a bug in RT.
 160     # So only load these heavy modules when they're needed.
 161     require HTML::TreeBuilder;
 162     require HTML::FormatText;
 163
 164     my $error = $r->error_as_HTML;
 165     my $tree  = HTML::TreeBuilder->new->parse( $error );
 166     $tree->eof;
 167
 168     # It'll be a cold day in hell before RT sends out bounces in HTML
 169     my $formatter = HTML::FormatText->new(
 170         leftmargin  => 0,
 171         rightmargin => 50,
 172     );
 173     print STDERR $formatter->format( $tree );
 174     print STDERR "\n$0: undefined server error\n" if $opts{'debug'};
 175     exit EX_TEMPFAIL;
 176 }
 177
 178 sub write_down_message {
 179     use File::Temp qw(tempfile);
 180
 181     local $@;
 182     my ($fh, $filename) = eval { tempfile() };
 183     if ( !$fh || $@ ) {
 184         print STDERR "$0: Couldn't create temp file, using memory\n";
 185         print STDERR "error: $@\n" if $@;
 186
 187         my $message = \do { local (@ARGV, $/); <STDIN> };
 188         unless ( $$message =~ /\S/ ) {
 189             print STDERR "$0: no message passed on STDIN\n";
 190             exit 0;
 191         }
 192         $$message = $opts{'headers'} . $$message if $opts{'headers'};
 193         return ( content => $message );
 194     }
 195
 196     binmode $fh;
 197     binmode \*STDIN;
 198
 199     print $fh $opts{'headers'} if $opts{'headers'};
 200
 201     my $buf; my $empty = 1;
 202     while(1) {
 203         my $status = read \*STDIN, $buf, BUFFER_SIZE;
 204         unless ( defined $status ) {
 205             print STDERR "$0: couldn't read message: $!\n";
 206             exit EX_TEMPFAIL;
 207         } elsif ( !$status ) {
 208             last;
 209         }
 210         $empty = 0 if $buf =~ /\S/;
 211         print $fh $buf;
 212     };
 213     close $fh;
 214
 215     if ( $empty ) {
 216         print STDERR "$0: no message passed on STDIN\n";
 217         exit 0;
 218     }
 219     print STDERR "$0: temp file is '$filename'\n" if $opts{'debug'};
 220     return (filename => $filename);
 221 }
 222
 223
 224 =head1 SYNOPSIS
 225
 226     rt-mailgate --help : this text
 227
 228 Usual invocation (from MTA):
 229
 230     rt-mailgate --action (correspond|comment|...) --queue queuename
 231                 --url http://your.rt.server/
 232                 [ --debug ]
 233                 [ --extension (queue|action|ticket) ]
 234                 [ --timeout seconds ]
 235
 236
 237
 238 =head1 OPTIONS
 239
 240 =over 3
 241
 242 =item C<--action>
 243
 244 Specifies what happens to email sent to this alias.  The avaliable
 245 basic actions are: C<correspond>, C<comment>.
 246
 247
 248 If you've set the RT configuration variable B<< C<UnsafeEmailCommands> >>,
 249 C<take> and C<resolve> are also available.  You can execute two or more
 250 actions on a single message using a C<-> separated list.  RT will execute
 251 the actions in the listed order.  For example you can use C<take-comment>,
 252 C<correspond-resolve> or C<take-comment-resolve> as actions.
 253
 254 Note that C<take> and C<resolve> actions ignore message text if used
 255 alone.  Include a  C<comment> or C<correspond> action if you want RT
 256 to record the incoming message.
 257
 258 The default action is C<correspond>.
 259
 260 =item C<--queue>
 261
 262 This flag determines which queue this alias should create a ticket in if no ticket identifier
 263 is found.
 264
 265 =item C<--url>
 266
 267 This flag tells the mail gateway where it can find your RT server. You should
 268 probably use the same URL that users use to log into RT.
 269
 270
 271 =item C<--extension> OPTIONAL
 272
 273 Some MTAs will route mail sent to user-foo@host or user+foo@host to user@host
 274 and present "foo" in the environment variable $EXTENSION. By specifying
 275 the value "queue" for this parameter, the queue this message should be
 276 submitted to will be set to the value of $EXTENSION. By specifying
 277 "ticket", $EXTENSION will be interpreted as the id of the ticket this message
 278 is related to.  "action" will allow the user to specify either "comment" or
 279 "correspond" in the address extension.
 280
 281 =item C<--debug> OPTIONAL
 282
 283 Print debugging output to standard error
 284
 285
 286 =item C<--timeout> OPTIONAL
 287
 288 Configure the timeout for posting the message to the web server.  The
 289 default timeout is 3 minutes (180 seconds).
 290
 291
 292 =head1 DESCRIPTION
 293
 294 The RT mail gateway is the primary mechanism for communicating with RT
 295 via email. This program simply directs the email to the RT web server,
 296 which handles filing correspondence and sending out any required mail.
 297 It is designed to be run as part of the mail delivery process, either
 298 called directly by the MTA or C<procmail>, or in a F<.forward> or
 299 equivalent.
 300
 301 =head1 SETUP
 302
 303 Much of the set up of the mail gateway depends on your MTA and mail
 304 routing configuration. However, you will need first of all to create an
 305 RT user for the mail gateway and assign it a password; this helps to
 306 ensure that mail coming into the web server did originate from the
 307 gateway.
 308
 309 Next, you need to route mail to C<rt-mailgate> for the queues you're
 310 monitoring. For instance, if you're using F</etc/aliases> and you have a
 311 "bugs" queue, you will want something like this:
 312
 313     bugs:         "|/opt/rt3/bin/rt-mailgate --queue bugs --action correspond
 314               --url http://rt.mycorp.com/"
 315
 316     bugs-comment: "|/opt/rt3/bin/rt-mailgate --queue bugs --action comment
 317               --url http://rt.mycorp.com/"
 318
 319 Note that you don't have to run your RT server on your mail server, as
 320 the mail gateway will happily relay to a different machine.
 321
 322 =head1 CUSTOMIZATION
 323
 324 By default, the mail gateway will accept mail from anyone. However,
 325 there are situations in which you will want to authenticate users
 326 before allowing them to communicate with the system. You can do this
 327 via a plug-in mechanism in the RT configuration.
 328
 329 You can set the array C<@MailPlugins> to be a list of plugins. The
 330 default plugin, if this is not given, is C<Auth::MailFrom> - that is,
 331 authentication of the person is done based on the C<From> header of the
 332 email. If you have additional filters or authentication mechanisms, you
 333 can list them here and they will be called in order:
 334
 335     Set( @MailPlugins =>
 336         "Filter::SpamAssassin",
 337         "Auth::LDAP",
 338         # ...
 339     );
 340
 341 See the documentation for any additional plugins you have.
 342
 343 You may also put Perl subroutines into the C<@MailPlugins> array, if
 344 they behave as described below.
 345
 346 =head1 WRITING PLUGINS
 347
 348 What's actually going on in the above is that C<@MailPlugins> is a
 349 list of Perl modules; RT prepends C<RT::Interface::Email::> to the name,
 350 to form a package name, and then C<use>'s this module. The module is
 351 expected to provide a C<GetCurrentUser> subroutine, which takes a hash of
 352 several parameters:
 353
 354 =over 4
 355
 356 =item Message
 357
 358 A C<MIME::Entity> object representing the email
 359
 360 =item CurrentUser
 361
 362 An C<RT::CurrentUser> object
 363
 364 =item AuthStat
 365
 366 The authentication level returned from the previous plugin.
 367
 368 =item Ticket [OPTIONAL]
 369
 370 The ticket under discussion
 371
 372 =item Queue [OPTIONAL]
 373
 374 If we don't already have a ticket id, we need to know which queue we're talking about
 375
 376 =item Action
 377
 378 The action being performed. At the moment, it's one of "comment" or "correspond"
 379
 380 =back 4
 381
 382 It returns two values, the new C<RT::CurrentUser> object, and the new
 383 authentication level. The authentication level can be zero, not allowed
 384 to communicate with RT at all, (a "permission denied" error is mailed to
 385 the correspondent) or one, which is the normal mode of operation.
 386 Additionally, if C<-1> is returned, then the processing of the plug-ins
 387 stops immediately and the message is ignored.
 388
 389 =head1 ENVIRONMENT
 390
 391 =over 4
 392
 393 =item EXTENSION
 394
 395 Some MTAs will route mail sent to user-foo@host or user+foo@host to user@host
 396 and present "foo" in the environment variable C<EXTENSION>. Mailgate adds value
 397 of this variable to message in the C<X-RT-Mail-Extension> field of the message
 398 header.
 399
 400 See also C<--extension> option. Note that value of the environment variable is
 401 always added to the message header when it's not empty even if C<--extension>
 402 option is not provided.
 403
 404 =back 4
 405
 406 =cut
 407