fs_signup/fs_signup_server

   1 #!/usr/bin/perl -Tw
   2 #
   3 # fs_signup_server
   4 #
   5
   6 use strict;
   7 use vars qw($pid);
   8 use IO::Handle;
   9 use Storable qw(nstore_fd fd_retrieve);
  10 use Tie::RefHash;
  11 use Net::SSH qw(sshopen2);
  12 use FS::UID qw(adminsuidsetup);
  13 use FS::Conf;
  14 use FS::Record qw( qsearch qsearchs );
  15 use FS::cust_main_county;
  16 use FS::cust_main;
  17 use FS::Msgcat qw(gettext);
  18
  19 use vars qw( $opt $Debug );
  20
  21 $Debug = 2;
  22
  23 my $user = shift or die &usage;
  24 &adminsuidsetup( $user );
  25
  26 my $conf = new FS::Conf;
  27
  28 #my @payby = qw(CARD PREPAY);
  29 my @payby = $conf->config('signup_server-payby');
  30 my $smtpmachine = $conf->config('smtpmachine');
  31
  32 my $machine = shift or die &usage;
  33
  34 my $agentnum = shift or die &usage;
  35 my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } ) or die &usage;
  36 my $pkgpart_href = $agent->pkgpart_hashref;
  37
  38 my $refnum = shift or die &usage;
  39
  40 #causing trouble for some folks
  41 #$SIG{CHLD} = sub { wait() };
  42
  43 $SIG{HUP} = \&killssh;
  44 $SIG{INT} = \&killssh;
  45 $SIG{QUIT} = \&killssh;
  46 $SIG{TERM} = \&killssh;
  47 $SIG{PIPE} = \&killssh;
  48 sub killssh { kill 'TERM', $pid if $pid; exit; };
  49
  50 my($fs_signupd)="/usr/local/sbin/fs_signupd";
  51
  52 while (1) {
  53   my($reader,$writer)=(new IO::Handle, new IO::Handle);
  54   #seems to be broken - calling ->flush explicitly# $writer->autoflush(1);
  55   warn "[fs_signup_server] Connecting to $machine...\n" if $Debug;
  56   $pid = sshopen2($machine,$reader,$writer,$fs_signupd);
  57
  58   my @pops = qsearch('svc_acct_pop',{} );
  59   my $init_data = {
  60
  61     #'_protocol' => 'signup',
  62     #'_version' => '0.1',
  63     #'_packet' => 'init'
  64
  65     'cust_main_county' =>
  66       [ map { $_->hashref } qsearch('cust_main_county', {}) ],
  67
  68     'part_pkg' =>
  69       [
  70         #map { $_->hashref }
  71         map { { 'payby' => [ $_->payby ], %{$_->hashref} } }
  72           grep { $_->svcpart('svc_acct') && $pkgpart_href->{ $_->pkgpart } }
  73             qsearch( 'part_pkg', { 'disabled' => '' } )
  74       ],
  75
  76     'svc_acct_pop' => [ map { $_->hashref } @pops ],
  77
  78     'security_phrase' => $conf->exists('security_phrase'),
  79
  80     'payby' => [ $conf->config('signup_server-payby') ],
  81
  82     'msgcat' => { map { $_=>gettext($_) } qw(
  83       passwords_dont_match invalid_card unknown_card_type not_a
  84     ) }
  85
  86   };
  87
  88   warn "[fs_signup_server] Sending init data...\n" if $Debug;
  89   nstore_fd($init_data, $writer) or die "can't send init data: $!";
  90   $writer->flush;
  91
  92   warn "[fs_signup_server] Entering main loop...\n" if $Debug;
  93   while (1) {
  94     warn "[fs_signup_server] Reading (waiting for) signup data...\n" if $Debug;
  95     my $signup_data = fd_retrieve($reader);
  96
  97     if ( $Debug > 1 ) {
  98       warn join('',
  99         map { "  $_ => ". $signup_data->{$_}. "\n" } keys %$signup_data );
 100     }
 101
 102     warn "[fs_signup_server] Processing signup...\n" if $Debug;
 103
 104     my $error = '';
 105
 106     #things that aren't necessary in base class, but are for signup server
 107       #return "Passwords don't match"
 108       #  if $hashref->{'_password'} ne $hashref->{'_password2'}
 109     $error ||= gettext('empty_password') unless $signup_data->{'_password'};
 110     $error ||= gettext('no_access_number_selected')
 111       unless $signup_data->{'popnum'} || !scalar(@pops);
 112
 113     #shares some stuff with htdocs/edit/process/cust_main.cgi... take any
 114     # common that are still here and library them.
 115     my $cust_main = new FS::cust_main ( {
 116       #'custnum'          => '',
 117       'agentnum'         => $signup_data->{agentnum} || $agentnum,
 118       'refnum'           => $refnum,
 119
 120       map { $_ => $signup_data->{$_} } qw(
 121         last first ss company address1 address2 city county state zip country
 122         daytime night fax payby payinfo paydate payname referral_custnum
 123       ),
 124
 125     } );
 126
 127     $error ||= "Illegal payment type"
 128       unless grep { $_ eq $signup_data->{'payby'} } @payby;
 129
 130     my @invoicing_list = split( /\s*\,\s*/, $signup_data->{'invoicing_list'} );
 131
 132     my $part_pkg =
 133       qsearchs( 'part_pkg', { 'pkgpart' => $signup_data->{'pkgpart'} } )
 134         or $error ||= "WARNING: unknown pkgpart ". $signup_data->{pkgpart};
 135     my $svcpart = $part_pkg->svcpart unless $error;
 136
 137     # this should wind up in FS::cust_pkg!
 138     my $agent = qsearchs( 'agent', { 'agentnum' => $agentnum } );
 139     #my $pkgpart_href = $agent->pkgpart_hashref;
 140     $error ||= "WARNING: agent $agentnum can't purchase pkgpart ".
 141                $signup_data->{pkgpart}
 142       unless $pkgpart_href->{ $signup_data->{pkgpart} };
 143
 144     my $cust_pkg = new FS::cust_pkg ( {
 145       #later#'custnum' => $custnum,
 146       'pkgpart' => $signup_data->{'pkgpart'},
 147     } );
 148     $error ||= $cust_pkg->check;
 149
 150     my $svc_acct = new FS::svc_acct ( {
 151       'svcpart'   => $svcpart,
 152       map { $_ => $signup_data->{$_} }
 153         qw( username _password sec_phrase popnum ),
 154     } );
 155
 156     my $y = $svc_acct->setdefault; # arguably should be in new method
 157     $error ||= $y unless ref($y);
 158
 159     $error ||= $svc_acct->check;
 160
 161     use Tie::RefHash;
 162     tie my %hash, 'Tie::RefHash';
 163     %hash = ( $cust_pkg => [ $svc_acct ] );
 164     $error ||= $cust_main->insert( \%hash, \@invoicing_list ); #msgcat
 165
 166     warn "[fs_signup_server] Sending results...\n" if $Debug;
 167     print $writer $error, "\n";
 168
 169     next if $error;
 170
 171     if ( $conf->exists('signup_server-realtime') ) {
 172
 173       warn "[fs_signup_server] Billing customer...\n" if $Debug;
 174
 175       my $bill_error = $cust_main->bill;
 176       warn "[fs_signup_server] error billing new customer: $bill_error"
 177         if $bill_error;
 178
 179       $cust_main->apply_payments;
 180       $cust_main->apply_credits;
 181
 182       $bill_error = $cust_main->collect;
 183       warn "[fs_signup_server] error collecting from new customer: $bill_error"
 184         if $bill_error;
 185
 186       if ( $cust_main->balance ) {
 187         #should check list for errors...
 188         $cust_main->suspend;
 189       }
 190     }
 191
 192     if ( $conf->config('signup_server-email') ) {
 193       warn "[fs_signup_server] Sending email...\n" if $Debug;
 194
 195       #false laziness w/FS::cust_bill::send & FS::cust_pay::delete
 196       use Mail::Header;
 197       use Mail::Internet;
 198       use Date::Format;
 199       my $from = $conf->config('invoice_from'); #??? as good as any
 200       $ENV{MAILADDRESS} = $from;
 201       my $header = new Mail::Header ( [
 202         "From: $from",
 203         "To: ". $conf->config('signup_server-email'),
 204         "Sender: $from",
 205         "Reply-To: $from",
 206         "Date: ". time2str("%a, %d %b %Y %X %z", time),
 207         "Subject: FREESIDE NOTIFICATION: Signup Server",
 208       ] );
 209       my $body = [
 210         "This is an automatic message from your Freeside installation\n",
 211         "informing you a customer has signed up via the signup server:\n",
 212         "\n",
 213         'custnum: '. $cust_main->custnum. "\n",
 214         'Name   : '. $cust_main->last. ", ". $cust_main->first. "\n",
 215         'Agent  : '. $cust_main->agent->agent. "\n",
 216         "\n",
 217       ];
 218       if ( $cust_main->balance ) {
 219         push @$body,
 220           "This customer has an outstanding balance and has been suspended.\n";
 221       }
 222       my $message = new Mail::Internet ( 'Header' => $header, 'Body' => $body );
 223       $!=0;
 224       $message->smtpsend( Host => $smtpmachine )
 225         or $message->smtpsend( Host => $smtpmachine, Debug => 1 )
 226           or warn "[fs_signup_server] can't send email to ".
 227                    $conf->config('signup_server-email').
 228                    " via server $smtpmachine with SMTP: $!";
 229       #end-of-send mail
 230     }
 231
 232   }
 233   close $writer;
 234   close $reader;
 235   warn "connection to $machine lost!  waiting 60 seconds...\n";
 236   sleep 60;
 237   warn "reconnecting...\n";
 238 }
 239
 240 sub usage {
 241   die "Usage:\n\n  fs_signup_server user machine agentnum refnum\n";
 242 }
 243