fs_selfservice/FS-SelfService/cgi/selfservice.cgi

   1 #!/usr/bin/perl -Tw
   2
   3 use strict;
   4 use vars qw($DEBUG $cgi $session_id $form_max $template_dir);
   5 use subs qw(do_template);
   6 use CGI;
   7 use CGI::Carp qw(fatalsToBrowser);
   8 use Text::Template;
   9 use HTML::Entities;
  10 use Date::Format;
  11 use Number::Format 1.50;
  12 use FS::SelfService qw( login_info login customer_info edit_info invoice
  13                         payment_info process_payment realtime_collect
  14                         process_prepay
  15                         list_pkgs order_pkg signup_info order_recharge
  16                         part_svc_info provision_acct provision_external
  17                         unprovision_svc change_pkg domainselector
  18                         list_svcs list_svc_usage list_support_usage
  19                         myaccount_passwd
  20                       );
  21
  22 $template_dir = '.';
  23
  24 $DEBUG = 1;
  25
  26 $form_max = 255;
  27
  28 $cgi = new CGI;
  29
  30 unless ( defined $cgi->param('session') ) {
  31   my $login_info = login_info();
  32
  33   do_template('login', $login_info );
  34   exit;
  35 }
  36
  37 if ( $cgi->param('session') eq 'login' ) {
  38
  39   $cgi->param('username') =~ /^\s*([a-z0-9_\-\.\&]{0,$form_max})\s*$/i
  40     or die "illegal username";
  41   my $username = $1;
  42
  43   $cgi->param('domain') =~ /^\s*([\w\-\.]{0,$form_max})\s*$/
  44     or die "illegal domain";
  45   my $domain = $1;
  46
  47   $cgi->param('password') =~ /^(.{0,$form_max})$/
  48     or die "illegal password";
  49   my $password = $1;
  50
  51   my $rv = login(
  52     'username' => $username,
  53     'domain'   => $domain,
  54     'password' => $password,
  55   );
  56   if ( $rv->{error} ) {
  57     my $login_info = login_info();
  58     do_template('login', {
  59       'error'    => $rv->{error},
  60       'username' => $username,
  61       'domain'   => $domain,
  62       %$login_info,
  63     } );
  64     exit;
  65   } else {
  66     $cgi->param('session' => $rv->{session_id} );
  67     $cgi->param('action'  => 'myaccount' );
  68   }
  69 }
  70
  71 $session_id = $cgi->param('session');
  72
  73 #order|pw_list XXX ???
  74 $cgi->param('action') =~
  75     /^(myaccount|view_invoice|make_payment|make_ach_payment|make_thirdparty_payment|payment_results|ach_payment_results|recharge_prepay|recharge_results|logout|change_bill|change_ship|change_pay|process_change_bill|process_change_ship|process_change_pay|customer_order_pkg|process_order_pkg|customer_change_pkg|process_change_pkg|process_order_recharge|provision|provision_svc|process_svc_acct|process_svc_external|delete_svc|view_usage|view_usage_details|view_support_details|change_password|process_change_password)$/
  76   or die "unknown action ". $cgi->param('action');
  77 my $action = $1;
  78
  79 warn "calling $action sub\n"
  80   if $DEBUG;
  81 $FS::SelfService::DEBUG = $DEBUG;
  82 my $result = eval "&$action();";
  83 die $@ if $@;
  84
  85 if ( $result->{error} eq "Can't resume session"
  86   || $result->{error} eq "Expired session" ) { #ick
  87
  88   my $login_info = login_info();
  89   do_template('login', $login_info);
  90   exit;
  91 }
  92
  93 #warn $result->{'open_invoices'};
  94 #warn scalar(@{$result->{'open_invoices'}});
  95
  96 warn "processing template $action\n"
  97   if $DEBUG;
  98 do_template($action, {
  99   'session_id' => $session_id,
 100   'action'     => $action, #so the menu knows what tab we're on...
 101   %{ payment_info( 'session_id' => $session_id ) },  # cust_paybys for the menu
 102   %{$result}
 103 });
 104
 105 #--
 106
 107 sub myaccount { customer_info( 'session_id' => $session_id ); }
 108
 109 sub change_bill { my $payment_info =
 110                     payment_info( 'session_id' => $session_id );
 111                   return $payment_info if ( $payment_info->{'error'} );
 112                   my $customer_info =
 113                     customer_info( 'session_id' => $session_id );
 114                   return {
 115                     %$payment_info,
 116                     %$customer_info,
 117                   };
 118                 }
 119 sub change_ship { change_bill(@_); }
 120 sub change_pay { change_bill(@_); }
 121
 122 sub _process_change_info {
 123   my ($erroraction, @fields) = @_;
 124
 125   my $results = '';
 126
 127   $results ||= edit_info (
 128     'session_id' => $session_id,
 129     map { ($_ => $cgi->param($_)) } grep { defined($cgi->param($_)) } @fields,
 130   );
 131
 132
 133   if ( $results->{'error'} ) {
 134     no strict 'refs';
 135     $action = $erroraction;
 136     return {
 137       $cgi->Vars,
 138       %{&$action()},
 139       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 140     };
 141   } else {
 142     return $results;
 143   }
 144 }
 145
 146 sub process_change_bill {
 147         _process_change_info( 'change_bill',
 148           qw( first last company address1 address2 city state
 149               county zip country daytime night fax )
 150         );
 151 }
 152
 153 sub process_change_ship {
 154         my @list = map { "ship_$_" }
 155                      qw( first last company address1 address2 city state
 156                          county zip country daytime night fax
 157                        );
 158         if ($cgi->param('same') eq 'Y') {
 159           foreach (@list) { $cgi->param($_, '') }
 160         }
 161
 162         _process_change_info( 'change_ship', @list );
 163 }
 164
 165 sub process_change_pay {
 166         my $postal = $cgi->param( 'postal_invoicing' );
 167         my @list =
 168           qw( payby payinfo payinfo1 payinfo2 month year payname
 169               address1 address2 city county state zip country auto paytype
 170               paystate ss stateid stateid_state invoicing_list
 171             );
 172         push @list, 'postal_invoicing' if $postal;
 173         unless ( $postal || $cgi->param( 'invoicing_list' ) ) {
 174           $action = 'change_pay';
 175           return {
 176             %{&change_pay()},
 177             $cgi->Vars,
 178             'error' => '<FONT COLOR="#FF0000">Postal or email required.</FONT>',
 179           };
 180         }
 181         _process_change_info( 'change_pay', @list );
 182 }
 183
 184 sub view_invoice {
 185
 186   $cgi->param('invnum') =~ /^(\d+)$/ or die "illegal invnum";
 187   my $invnum = $1;
 188
 189   invoice( 'session_id' => $session_id,
 190            'invnum'     => $invnum,
 191          );
 192
 193 }
 194
 195 sub customer_order_pkg {
 196   my $init_data = signup_info( 'customer_session_id' => $session_id );
 197   return $init_data if ( $init_data->{'error'} );
 198
 199   my $customer_info = customer_info( 'session_id' => $session_id );
 200   return $customer_info if ( $customer_info->{'error'} );
 201
 202   return {
 203     ( map { $_ => $init_data->{$_} }
 204           qw( part_pkg security_phrase svc_acct_pop ),
 205     ),
 206     %$customer_info,
 207   };
 208 }
 209
 210 sub customer_change_pkg {
 211   my $init_data = signup_info( 'customer_session_id' => $session_id );
 212   return $init_data if ( $init_data->{'error'} );
 213
 214   my $customer_info = customer_info( 'session_id' => $session_id );
 215   return $customer_info if ( $customer_info->{'error'} );
 216
 217   return {
 218     ( map { $_ => $init_data->{$_} }
 219           qw( part_pkg security_phrase svc_acct_pop ),
 220     ),
 221     ( map { $_ => $cgi->param($_) }
 222         qw( pkgnum pkg )
 223     ),
 224     %$customer_info,
 225   };
 226 }
 227
 228 sub process_order_pkg {
 229
 230   my $results = '';
 231
 232   unless ( length($cgi->param('_password')) ) {
 233     my $init_data = signup_info( 'customer_session_id' => $session_id );
 234     $results = { 'error' => $init_data->{msgcat}{empty_password} };
 235     $results = { 'error' => $init_data->{error} } if($init_data->{error});
 236   }
 237   if ( $cgi->param('_password') ne $cgi->param('_password2') ) {
 238     my $init_data = signup_info( 'customer_session_id' => $session_id );
 239     $results = { 'error' => $init_data->{msgcat}{passwords_dont_match} };
 240     $results = { 'error' => $init_data->{error} } if($init_data->{error});
 241     $cgi->param('_password', '');
 242     $cgi->param('_password2', '');
 243   }
 244
 245   $results ||= order_pkg (
 246     'session_id' => $session_id,
 247     map { $_ => $cgi->param($_) }
 248         qw( custnum pkgpart username _password _password2 sec_phrase popnum )
 249   );
 250
 251
 252   if ( $results->{'error'} ) {
 253     $action = 'customer_order_pkg';
 254     return {
 255       $cgi->Vars,
 256       %{customer_order_pkg()},
 257       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 258     };
 259   } else {
 260     return $results;
 261   }
 262
 263 }
 264
 265 sub process_change_pkg {
 266
 267   my $results = '';
 268
 269   $results ||= change_pkg (
 270     'session_id' => $session_id,
 271     map { $_ => $cgi->param($_) }
 272         qw( pkgpart pkgnum )
 273   );
 274
 275
 276   if ( $results->{'error'} ) {
 277     $action = 'customer_change_pkg';
 278     return {
 279       $cgi->Vars,
 280       %{customer_change_pkg()},
 281       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 282     };
 283   } else {
 284     return $results;
 285   }
 286
 287 }
 288
 289 sub process_order_recharge {
 290
 291   my $results = '';
 292
 293   $results ||= order_recharge (
 294     'session_id' => $session_id,
 295     map { $_ => $cgi->param($_) }
 296         qw( svcnum )
 297   );
 298
 299
 300   if ( $results->{'error'} ) {
 301     $action = 'view_usage';
 302     if ($results->{'error'} eq '_decline') {
 303       $results->{'error'} = "There has been an error processing your account.  Please contact customer support."
 304     }
 305     return {
 306       $cgi->Vars,
 307       %{view_usage()},
 308       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 309     };
 310   } else {
 311     return $results;
 312   }
 313
 314 }
 315
 316 sub make_payment {
 317   payment_info( 'session_id' => $session_id );
 318 }
 319
 320 sub payment_results {
 321
 322   use Business::CreditCard;
 323
 324   #we should only do basic checking here for DoS attacks and things
 325   #that couldn't be constructed by the web form...  let process_payment() do
 326   #the rest, it gives better error messages
 327
 328   $cgi->param('amount') =~ /^\s*(\d+(\.\d{2})?)\s*$/
 329     or die "Illegal amount: ". $cgi->param('amount'); #!!!
 330   my $amount = $1;
 331
 332   my $payinfo = $cgi->param('payinfo');
 333   $payinfo =~ s/\D//g;
 334   $payinfo =~ /^(\d{13,16})$/
 335     #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 336     or die "illegal card"; #!!!
 337   $payinfo = $1;
 338   validate($payinfo)
 339     #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 340     or die "invalid card"; #!!!
 341
 342   if ( $cgi->param('card_type') ) {
 343     cardtype($payinfo) eq $cgi->param('card_type')
 344       #or $error ||= $init_data->{msgcat}{not_a}. $cgi->param('CARD_type');
 345       or die "not a ". $cgi->param('card_type');
 346   }
 347
 348   $cgi->param('paycvv') =~ /^\s*(.{0,4})\s*$/ or die "illegal CVV2";
 349   my $paycvv = $1;
 350
 351   $cgi->param('month') =~ /^(\d{2})$/ or die "illegal month";
 352   my $month = $1;
 353   $cgi->param('year') =~ /^(\d{4})$/ or die "illegal year";
 354   my $year = $1;
 355
 356   $cgi->param('payname') =~ /^(.{0,80})$/ or die "illegal payname";
 357   my $payname = $1;
 358
 359   $cgi->param('address1') =~ /^(.{0,80})$/ or die "illegal address1";
 360   my $address1 = $1;
 361
 362   $cgi->param('address2') =~ /^(.{0,80})$/ or die "illegal address2";
 363   my $address2 = $1;
 364
 365   $cgi->param('city') =~ /^(.{0,80})$/ or die "illegal city";
 366   my $city = $1;
 367
 368   $cgi->param('state') =~ /^(.{2})$/ or die "illegal state";
 369   my $state = $1;
 370
 371   $cgi->param('zip') =~ /^(.{0,10})$/ or die "illegal zip";
 372   my $zip = $1;
 373
 374   my $save = 0;
 375   $save = 1 if $cgi->param('save');
 376
 377   my $auto = 0;
 378   $auto = 1 if $cgi->param('auto');
 379
 380   $cgi->param('paybatch') =~ /^([\w\-\.]+)$/ or die "illegal paybatch";
 381   my $paybatch = $1;
 382
 383   process_payment(
 384     'session_id' => $session_id,
 385     'payby'      => 'CARD',
 386     'amount'     => $amount,
 387     'payinfo'    => $payinfo,
 388     'paycvv'     => $paycvv,
 389     'month'      => $month,
 390     'year'       => $year,
 391     'payname'    => $payname,
 392     'address1'   => $address1,
 393     'address2'   => $address2,
 394     'city'       => $city,
 395     'state'      => $state,
 396     'zip'        => $zip,
 397     'save'       => $save,
 398     'auto'       => $auto,
 399     'paybatch'   => $paybatch,
 400   );
 401
 402 }
 403
 404 sub make_ach_payment {
 405   payment_info( 'session_id' => $session_id );
 406 }
 407
 408 sub ach_payment_results {
 409
 410   #we should only do basic checking here for DoS attacks and things
 411   #that couldn't be constructed by the web form...  let process_payment() do
 412   #the rest, it gives better error messages
 413
 414   $cgi->param('amount') =~ /^\s*(\d+(\.\d{2})?)\s*$/
 415     or die "illegal amount"; #!!!
 416   my $amount = $1;
 417
 418   my $payinfo1 = $cgi->param('payinfo1');
 419   $payinfo1=~ /^(\d+)$/
 420     or die "illegal account"; #!!!
 421   $payinfo1= $1;
 422
 423   my $payinfo2 = $cgi->param('payinfo2');
 424   $payinfo2=~ /^(\d+)$/
 425     or die "illegal ABA/routing code"; #!!!
 426   $payinfo2= $1;
 427
 428   $cgi->param('payname') =~ /^(.{0,80})$/ or die "illegal payname";
 429   my $payname = $1;
 430
 431   $cgi->param('paystate') =~ /^(.{0,2})$/ or die "illegal paystate";
 432   my $paystate = $1;
 433
 434   $cgi->param('paytype') =~ /^(.{0,80})$/ or die "illegal paytype";
 435   my $paytype = $1;
 436
 437   $cgi->param('ss') =~ /^(.{0,80})$/ or die "illegal ss";
 438   my $ss = $1;
 439
 440   $cgi->param('stateid') =~ /^(.{0,80})$/ or die "illegal stateid";
 441   my $stateid = $1;
 442
 443   $cgi->param('stateid_state') =~ /^(.{0,2})$/ or die "illegal stateid_state";
 444   my $stateid_state = $1;
 445
 446   my $save = 0;
 447   $save = 1 if $cgi->param('save');
 448
 449   my $auto = 0;
 450   $auto = 1 if $cgi->param('auto');
 451
 452   $cgi->param('paybatch') =~ /^([\w\-\.]+)$/ or die "illegal paybatch";
 453   my $paybatch = $1;
 454
 455   process_payment(
 456     'session_id' => $session_id,
 457     'payby'      => 'CHEK',
 458     'amount'     => $amount,
 459     'payinfo1'   => $payinfo1,
 460     'payinfo2'   => $payinfo2,
 461     'month'      => '12',
 462     'year'       => '2037',
 463     'payname'    => $payname,
 464     'paytype'    => $paytype,
 465     'paystate'   => $paystate,
 466     'ss'         => $ss,
 467     'stateid'    => $stateid,
 468     'stateid_state' => $stateid_state,
 469     'save'       => $save,
 470     'auto'       => $auto,
 471     'paybatch'   => $paybatch,
 472   );
 473
 474 }
 475
 476 sub make_thirdparty_payment {
 477   $cgi->param('payby_method') =~ /^(CC|ECHECK)$/
 478     or die "illegal payby method";
 479   realtime_collect( 'session_id' => $session_id, 'method' => $1 );
 480 }
 481
 482 sub recharge_prepay {
 483   customer_info( 'session_id' => $session_id );
 484 }
 485
 486 sub recharge_results {
 487
 488   my $prepaid_cardnum = $cgi->param('prepaid_cardnum');
 489   $prepaid_cardnum =~ s/\W//g;
 490   $prepaid_cardnum =~ /^(\w*)$/ or die "illegal prepaid card number";
 491   $prepaid_cardnum = $1;
 492
 493   process_prepay ( 'session_id'     => $session_id,
 494                    'prepaid_cardnum' => $prepaid_cardnum,
 495                  );
 496 }
 497
 498 sub logout {
 499   FS::SelfService::logout( 'session_id' => $session_id );
 500 }
 501
 502 sub provision {
 503   my $result = list_pkgs( 'session_id' => $session_id );
 504   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 505   $result;
 506 }
 507
 508 sub provision_svc {
 509
 510   my $result = part_svc_info(
 511     'session_id' => $session_id,
 512     map { $_ => $cgi->param($_) } qw( pkgnum svcpart ),
 513   );
 514   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 515
 516   $result->{'svcdb'} =~ /^svc_(.*)$/
 517     #or return { 'error' => 'Unknown svcdb '. $result->{'svcdb'} };
 518     or die 'Unknown svcdb '. $result->{'svcdb'};
 519   $action .= "_$1";
 520
 521   $result;
 522 }
 523
 524 sub process_svc_acct {
 525
 526   my $result = provision_acct (
 527     'session_id' => $session_id,
 528     map { $_ => $cgi->param($_) } qw(
 529       pkgnum svcpart username domsvc _password _password2 sec_phrase popnum )
 530   );
 531
 532   if ( exists $result->{'error'} && $result->{'error'} ) {
 533     #warn "$result $result->{'error'}";
 534     $action = 'provision_svc_acct';
 535     return {
 536       $cgi->Vars,
 537       %{ part_svc_info( 'session_id' => $session_id,
 538                         map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 539                       )
 540       },
 541       'error' => $result->{'error'},
 542     };
 543   } else {
 544     #warn "$result $result->{'error'}";
 545     return $result;
 546   }
 547
 548 }
 549
 550 sub process_svc_external {
 551   provision_external (
 552     'session_id' => $session_id,
 553     map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 554   );
 555 }
 556
 557 sub delete_svc {
 558   unprovision_svc(
 559     'session_id' => $session_id,
 560     'svcnum'     => $cgi->param('svcnum'),
 561   );
 562 }
 563
 564 sub view_usage {
 565   list_svcs(
 566     'session_id'  => $session_id,
 567     'svcdb'       => 'svc_acct',
 568     'ncancelled'  => 1,
 569   );
 570 }
 571
 572 sub view_usage_details {
 573   list_svc_usage(
 574     'session_id'  => $session_id,
 575     'svcnum'      => $cgi->param('svcnum'),
 576     'beginning'   => $cgi->param('beginning') || '',
 577     'ending'      => $cgi->param('ending') || '',
 578   );
 579 }
 580
 581 sub view_support_details {
 582   list_support_usage(
 583     'session_id'  => $session_id,
 584     'svcnum'      => $cgi->param('svcnum'),
 585     'beginning'   => $cgi->param('beginning') || '',
 586     'ending'      => $cgi->param('ending') || '',
 587   );
 588 }
 589
 590 sub change_password {
 591   list_svcs(
 592     'session_id' => $session_id,
 593     'svcdb'      => 'svc_acct',
 594   );
 595 };
 596
 597 sub process_change_password {
 598
 599   my $result = myaccount_passwd(
 600     'session_id'    => $session_id,
 601     map { $_ => $cgi->param($_) } qw( svcnum new_password new_password2 )
 602   );
 603
 604   if ( exists $result->{'error'} && $result->{'error'} ) {
 605
 606     $action = 'change_password';
 607     return {
 608       $cgi->Vars,
 609       %{ list_svcs( 'session_id' => $session_id,
 610                     'svcdb'      => 'svc_acct',
 611                   )
 612        },
 613       #'svcnum' => $cgi->param('svcnum'),
 614       'error'  => $result->{'error'}
 615     };
 616
 617  } else {
 618
 619    return $result;
 620
 621  }
 622
 623 }
 624
 625 #--
 626
 627 sub do_template {
 628   my $name = shift;
 629   my $fill_in = shift;
 630
 631   $cgi->delete_all();
 632   $fill_in->{'selfurl'} = $cgi->self_url;
 633   $fill_in->{'cgi'} = \$cgi;
 634
 635   my $source = "$template_dir/$name.html";
 636   #warn "creating template for $source\n";
 637   my $template = new Text::Template( TYPE       => 'FILE',
 638                                      SOURCE     => $source,
 639                                      DELIMITERS => [ '<%=', '%>' ],
 640                                      UNTAINT    => 1,
 641                                    )
 642     or die $Text::Template::ERROR;
 643
 644   #warn "filling in $template with $fill_in\n";
 645   print $cgi->header( '-expires' => 'now' ),
 646         $template->fill_in( PACKAGE => 'FS::SelfService::_selfservicecgi',
 647                             HASH    => $fill_in
 648                           );
 649 }
 650
 651 #*FS::SelfService::_selfservicecgi::include = \&Text::Template::fill_in_file;
 652
 653 package FS::SelfService::_selfservicecgi;
 654
 655 #use FS::SelfService qw(regionselector expselect popselector);
 656 use HTML::Entities;
 657 use FS::SelfService qw(regionselector popselector domainselector);
 658
 659 #false laziness w/agent.cgi
 660 sub include {
 661   my $name = shift;
 662   my $template = new Text::Template( TYPE   => 'FILE',
 663                                      SOURCE => "$main::template_dir/$name.html",
 664                                      DELIMITERS => [ '<%=', '%>' ],
 665                                      UNTAINT => 1,
 666                                    )
 667     or die $Text::Template::ERROR;
 668
 669   $template->fill_in( PACKAGE => 'FS::SelfService::_selfservicecgi',
 670                       #HASH    => $fill_in
 671                     );
 672
 673 }
 674