httemplate/edit/elements/svc_Common.html

   1 <% include( 'edit.html',
   2
   3                  'menubar' => [],
   4
   5                  'error_callback' => sub {
   6                    my( $cgi, $svc_x, $fields, $opt ) = @_;
   7                    #$svcnum = $svc_x->svcnum;
   8                    $pkgnum  = $cgi->param('pkgnum');
   9                    $svcpart = $cgi->param('svcpart');
  10
  11                    $part_svc = qsearchs( 'part_svc', { svcpart=>$svcpart });
  12                    die "No part_svc entry!" unless $part_svc;
  13
  14                    label_fixup($part_svc, $opt);
  15
  16                    $svc_x->setfield('svcpart', $svcpart);
  17
  18                    if ( my $cb = $opt{'svc_error_callback'} ) {
  19                      my $cust_pkg = $pkgnum
  20                                       ? qsearchs('cust_pkg', {pkgnum=>$pkgnum})
  21                                       : ''; #?
  22                      &{ $cb }( $cgi,$svc_x, $part_svc,$cust_pkg, $fields,$opt);
  23                    }
  24
  25                  },
  26
  27                  'edit_callback' => sub {
  28                    my( $cgi, $svc_x, $fields, $opt ) = @_;
  29                    #$svcnum = $svc_x->svcnum;
  30                    my $cust_svc = $svc_x->cust_svc
  31                      or die "Unknown (cust_svc) svcnum!";
  32
  33                    $pkgnum  = $cust_svc->pkgnum;
  34                    $svcpart = $cust_svc->svcpart;
  35
  36                    $part_svc = qsearchs ('part_svc', { svcpart=>$svcpart });
  37                    die "No part_svc entry!" unless $part_svc;
  38
  39                    label_fixup($part_svc, $opt);
  40
  41                    if ( my $cb = $opt{'svc_edit_callback'} ) {
  42                      my $cust_pkg = $pkgnum
  43                                       ? qsearchs('cust_pkg', {pkgnum=>$pkgnum})
  44                                       : ''; #?
  45                      &{ $cb }( $cgi,$svc_x, $part_svc,$cust_pkg, $fields,$opt);
  46                    }
  47
  48                    if ( $part_svc->has_router ) {
  49                      my $router = qsearchs('router', {svcnum => $svc_x->svcnum});
  50                      if ( $router ) {
  51                        $svc_x->set("router_$_", $router->get($_))
  52                          foreach ('routername', 'routernum');
  53                        my ($block) = $router->addr_block; # one-to-one for now
  54                        if ( $block ) {
  55                          $svc_x->set('router_blocknum', $block->blocknum);
  56                          # silly, but necessary...make the currently
  57                          # assigned block appear on the list
  58                          my ($field) = grep {ref($_) and
  59                                              $_->{field} eq 'router_blocknum'}
  60                                          @$fields;
  61                          $field->{extra_sql} =
  62                            ' OR routernum = '.$router->routernum;
  63                          $field->{curr_value} = $block->blocknum;
  64                        }
  65                      }
  66                    }
  67
  68                  },
  69
  70                  'new_hashref_callback' => sub {
  71                    #my( $cgi, $svc_x ) = @_;
  72
  73                    { pkgnum  => $pkgnum,
  74                      svcpart => $svcpart,
  75                    };
  76
  77                  },
  78
  79                  'new_callback' => sub {
  80                    my( $cgi, $svc_x, $fields, $opt ) = @_;
  81
  82                    $part_svc = qsearchs( 'part_svc', { svcpart=>$svcpart });
  83                    die "No part_svc entry!" unless $part_svc;
  84
  85                    label_fixup($part_svc, $opt);
  86
  87                    #$svcnum='';
  88
  89                    if ( my $cb = $opt{'svc_new_callback'} ) {
  90                      my $cust_pkg = $pkgnum
  91                                      ? qsearchs('cust_pkg', {pkgnum=>$pkgnum})
  92                                      : ''; #?
  93                      &{ $cb }( $cgi,$svc_x, $part_svc,$cust_pkg, $fields,$opt);
  94                    }
  95
  96                    $svc_x->set_default_and_fixed;
  97                  },
  98
  99                  'field_callback' => sub {
 100                    my ($cgi, $object, $f) = @_;
 101
 102                    my $columndef = $part_svc->part_svc_column($f->{'field'});
 103                    my $flag = $columndef->columnflag;
 104                    if ( $flag eq 'F' ) {
 105                      $f->{'type'} = length($columndef->columnvalue)
 106                                       ? 'fixed'
 107                                       : 'hidden';
 108                      $f->{'value'} = $columndef->columnvalue;
 109                    } elsif ( $flag eq 'A' ) {
 110                      $f->{'type'} = 'hidden';
 111                    } elsif ( $flag eq 'M' ) {
 112                      $f->{'type'} = 'select-inventory_item';
 113                      $f->{'empty_label'} = 'Select inventory item';
 114                      $f->{'extra_sql'} = 'WHERE ( svcnum IS NULL ' .
 115                         ($object->svcnum && ' OR svcnum = '.$object->svcnum) .
 116                         ')';
 117                      $f->{'classnum'} = $columndef->columnvalue;
 118                      $f->{'disable_empty'} = $object->svcnum ? 1 : 0;
 119                    } elsif ( $flag eq 'H' ) {
 120                      $f->{'type'}        = 'select-hardware_type';
 121                      $f->{'hashref'}     = {
 122                                             'classnum'=>$columndef->columnvalue
 123                                            };
 124                    } elsif ( $flag eq 'S' ) { #selectable choice
 125                      $f->{type}    = 'select';
 126                      $f->{options} = [ split( /\s*,\s*/,
 127                                                 $columndef->columnvalue)
 128                                      ];
 129                    }
 130
 131                    if (    $f->{'type'} eq 'select-svc_pbx'
 132                         || $f->{'type'} eq 'select-svc-domain'
 133                       )
 134                    {
 135                      $f->{'include_opt_callback'} =
 136                        sub { ( 'pkgnum'  => $pkgnum,
 137                                'svcpart' => $svcpart,
 138                              );
 139                            };
 140                    }
 141
 142                    if ( $f->{'field'} eq 'custnum' && $pkgnum ) {
 143                      my $cust_pkg = qsearchs('cust_pkg', {'pkgnum' => $pkgnum});
 144                      $object->set('custnum', $cust_pkg->custnum);
 145                    }
 146
 147                    if ( my $cb = $opt{'svc_field_callback'} ) {
 148                      &{ $cb }( $cgi, $object, $f);
 149                    }
 150
 151                  },
 152
 153                  'html_init' => sub {
 154                    my $html;
 155                    my $cust_main;
 156                    if ( $pkgnum ) {
 157                      my $cust_pkg = qsearchs('cust_pkg', {'pkgnum' => $pkgnum});
 158                      $cust_main = $cust_pkg->cust_main if $cust_pkg;
 159                      if ( $cust_main ) {
 160                         $html = include( '/elements/small_custview.html',
 161                                 $cust_main,
 162                                 '',
 163                                 1,
 164                                 popurl(2). "view/cust_main.cgi"
 165                               ). '<BR>';
 166                      }
 167                    }
 168                    $html;
 169                  },
 170
 171                  'html_table_bottom' => sub {
 172                    my $svc_x = shift;
 173                    my $html = '';
 174                    foreach my $field ($svc_x->virtual_fields) {
 175                      if ($part_svc->part_svc_column($field)->columnflag ne 'F'){
 176                        # If the flag is X, it won't even show up
 177                        # in $svc_acct->virtual_fields.
 178                        $html .=
 179                          $svc_x->pvf($field)->widget( 'HTML',
 180                                                       'edit',
 181                                                       $svc_x->getfield($field)
 182                                                     );
 183                      }
 184                    }
 185                    $html;
 186                  },
 187
 188                  'html_bottom' => sub {
 189                    qq!<INPUT TYPE="hidden" NAME="pkgnum" VALUE="$pkgnum">!.
 190                    qq!<INPUT TYPE="hidden" NAME="svcpart" VALUE="$svcpart">!;
 191                  },
 192
 193                  %opt #pass through/override params
 194              )
 195 %>
 196 <%once>
 197
 198 sub label_fixup {
 199   my( $part_svc, $opt ) = @_;
 200
 201   $opt->{'name'} ||= $part_svc->svc;
 202
 203   my $svcdb = $part_svc->svcdb;
 204   require "FS/$svcdb.pm";
 205
 206   if ( UNIVERSAL::can("FS::$svcdb", 'table_info') ) {
 207     #$opt->{'name'} ||= "FS::$svcdb"->table_info->{'name'};
 208
 209     my $fields = "FS::$svcdb"->table_info->{'fields'};
 210     $opt->{'fields'} ||= [ grep { $_ ne 'svcnum' } keys %$fields ];
 211
 212     $opt->{labels} ||= {
 213                          map { $_ => ( ref($fields->{$_})
 214                                          ? $fields->{$_}{'label'}
 215                                          : $fields->{$_}
 216                                      );
 217                              }
 218                          keys %$fields
 219                        };
 220   }
 221
 222   #false laziness w/view/svc_Common.html
 223   #override default labels with service-definition labels if applicable
 224   my $labels = $opt->{labels}; # with -> here
 225   foreach my $field ( keys %{ $opt->{labels} } ) {
 226     my $col = $part_svc->part_svc_column($field);
 227     $labels->{$field} = $col->columnlabel if $col->columnlabel !~ /^\s*$/;
 228   }
 229
 230   if ( $part_svc->has_router ) {
 231     # these will be set up as pseudo-fields in the new_ and edit_ callbacks
 232     push @{ $opt->{'fields'} }, (
 233       { field => 'router_routernum',   type => 'hidden' },
 234       { field => 'router_routername',  type => 'text', size => 32 },
 235       # router address block selection
 236       # (one-to-one for now)
 237       { field => 'router_blocknum',
 238         type  => 'select-table',
 239         table       => 'addr_block',
 240         hashref     => { 'routernum' => '0' },
 241         agent_virt  => 1,
 242         agent_null  => 1,
 243         name_col    => 'cidr',
 244         order_by    => 'ORDER BY ip_gateway, ip_netmask',
 245         empty_label => '(none)',
 246         disable_empty => 0,
 247       },
 248     );
 249     $labels->{router_routername}  = 'Attached router name';
 250     $labels->{router_blocknum}    = 'Attached address block';
 251   }
 252 }
 253
 254 </%once>
 255 <%init>
 256
 257 my %opt = @_;
 258
 259 #my( $svcnum, $pkgnum, $svcpart, $part_svc );
 260 my( $pkgnum, $svcpart, $part_svc );
 261
 262 #get & untaint pkgnum & svcpart
 263 if ( ! $cgi->param('error')
 264      && $cgi->param('pkgnum') && $cgi->param('svcpart')
 265    )
 266 {
 267   $cgi->param('pkgnum') =~ /^(\d+)$/ or die 'unparsable pkgnum';
 268   $pkgnum = $1;
 269   $cgi->param('svcpart') =~ /^(\d+)$/ or die 'unparsable svcpart';
 270   $svcpart = $1;
 271   #$cgi->delete_all(); #so edit.html treats this correctly as new??
 272 }
 273
 274 </%init>