httemplate/search/sqlradius.cgi

   1 <% include( '/elements/header.html', 'RADIUS Sessions',
   2              include('/elements/menubar.html',
   3                        'Main menu' => $p, # popurl(2),
   4                     ),
   5
   6     )
   7 %>
   8
   9 % ###
  10 % # and finally, display the thing
  11 % ###
  12 %
  13 % foreach my $part_export (
  14 %   #grep $_->can('usage_sessions'), qsearch( 'part_export' )
  15 %   qsearch( 'part_export', { 'exporttype' => 'sqlradius' } ),
  16 %   qsearch( 'part_export', { 'exporttype' => 'sqlradius_withdomain' } )
  17 % ) {
  18 %   %user2svc_acct = ();
  19 %
  20 %   my $efields = tie my %efields, 'Tie::IxHash', %fields;
  21 %   delete $efields{'framedipaddress'} if $part_export->option('hide_ip');
  22 %   if ( $part_export->option('hide_data') ) {
  23 %     delete $efields{$_} foreach qw(acctinputoctets acctoutputoctets);
  24 %   }
  25 %   if ( $part_export->option('show_called_station') ) {
  26 %     $efields->Splice(1, 0,
  27 %       'calledstationid' => {
  28 %                              'name'   => 'Destination',
  29 %                              'attrib' => 'Called-Station-ID',
  30 %                              'fmt'    =>
  31 %                                sub { length($_[0]) ? shift : '&nbsp'; },
  32 %                              'align'  => 'left',
  33 %                            },
  34 %     );
  35 %   }
  36 %
  37 %
  38
  39     <% $part_export->exporttype %> to <% $part_export->machine %><BR>
  40     <% include( '/elements/table-grid.html' ) %>
  41 %   my $bgcolor1 = '#eeeeee';
  42 %   my $bgcolor2 = '#ffffff';
  43 %   my $bgcolor;
  44
  45     <TR>
  46 %   foreach my $field ( keys %efields ) {
  47
  48       <TH CLASS="grid" BGCOLOR="#cccccc">
  49         <% $efields{$field}->{name} %><BR>
  50         <FONT SIZE=-2><% $efields{$field}->{attrib} %></FONT>
  51       </TH>
  52
  53 %   }
  54   </TR>
  55
  56 %   foreach my $session (
  57 %       @{ $part_export->usage_sessions(
  58 %            $beginning, $ending, $cgi_svc_acct, $ip, $prefix, ) }
  59 %   ) {
  60 %     if ( $bgcolor eq $bgcolor1 ) {
  61 %       $bgcolor = $bgcolor2;
  62 %     } else {
  63 %       $bgcolor = $bgcolor1;
  64 %     }
  65
  66       <TR>
  67 %     foreach my $field ( keys %efields ) {
  68 %       my $html = &{ $efields{$field}->{fmt} }( $session->{$field},
  69 %                                                $session,
  70 %                                                $part_export,
  71 %                                              );
  72 %       my $class = ( $html =~ /<TABLE/ ? 'inv' : 'grid' );
  73
  74         <TD CLASS="<%$class%>" BGCOLOR="<% $bgcolor %>" ALIGN="<% $efields{$field}->{align} %>">
  75           <% $html %>
  76         </TD>
  77 %     }
  78   </TR>
  79
  80 %   }
  81
  82 </TABLE>
  83 <BR><BR>
  84
  85 % }
  86
  87
  88 <%init>
  89 ###
  90 # parse cgi params
  91 ###
  92
  93 #sort of false laziness w/cust_pay.cgi
  94 my $beginning = '';
  95 my $ending = '';
  96 if ( $cgi->param('beginning')
  97      && $cgi->param('beginning') =~ /^([ 0-9\-\/\:\w]{0,54})$/ ) {
  98   $beginning = str2time($1);
  99 }
 100 if ( $cgi->param('ending')
 101      && $cgi->param('ending') =~ /^([ 0-9\-\/\:\w]{0,54})$/ ) {
 102   $ending = str2time($1); # + 86399;
 103 }
 104 if ( $cgi->param('begin') && $cgi->param('begin') =~ /^(\d+)$/ ) {
 105   $beginning = $1;
 106 }
 107 if ( $cgi->param('end') && $cgi->param('end') =~ /^(\d+)$/ ) {
 108   $ending = $1;
 109 }
 110
 111 my $cgi_svc_acct = '';
 112 if ( $cgi->param('svcnum') =~ /^(\d+)$/ ) {
 113   $cgi_svc_acct = qsearchs( 'svc_acct', { 'svcnum' => $1 } );
 114 } elsif ( $cgi->param('username') =~ /^([^@]+)\@([^@]+)$/ ) {
 115   my %search = { 'username' => $1 };
 116   my $svc_domain = qsearchs('svc_domain', { 'domain' => $2 } );
 117   if ( $svc_domain ) {
 118     $search{'domsvc'} = $svc_domain->svcnum;
 119   } else {
 120     delete $search{'username'};
 121   }
 122   $cgi_svc_acct = qsearchs( 'svc_acct', \%search )
 123     if keys %search;
 124 } elsif ( $cgi->param('username') =~ /^(.+)$/ ) {
 125   $cgi_svc_acct = qsearchs( 'svc_acct', { 'username' => $1 } );
 126 }
 127
 128 my $ip = '';
 129 if ( $cgi->param('ip') =~ /^((\d+\.){3}\d+)$/ ) {
 130   $ip = $1;
 131 }
 132
 133 my $prefix = $cgi->param('prefix');
 134 $prefix =~ s/\D//g;
 135 if ( $prefix =~ /^(\d+)$/ ) {
 136   $prefix = $1;
 137   $prefix = "011$prefix" unless $prefix =~ /^1/;
 138 } else {
 139   $prefix = '';
 140 }
 141
 142 ###
 143 # field formatting subroutines
 144 ###
 145
 146 my %user2svc_acct = ();
 147 my $user_format = sub {
 148   my ( $user, $session, $part_export ) = @_;
 149
 150   my $svc_acct = '';
 151   if ( exists $user2svc_acct{$user} ) {
 152     $svc_acct = $user2svc_acct{$user};
 153   } else {
 154     my %search = ();
 155     if ( $part_export->exporttype eq 'sqlradius_withdomain' ) {
 156       my $domain;
 157       if ( $user =~ /^([^@]+)\@([^@]+)$/ ) {
 158        $search{'username'} = $1;
 159        $domain = $2;
 160      } else {
 161        $search{'username'} = $user;
 162        $domain = $session->{'realm'};
 163      }
 164      my $svc_domain = qsearchs('svc_domain', { 'domain' => $domain } );
 165      if ( $svc_domain ) {
 166        $search{'domsvc'} = $svc_domain->svcnum;
 167      } else {
 168        delete $search{'username'};
 169      }
 170     } elsif ( $part_export->exporttype eq 'sqlradius' ) {
 171       $search{'username'} = $user;
 172     } else {
 173       die 'unknown export type '. $part_export->exporttype.
 174           " for $part_export\n";
 175     }
 176     if ( keys %search ) {
 177       my @svc_acct =
 178         grep { qsearchs( 'export_svc', {
 179                  'exportnum' => $part_export->exportnum,
 180                  'svcpart'   => $_->cust_svc->svcpart,
 181                } )
 182              } qsearch( 'svc_acct', \%search );
 183       if ( @svc_acct ) {
 184         warn 'multiple svc_acct records for user $user found; '.
 185              'using first arbitrarily'
 186           if scalar(@svc_acct) > 1;
 187         $user2svc_acct{$user} = $svc_acct = shift @svc_acct;
 188       }
 189     }
 190   }
 191
 192   if ( $svc_acct ) {
 193     my $svcnum = $svc_acct->svcnum;
 194     qq(<A HREF="${p}view/svc_acct.cgi?$svcnum"><B>$user</B></A>);
 195   } else {
 196     "<B>$user</B>";
 197   }
 198
 199 };
 200
 201 my $customer_format = sub {
 202   my( $unused, $session ) = @_;
 203   return '&nbsp;' unless exists $user2svc_acct{$session->{'username'}};
 204   my $svc_acct = $user2svc_acct{$session->{'username'}};
 205   my $cust_pkg = $svc_acct->cust_svc->cust_pkg;
 206   return '&nbsp;' unless $cust_pkg;
 207   my $cust_main = $cust_pkg->cust_main;
 208
 209   qq!<A HREF="${p}view/cust_main.cgi?!. $cust_main->custnum. '">'.
 210     $cust_pkg->cust_main->name. '</A>';
 211 };
 212
 213 my $time_format = sub {
 214   my $time = shift;
 215   return '&nbsp;' if $time == 0;
 216   my $pretty = time2str('%T%P %a&nbsp;%b&nbsp;%o&nbsp;%Y', $time );
 217   $pretty =~ s/ (\d)(st|dn|rd|th)/$1$2/;
 218   $pretty;
 219 };
 220
 221 my $duration_format = sub {
 222   my $seconds = shift;
 223   my $hour = int($seconds/3600);
 224   my $min = int( ($seconds%3600) / 60 );
 225   my $sec = $seconds%60;
 226   '<TABLE CLASS="inv" BORDER=0 CELLSPACING=0 CELLPADDING=0>'.
 227   '<TR><TD CLASS="inv" ALIGN="right">'.
 228      ( $hour ? "<B>$hour</B>h" : '&nbsp;' ).
 229    '</TD><TD CLASS="inv" ALIGN="right">'.
 230      ( ( $hour || $min ) ? "<B>$min</B>m" : '&nbsp;' ).
 231    '</TD><TD CLASS="inv" ALIGN="right">'.
 232      "<B>$sec</B>s".
 233   '</TD></TR></TABLE>';
 234 };
 235
 236 my $octets_format = sub {
 237   my $octets = shift;
 238   my $megs = $octets / 1048576;
 239   sprintf('<B>%.3f</B>&nbsp;megs', $megs);
 240   #my $gigs = $octets / 1073741824
 241   #sprintf('<B>%.3f</B> gigabytes', $gigs);
 242 };
 243
 244 ###
 245 # the fields
 246 ###
 247
 248 tie my %fields, 'Tie::IxHash',
 249   'username'          => {
 250                            name    => 'User',
 251                            attrib  => 'UserName',
 252                            fmt     => $user_format,
 253                            align   => 'left',
 254                          },
 255   'realm'             => {
 256                            name    => 'Realm',
 257                            attrib  => 'Realm',
 258                            align   => 'left',
 259                          },
 260   'dummy'             => {
 261                            name    => 'Customer',
 262                            attrib  => '',
 263                            fmt     => $customer_format,
 264                            align   => 'left',
 265                          },
 266   'framedipaddress'   => {
 267                            name    => 'IP&nbsp;Address',
 268                            attrib  => 'Framed-IP-Address',
 269                            fmt     => sub { my $ip = shift;
 270                                             length($ip) ? $ip : '&nbsp';
 271                                           },
 272                            align   => 'right',
 273                          },
 274   'acctstarttime'     => {
 275                            name    => 'Start&nbsp;time',
 276                            attrib  => 'Acct-Start-Time',
 277                            fmt     => $time_format,
 278                            align   => 'left',
 279                          },
 280   'acctstoptime'      => {
 281                            name    => 'End&nbsp;time',
 282                            attrib  => 'Acct-Stop-Time',
 283                            fmt     => $time_format,
 284                            align   => 'left',
 285                          },
 286   'acctsessiontime'   => {
 287                            name    => 'Duration',
 288                            attrib  => 'Acct-Session-Time',
 289                            fmt     => $duration_format,
 290                            align   => 'right',
 291                          },
 292   'acctinputoctets'   => {
 293                            name    => 'Upload', # (from user)',
 294                            attrib  => 'Acct-Input-Octets',
 295                            fmt     => $octets_format,
 296                            align   => 'right',
 297                          },
 298   'acctoutputoctets'  => {
 299                            name    => 'Download', # (to user)',
 300                            attrib  => 'Acct-Output-Octets',
 301                            fmt     => $octets_format,
 302                            align   => 'right',
 303                          },
 304 ;
 305 $fields{$_}->{fmt} ||= sub { length($_[0]) ? shift : '&nbsp'; }
 306   foreach keys %fields;
 307
 308 </%init>