fs_selfservice/FS-SelfService/cgi/selfservice.cgi

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw($DEBUG $cgi $session_id $pw_session_id $form_max $template_dir);
   5 use subs qw(do_template);
   6 use CGI;
   7 use CGI::Carp qw(fatalsToBrowser);
   8 use CGI::Cookie;
   9 use Text::Template;
  10 use HTML::Entities;
  11 use Date::Format;
  12 use Date::Parse 'str2time';
  13 use Number::Format 1.50;
  14 use FS::SelfService qw(
  15   access_info login_info login customer_info edit_info invoice
  16   payment_info process_payment realtime_collect process_prepay
  17   list_pkgs order_pkg signup_info order_recharge
  18   part_svc_info provision_acct provision_external provision_phone
  19   unprovision_svc change_pkg suspend_pkg domainselector
  20   list_svcs list_svc_usage list_cdr_usage list_support_usage
  21   myaccount_passwd list_invoices create_ticket get_ticket did_report
  22   adjust_ticket_priority
  23   mason_comp port_graph
  24   start_thirdparty finish_thirdparty
  25   reset_passwd check_reset_passwd process_reset_passwd
  26 );
  27
  28 $template_dir = '.';
  29
  30 $DEBUG = 0;
  31
  32 $form_max = 255;
  33
  34 $cgi = new CGI;
  35
  36 #order|pw_list XXX ???
  37 my @actions = ( qw(
  38   myaccount
  39   tktcreate
  40   tktview
  41   ticket_priority
  42   didreport
  43   invoices
  44   view_invoice
  45   make_payment
  46   make_ach_payment
  47   make_term_payment
  48   make_thirdparty_payment
  49   post_thirdparty_payment
  50   finish_thirdparty_payment
  51   cancel_thirdparty_payment
  52   payment_results
  53   ach_payment_results
  54   recharge_prepay
  55   recharge_results
  56   logout
  57   change_bill
  58   change_ship
  59   change_pay
  60   process_change_bill
  61   process_change_ship
  62   process_change_pay
  63   customer_order_pkg
  64   process_order_pkg
  65   customer_change_pkg
  66   process_change_pkg
  67   process_order_recharge
  68   provision
  69   provision_svc
  70   process_svc_acct
  71   process_svc_phone
  72   process_svc_external
  73   delete_svc
  74   view_usage
  75   view_usage_details
  76   view_cdr_details
  77   view_support_details
  78   view_port_graph
  79   real_port_graph
  80   change_password
  81   process_change_password
  82   customer_suspend_pkg
  83   process_suspend_pkg
  84   switch_cust
  85 ));
  86
  87 my @nologin_actions = (qw(
  88   forgot_password
  89   do_forgot_password
  90   process_forgot_password
  91   do_process_forgot_password
  92   process_forgot_password_session
  93 ));
  94 push @actions, @nologin_actions;
  95 my %nologin_actions = map { $_=>1 } @nologin_actions;
  96
  97 my $action = 'myaccount'; # sensible default
  98
  99 if ( $cgi->param('action') =~ /^process_forgot_password_session_(\w+)$/ ) {
 100   $action = 'process_forgot_password_session';
 101   $pw_session_id = $1;
 102 } elsif ( $cgi->param('action') =~ /^(\w+)$/ ) {
 103   if (grep {$_ eq $1} @actions) {
 104     $action = $1;
 105   } else {
 106     warn "WARNING: unrecognized action '$1'\n";
 107   }
 108 }
 109
 110 unless ( $nologin_actions{$action} ) {
 111
 112   my %cookies = CGI::Cookie->fetch;
 113
 114   my $login_rv = {};
 115
 116   if ( exists($cookies{'session'}) ) {
 117
 118     $session_id = $cookies{'session'}->value;
 119
 120     if ( $session_id eq 'login' ) {
 121       # then we've just come back from the login page
 122
 123       $cgi->param('password') =~ /^(.{0,$form_max})$/;
 124       my $password = $1;
 125
 126       if ( $cgi->param('email') =~ /^\s*([a-z0-9_\-\.\@]{1,$form_max})\s*$/i ) {
 127
 128         my $email = $1;
 129         $login_rv = login(
 130           'email'    => $email,
 131           'password' => $password
 132         );
 133
 134         if ( $login_rv->{'error'} ) {
 135           my $ip = $cgi->remote_addr();
 136           warn("login failure [email $email] [ip $ip] [error $login_rv->{error}]");
 137         } else {
 138           #successful login
 139         }
 140
 141         $session_id = $login_rv->{'session_id'};
 142
 143       } else {
 144
 145         $cgi->param('username') =~ /^\s*([a-z0-9_\-\.\&]{0,$form_max})\s*$/i;
 146         my $username = $1;
 147
 148         $cgi->param('domain') =~ /^\s*([\w\-\.]{0,$form_max})\s*$/;
 149         my $domain = $1;
 150
 151         if ( $username and $domain and $password ) {
 152
 153           # authenticate
 154           $login_rv = login(
 155             'username' => $username,
 156             'domain'   => $domain,
 157             'password' => $password,
 158           );
 159           $session_id = $login_rv->{'session_id'};
 160
 161         } elsif ( $username or $domain or $password ) {
 162
 163           my $error = 'Illegal '; #XXX localization...
 164           my $count = 0;
 165           if ( !$username ) {
 166             $error .= 'username';
 167             $count++;
 168           }
 169           if ( !$domain )  {
 170             $error .= ', ' if $count;
 171             $error .= 'domain';
 172             $count++;
 173           }
 174           if ( !$password ) {
 175             $error .= ', ' if $count;
 176             $error .= 'and ' if $count > 1;
 177             $error .= 'password';
 178             $count++;
 179           }
 180           $error .= '.';
 181           $login_rv = {
 182             'username'  => $username,
 183             'domain'    => $domain,
 184             'password'  => $password,
 185             'error'     => $error,
 186           };
 187           $session_id = undef; # attempt login again
 188
 189         }
 190
 191       } # else there was no input, so show no error message
 192
 193     } # else session_id ne 'login'
 194
 195   } # else there is no session cookie
 196
 197   if ( !$session_id ) {
 198     # show the login page
 199     $session_id = 'login'; # set state
 200     my $login_info = login_info( 'agentnum' => scalar($cgi->param('agentnum')) );
 201
 202     do_template('login', { %$login_rv, %$login_info });
 203     exit;
 204   }
 205
 206   # at this point $session_id is a real session
 207
 208   if ( ! $login_rv->{'custnum'} && ! $login_rv->{'svcnum'} && $login_rv->{'customers'} ) {
 209     #select a customer if we're a multi-contact customer
 210     do_template('select_cust', { %$login_rv } );
 211     exit;
 212   }
 213
 214 }
 215
 216 warn "calling $action sub\n"
 217   if $DEBUG;
 218 $FS::SelfService::DEBUG = $DEBUG;
 219 my $result = eval "&$action();";
 220 die $@ if $@;
 221
 222 use Data::Dumper;
 223 warn Dumper($result) if $DEBUG;
 224
 225 if ( $result->{error} && ( $result->{error} eq "Can't resume session"
 226   || $result->{error} eq "Expired session") ) { #ick
 227
 228   $session_id = 'login';
 229   my $login_info = login_info( 'agentnum' => scalar($cgi->param('agentnum')) );
 230   do_template('login', $login_info);
 231   exit;
 232 }
 233
 234 #warn $result->{'open_invoices'};
 235 #warn scalar(@{$result->{'open_invoices'}});
 236
 237 warn "processing template $action\n"
 238   if $DEBUG;
 239 do_template($action, {
 240   'session_id' => $session_id,
 241   'action'     => $action, #so the menu knows what tab we're on...
 242   #%{ payment_info( 'session_id' => $session_id ) },  # cust_paybys for the menu
 243   %{$result}
 244 });
 245
 246 #--
 247
 248 sub switch_cust {
 249   $action = 'myaccount';
 250   FS::SelfService::switch_cust( 'session_id' => $session_id,
 251                                 'custnum'    => scalar($cgi->param('custnum')),
 252                               );
 253 }
 254
 255 sub myaccount {
 256   customer_info( 'session_id' => $session_id );
 257 }
 258
 259 sub change_bill { my $payment_info =
 260                     payment_info( 'session_id' => $session_id );
 261                   return $payment_info if ( $payment_info->{'error'} );
 262                   my $customer_info =
 263                     customer_info( 'session_id' => $session_id );
 264                   return {
 265                     %$payment_info,
 266                     %$customer_info,
 267                   };
 268                 }
 269 sub change_ship { change_bill(@_); }
 270 sub change_pay { change_bill(@_); }
 271
 272 sub _process_change_info {
 273   my ($erroraction, @fields) = @_;
 274
 275   my $results = '';
 276
 277   $results ||= edit_info (
 278     'session_id' => $session_id,
 279     map { ($_ => $cgi->param($_)) } grep { defined($cgi->param($_)) } @fields,
 280   );
 281
 282
 283   if ( $results->{'error'} ) {
 284     no strict 'refs';
 285     $action = $erroraction;
 286     return {
 287       $cgi->Vars,
 288       %{&$action()},
 289       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 290     };
 291   } else {
 292     return $results;
 293   }
 294 }
 295
 296 sub process_change_bill {
 297         _process_change_info( 'change_bill',
 298           qw( first last company address1 address2 city state
 299               county zip country daytime night fax )
 300         );
 301 }
 302
 303 sub process_change_ship {
 304         my @list = map { "ship_$_" }
 305                      qw( first last company address1 address2 city state
 306                          county zip country daytime night fax
 307                        );
 308         if ($cgi->param('same') eq 'Y') {
 309           foreach (@list) { $cgi->param($_, '') }
 310         }
 311
 312         _process_change_info( 'change_ship', @list );
 313 }
 314
 315 sub process_change_pay {
 316         my $postal = $cgi->param( 'postal_invoicing' );
 317         my $payby  = $cgi->param( 'payby' );
 318         my @list =
 319           qw( payby payinfo payinfo1 payinfo2 month year payname
 320               address1 address2 city county state zip country auto paytype
 321               paystate ss stateid stateid_state invoicing_list
 322             );
 323         push @list, 'postal_invoicing' if $postal;
 324         unless (    $payby ne 'BILL'
 325                  || $postal
 326                  || $cgi->param( 'invoicing_list' )
 327                )
 328         {
 329           $action = 'change_pay';
 330           return {
 331             %{&change_pay()},
 332             $cgi->Vars,
 333             'error' => '<FONT COLOR="#FF0000">Postal or email required.</FONT>',
 334           };
 335         }
 336
 337         _process_change_info( 'change_pay', @list );
 338 }
 339
 340 sub view_invoice {
 341
 342   $cgi->param('invnum') =~ /^(\d+)$/ or die "illegal invnum";
 343   my $invnum = $1;
 344
 345   invoice( 'session_id' => $session_id,
 346            'invnum'     => $invnum,
 347          );
 348
 349 }
 350
 351 sub invoices {
 352   list_invoices( 'session_id' => $session_id, );
 353 }
 354
 355 sub tktcreate {
 356   my $customer_info = customer_info( 'session_id' => $session_id );
 357   return $customer_info if ( $customer_info->{'error'} );
 358
 359   my $requestor = "";
 360   if ( $customer_info->{'invoicing_list'} ) {
 361     my @requestor = split( /\s*\,\s*/, $customer_info->{'invoicing_list'} );
 362     $requestor = $requestor[0] if scalar(@requestor);
 363   }
 364
 365   return { 'requestor' => $requestor }
 366     unless ($cgi->param('subject') && $cgi->param('message') &&
 367         length($cgi->param('subject')) && length($cgi->param('message')));
 368
 369  create_ticket( 'session_id' => $session_id,
 370                         'subject' => $cgi->param('subject'),
 371                         'message' => $cgi->param('message'),
 372                         'requestor' => $requestor,
 373             );
 374 }
 375
 376 sub tktview {
 377  get_ticket(    'session_id' => $session_id,
 378                 'ticket_id' => ($cgi->param('ticket_id') || ''),
 379                 'subject'   => ($cgi->param('subject') || ''),
 380                 'reply'     => ($cgi->param('reply') || ''),
 381             );
 382 }
 383
 384 sub ticket_priority {
 385   my %values;
 386   foreach ( $cgi->param ) {
 387     if ( /^ticket(\d+)$/ ) {
 388       # a 'ticket1001' param implies the existence of a 'priority1001' param
 389       # but if that's empty, we need to send it as empty rather than forget
 390       # it.
 391       $values{$1} = $cgi->param("priority$1") || '';
 392     }
 393   }
 394   $action = 'myaccount';
 395   # this returns an updated customer_info for myaccount
 396   adjust_ticket_priority( 'session_id' => $session_id,
 397                           'values'     => \%values );
 398 }
 399
 400 sub customer_order_pkg {
 401   my $init_data = signup_info( 'customer_session_id' => $session_id );
 402   return $init_data if ( $init_data->{'error'} );
 403
 404   my $customer_info = customer_info( 'session_id' => $session_id );
 405   return $customer_info if ( $customer_info->{'error'} );
 406
 407   my $pkgselect = mason_comp(
 408     'session_id' => $session_id,
 409     'comp'       => '/edit/cust_main/first_pkg/select-part_pkg.html',
 410     'args'       => [ 'password_verify' => 1,
 411                       'onchange'        => 'enable_order_pkg()',
 412                       'relurls'         => 1,
 413                       'empty_label'     => 'Select package',
 414                     ],
 415   );
 416
 417   $pkgselect = $pkgselect->{'error'} || $pkgselect->{'output'};
 418
 419   return {
 420     ( map { $_ => $init_data->{$_} }
 421           qw( part_pkg security_phrase svc_acct_pop ),
 422     ),
 423     %$customer_info,
 424     'pkg_selector' => $pkgselect,
 425   };
 426 }
 427
 428 sub customer_change_pkg {
 429   my $init_data = signup_info( 'customer_session_id' => $session_id );
 430   return $init_data if ( $init_data->{'error'} );
 431
 432   my $customer_info = customer_info( 'session_id' => $session_id );
 433   return $customer_info if ( $customer_info->{'error'} );
 434
 435   return {
 436     ( map { $_ => $init_data->{$_} }
 437           qw( part_pkg security_phrase svc_acct_pop ),
 438     ),
 439     ( map { $_ => $cgi->param($_) }
 440         qw( pkgnum pkg )
 441     ),
 442     %$customer_info,
 443   };
 444 }
 445
 446 sub process_order_pkg {
 447
 448   my $results = '';
 449
 450   my @params = (qw( custnum pkgpart ));
 451   my $svcdb = '';
 452   if ( $cgi->param('pkgpart_svcpart') =~ /^(\d+)_(\d+)$/ ) {
 453     $cgi->param('pkgpart', $1);
 454     $cgi->param('svcpart', $2);
 455     push @params, 'svcpart';
 456     $svcdb = $cgi->param('svcdb');
 457     push @params, 'domsvc' if $svcdb eq 'svc_acct';
 458   } else {
 459     $svcdb = 'svc_acct';
 460   }
 461
 462   if ( $svcdb eq 'svc_acct' ) {
 463
 464     push @params, qw( username _password _password2 sec_phrase popnum );
 465
 466     unless ( length($cgi->param('_password')) ) {
 467       my $init_data = signup_info( 'customer_session_id' => $session_id );
 468       $results = { 'error' => $init_data->{msgcat}{empty_password} };
 469       $results = { 'error' => $init_data->{error} } if($init_data->{error});
 470     }
 471     if ( $cgi->param('_password') ne $cgi->param('_password2') ) {
 472       my $init_data = signup_info( 'customer_session_id' => $session_id );
 473       $results = { 'error' => $init_data->{msgcat}{passwords_dont_match} };
 474       $results = { 'error' => $init_data->{error} } if($init_data->{error});
 475       $cgi->param('_password', '');
 476       $cgi->param('_password2', '');
 477     }
 478
 479   } elsif ( $svcdb eq 'svc_phone' ) {
 480
 481     push @params, qw( phonenum sip_password pin phone_name );
 482
 483   } else {
 484     die "$svcdb not handled on process_order_pkg yet";
 485   }
 486
 487   $results ||= order_pkg (
 488     'session_id' => $session_id,
 489     map { $_ => $cgi->param($_) } @params
 490   );
 491
 492
 493   if ( $results->{'error'} ) {
 494     $action = 'customer_order_pkg';
 495     return {
 496       $cgi->Vars,
 497       %{customer_order_pkg()},
 498       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 499     };
 500   } else {
 501     return $results;
 502   }
 503
 504 }
 505
 506 sub process_change_pkg {
 507
 508   my $results = '';
 509
 510   $results ||= change_pkg (
 511     'session_id' => $session_id,
 512     map { $_ => $cgi->param($_) }
 513         qw( pkgpart pkgnum )
 514   );
 515
 516
 517   if ( $results->{'error'} ) {
 518     $action = 'customer_change_pkg';
 519     return {
 520       $cgi->Vars,
 521       %{customer_change_pkg()},
 522       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 523     };
 524   } else {
 525     return $results;
 526   }
 527
 528 }
 529
 530 sub process_suspend_pkg {
 531   my $results = '';
 532   $results = suspend_pkg (
 533     'session_id' => $session_id,
 534     map { $_ => $cgi->param($_) }
 535       qw( pkgnum )
 536     );
 537   if ( $results->{'error'} ) {
 538     $action = 'provision';
 539     return {
 540       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 541     }
 542   }
 543   else {
 544     return $results;
 545   }
 546 }
 547
 548 sub process_order_recharge {
 549
 550   my $results = '';
 551
 552   $results ||= order_recharge (
 553     'session_id' => $session_id,
 554     map { $_ => $cgi->param($_) }
 555         qw( svcnum )
 556   );
 557
 558
 559   if ( $results->{'error'} ) {
 560     $action = 'view_usage';
 561     if ($results->{'error'} eq '_decline') {
 562       $results->{'error'} = "There has been an error processing your account.  Please contact customer support."
 563     }
 564     return {
 565       $cgi->Vars,
 566       %{view_usage()},
 567       'error' => '<FONT COLOR="#FF0000">'. $results->{'error'}. '</FONT>',
 568     };
 569   } else {
 570     return $results;
 571   }
 572
 573 }
 574
 575 sub make_payment {
 576
 577   my $payment_info = payment_info( 'session_id' => $session_id );
 578
 579   my $tr_amount_fee = mason_comp(
 580     'session_id' => $session_id,
 581     'comp'       => '/elements/tr-amount_fee.html',
 582     'args'       => [ 'amount' => $payment_info->{'balance'},
 583                     ],
 584   );
 585
 586   $tr_amount_fee = $tr_amount_fee->{'error'} || $tr_amount_fee->{'output'};
 587
 588   $payment_info->{'tr_amount_fee'} = $tr_amount_fee;
 589
 590   $payment_info;
 591 }
 592
 593 sub payment_results {
 594
 595   use Business::CreditCard 0.30;
 596
 597   #we should only do basic checking here for DoS attacks and things
 598   #that couldn't be constructed by the web form...  let process_payment() do
 599   #the rest, it gives better error messages
 600
 601   $cgi->param('amount') =~ /^\s*(\d+(\.\d{2})?)\s*$/
 602     or die "Illegal amount: ". $cgi->param('amount'); #!!!
 603   my $amount = $1;
 604
 605   my $payinfo = $cgi->param('payinfo');
 606   $payinfo =~ s/[^\dx]//g;
 607   $payinfo =~ /^([\dx]{13,16}|[\dx]{8,9})$/
 608     #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 609     or die "illegal card"; #!!!
 610   $payinfo = $1;
 611   unless ( $payinfo =~ /x/ ) {
 612     validate($payinfo)
 613       #or $error ||= $init_data->{msgcat}{invalid_card}; #. $self->payinfo;
 614       or die "invalid card"; #!!!
 615   }
 616
 617   if ( $cgi->param('card_type') ) {
 618     cardtype($payinfo) eq $cgi->param('card_type')
 619       #or $error ||= $init_data->{msgcat}{not_a}. $cgi->param('CARD_type');
 620       or die "not a ". $cgi->param('card_type');
 621   }
 622
 623   $cgi->param('paycvv') =~ /^\s*(.{0,4})\s*$/ or die "illegal CVV2";
 624   my $paycvv = $1;
 625
 626   $cgi->param('month') =~ /^(\d{2})$/ or die "illegal month";
 627   my $month = $1;
 628   $cgi->param('year') =~ /^(\d{4})$/ or die "illegal year";
 629   my $year = $1;
 630
 631   $cgi->param('payname') =~ /^(.{0,80})$/ or die "illegal payname";
 632   my $payname = $1;
 633
 634   $cgi->param('address1') =~ /^(.{0,80})$/ or die "illegal address1";
 635   my $address1 = $1;
 636
 637   $cgi->param('address2') =~ /^(.{0,80})$/ or die "illegal address2";
 638   my $address2 = $1;
 639
 640   $cgi->param('city') =~ /^(.{0,80})$/ or die "illegal city";
 641   my $city = $1;
 642
 643   $cgi->param('state') =~ /^(.{0,80})$/ or die "illegal state";
 644   my $state = $1;
 645
 646   $cgi->param('zip') =~ /^(.{0,10})$/ or die "illegal zip";
 647   my $zip = $1;
 648
 649   $cgi->param('country') =~ /^(.{0,2})$/ or die "illegal country";
 650   my $country = $1;
 651
 652   my $save = 0;
 653   $save = 1 if $cgi->param('save');
 654
 655   my $auto = 0;
 656   $auto = 1 if $cgi->param('auto');
 657
 658   $cgi->param('payunique') =~ /^([\w\-\.]*)$/ or die "illegal payunique";
 659   my $payunique = $1;
 660
 661   $cgi->param('paybatch') =~ /^([\w\-\.]*)$/ or die "illegal paybatch";
 662   my $paybatch = $1;
 663
 664   $cgi->param('discount_term') =~ /^(\d*)$/ or die "illegal discount_term";
 665   my $discount_term = $1;
 666
 667
 668   process_payment(
 669     'session_id' => $session_id,
 670     'payby'      => 'CARD',
 671     'amount'     => $amount,
 672     'payinfo'    => $payinfo,
 673     'paycvv'     => $paycvv,
 674     'month'      => $month,
 675     'year'       => $year,
 676     'payname'    => $payname,
 677     'address1'   => $address1,
 678     'address2'   => $address2,
 679     'city'       => $city,
 680     'state'      => $state,
 681     'zip'        => $zip,
 682     'country'    => $country,
 683     'save'       => $save,
 684     'auto'       => $auto,
 685     'payunique'  => $payunique,
 686     'paybatch'   => $paybatch,
 687     'discount_term' => $discount_term,
 688   );
 689
 690 }
 691
 692 sub make_ach_payment {
 693   payment_info( 'session_id' => $session_id );
 694 }
 695
 696 sub ach_payment_results {
 697
 698   #we should only do basic checking here for DoS attacks and things
 699   #that couldn't be constructed by the web form...  let process_payment() do
 700   #the rest, it gives better error messages
 701
 702   $cgi->param('amount') =~ /^\s*(\d+(\.\d{2})?)\s*$/
 703     or die "illegal amount"; #!!!
 704   my $amount = $1;
 705
 706   my $payinfo1 = $cgi->param('payinfo1');
 707   $payinfo1 =~ s/[^\dx]//g;
 708   $payinfo1 =~ /^([\dx]+)$/
 709     or die "illegal account"; #!!!
 710   $payinfo1 = $1;
 711
 712   my $payinfo2 = $cgi->param('payinfo2');
 713   $payinfo2 =~ s/[^\dx]//g;
 714   $payinfo2 =~ /^([\dx]+)$/
 715     or die "illegal ABA/routing code"; #!!!
 716   $payinfo2 = $1;
 717
 718   $cgi->param('payname') =~ /^(.{0,80})$/ or die "illegal payname";
 719   my $payname = $1;
 720
 721   $cgi->param('paystate') =~ /^(.{0,2})$/ or die "illegal paystate";
 722   my $paystate = $1;
 723
 724   $cgi->param('paytype') =~ /^(.{0,80})$/ or die "illegal paytype";
 725   my $paytype = $1;
 726
 727   $cgi->param('ss') =~ /^(.{0,80})$/ or die "illegal ss";
 728   my $ss = $1;
 729
 730   $cgi->param('stateid') =~ /^(.{0,80})$/ or die "illegal stateid";
 731   my $stateid = $1;
 732
 733   $cgi->param('stateid_state') =~ /^(.{0,2})$/ or die "illegal stateid_state";
 734   my $stateid_state = $1;
 735
 736   my $save = 0;
 737   $save = 1 if $cgi->param('save');
 738
 739   my $auto = 0;
 740   $auto = 1 if $cgi->param('auto');
 741
 742   $cgi->param('paybatch') =~ /^([\w\-\.]+)$/ or die "illegal paybatch";
 743   my $paybatch = $1;
 744
 745   process_payment(
 746     'session_id' => $session_id,
 747     'payby'      => 'CHEK',
 748     'amount'     => $amount,
 749     'payinfo1'   => $payinfo1,
 750     'payinfo2'   => $payinfo2,
 751     'month'      => '12',
 752     'year'       => '2037',
 753     'payname'    => $payname,
 754     'paytype'    => $paytype,
 755     'paystate'   => $paystate,
 756     'ss'         => $ss,
 757     'stateid'    => $stateid,
 758     'stateid_state' => $stateid_state,
 759     'save'       => $save,
 760     'auto'       => $auto,
 761     'paybatch'   => $paybatch,
 762   );
 763
 764 }
 765
 766 sub make_thirdparty_payment {
 767   my $payment_info = payment_info('session_id' => $session_id);
 768   $cgi->param('payby_method') =~ /^(CC|ECHECK|PAYPAL)$/
 769     or die "illegal payby method";
 770   $payment_info->{'payby_method'} = $1;
 771   $payment_info->{'error'} = $cgi->param('error');
 772
 773   $payment_info;
 774 }
 775
 776 sub post_thirdparty_payment {
 777   $cgi->param('payby_method') =~ /^(CC|ECHECK|PAYPAL)$/
 778     or die "illegal payby method";
 779   my $method = $1;
 780   $cgi->param('amount') =~ /^(\d+(\.\d*)?)$/
 781     or die "illegal amount";
 782   my $amount = $1;
 783   my $result = start_thirdparty(
 784     'session_id' => $session_id,
 785     'method' => $method,
 786     'amount' => $amount,
 787   );
 788   if ( $result->{error} ) {
 789     $cgi->param('action', 'make_thirdparty_payment');
 790     $cgi->param('error', $result->{error});
 791     print $cgi->redirect( $cgi->self_url );
 792     exit;
 793   }
 794
 795   $result;
 796 }
 797
 798 sub finish_thirdparty_payment {
 799   my %param = $cgi->Vars;
 800   finish_thirdparty( 'session_id' => $session_id, %param );
 801   # result contains either 'error' => error message, or the payment details
 802 }
 803
 804 sub cancel_thirdparty_payment {
 805   $action = 'make_thirdparty_payment';
 806   finish_thirdparty( 'session_id' => $session_id, '_cancel' => 1 );
 807 }
 808
 809 sub make_term_payment {
 810   $cgi->param('amount') =~ /^(\d+\.\d{2})$/
 811     or die "illegal payment amount";
 812   my $balance = $1;
 813   $cgi->param('discount_term') =~ /^(\d+)$/
 814     or die "illegal discount term";
 815   my $discount_term = $1;
 816   $action = 'make_payment';
 817   ({ %{payment_info( 'session_id' => $session_id )},
 818     'balance' => $balance,
 819     'discount_term' => $discount_term,
 820   })
 821 }
 822
 823 sub recharge_prepay {
 824   customer_info( 'session_id' => $session_id );
 825 }
 826
 827 sub recharge_results {
 828
 829   my $prepaid_cardnum = $cgi->param('prepaid_cardnum');
 830   $prepaid_cardnum =~ s/\W//g;
 831   $prepaid_cardnum =~ /^(\w*)$/ or die "illegal prepaid card number";
 832   $prepaid_cardnum = $1;
 833
 834   process_prepay ( 'session_id'     => $session_id,
 835                    'prepaid_cardnum' => $prepaid_cardnum,
 836                  );
 837 }
 838
 839 sub logout {
 840   FS::SelfService::logout( 'session_id' => $session_id );
 841 }
 842
 843 sub didreport {
 844   my $result = did_report( 'session_id' => $session_id,
 845             'format' => $cgi->param('type'),
 846             'recentonly' => $cgi->param('recentonly'),
 847         );
 848   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 849   $result;
 850 }
 851
 852 sub provision {
 853   my $result = list_pkgs( 'session_id' => $session_id );
 854   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 855   $result->{'pkgpart'} = $cgi->param('pkgpart') if $cgi->param('pkgpart');
 856   $result->{'filter'} = $cgi->param('filter') if $cgi->param('filter');
 857   $result;
 858 }
 859
 860 sub provision_svc {
 861
 862   my $result = part_svc_info(
 863     'session_id' => $session_id,
 864     map { $_ => $cgi->param($_) } qw( pkgnum svcpart svcnum ),
 865   );
 866   die $result->{'error'} if exists $result->{'error'} && $result->{'error'};
 867
 868   $result->{'svcdb'} =~ /^svc_(.*)$/
 869     #or return { 'error' => 'Unknown svcdb '. $result->{'svcdb'} };
 870     or die 'Unknown svcdb '. $result->{'svcdb'};
 871   $action .= "_$1";
 872
 873   $result->{'numavail'} = $cgi->param('numavail');
 874   $result->{'lnp'} = $cgi->param('lnp');
 875
 876   $result;
 877 }
 878
 879 sub process_svc_phone {
 880     my @bulkdid = $cgi->param('bulkdid');
 881     my $phonenum = $cgi->param('phonenum');
 882     my $lnp = $cgi->param('lnp');
 883
 884     my $result;
 885     if($lnp) {
 886         $result = provision_phone (
 887             'session_id' => $session_id,
 888             'countrycode' => '1',
 889              map { $_ => $cgi->param($_) } qw( pkgnum svcpart phonenum
 890                 lnp_desired_due_date lnp_other_provider
 891                 lnp_other_provider_account )
 892         );
 893     } else {
 894         $result = provision_phone (
 895             'session_id' => $session_id,
 896             'bulkdid' => [ @bulkdid ],
 897             'countrycode' => '1',
 898              map { $_ => $cgi->param($_) } qw( pkgnum svcpart phonenum svcnum email forwarddst )
 899         );
 900     }
 901
 902     if ( exists $result->{'error'} && $result->{'error'} ) {
 903         $action = 'provision_svc_phone';
 904         return {
 905           $cgi->Vars,
 906           %{ part_svc_info( 'session_id' => $session_id,
 907                         map { $_ => $cgi->param($_) } qw( pkgnum svcpart svcnum )
 908               )
 909           },
 910           'error' => $result->{'error'},
 911         };
 912   }
 913
 914   $result;
 915 }
 916
 917 sub process_svc_acct {
 918
 919   my $result = provision_acct (
 920     'session_id' => $session_id,
 921     map { $_ => $cgi->param($_) } qw(
 922       pkgnum svcpart username domsvc _password _password2 sec_phrase popnum )
 923   );
 924
 925   if ( exists $result->{'error'} && $result->{'error'} ) {
 926     #warn "$result $result->{'error'}";
 927     $action = 'provision_svc_acct';
 928     return {
 929       $cgi->Vars,
 930       %{ part_svc_info( 'session_id' => $session_id,
 931                         map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 932                       )
 933       },
 934       'error' => $result->{'error'},
 935     };
 936   } else {
 937     #warn "$result $result->{'error'}";
 938     return $result;
 939   }
 940
 941 }
 942
 943 sub process_svc_external {
 944   provision_external (
 945     'session_id' => $session_id,
 946     map { $_ => $cgi->param($_) } qw( pkgnum svcpart )
 947   );
 948 }
 949
 950 sub delete_svc {
 951   unprovision_svc(
 952     'session_id' => $session_id,
 953     'svcnum'     => $cgi->param('svcnum'),
 954   );
 955 }
 956
 957 sub view_usage {
 958   my $res = list_svcs(
 959     'session_id'  => $session_id,
 960     'svcdb'       => [ 'svc_acct', 'svc_phone', 'svc_port', ],
 961     'ncancelled'  => 1,
 962   );
 963   if ($res->{hide_usage}) {
 964     $action = 'myaccount';
 965     return myaccount();
 966   } else {
 967     return $res;
 968   }
 969 }
 970
 971 sub real_port_graph {
 972     my $svcnum = $cgi->param('svcnum');
 973     my $res = port_graph(
 974             'session_id'  => $session_id,
 975             'svcnum'      => $svcnum,
 976             'beginning'   => str2time($cgi->param('start')." 00:00:00"),
 977             'ending'      => str2time($cgi->param('end')  ." 23:59:59"),
 978             );
 979     my @usage = @{$res->{'usage'}};
 980     my $png = $usage[0]->{'png'};
 981     { 'content' => $png, 'format' => 'png' };
 982 }
 983
 984 sub view_port_graph {
 985     my $svcnum = $cgi->param('svcnum');
 986     { 'svcnum' => $svcnum,
 987       'start' => $cgi->param($svcnum.'_start'),
 988       'end' => $cgi->param($svcnum.'_end'),
 989     }
 990 }
 991
 992 sub view_usage_details {
 993       list_svc_usage(
 994         'session_id'  => $session_id,
 995         'svcnum'      => $cgi->param('svcnum'),
 996         'beginning'   => $cgi->param('beginning') || '',
 997         'ending'      => $cgi->param('ending') || '',
 998       );
 999 }
1000
1001 sub view_cdr_details {
1002   list_cdr_usage(
1003     'session_id'  => $session_id,
1004     'svcnum'      => $cgi->param('svcnum'),
1005     'beginning'   => $cgi->param('beginning') || '',
1006     'ending'      => $cgi->param('ending') || '',
1007     'inbound'     => $cgi->param('inbound') || 0,
1008   );
1009 }
1010
1011 sub view_support_details {
1012   list_support_usage(
1013     'session_id'  => $session_id,
1014     'svcnum'      => $cgi->param('svcnum'),
1015     'beginning'   => $cgi->param('beginning') || '',
1016     'ending'      => $cgi->param('ending') || '',
1017   );
1018 }
1019
1020 sub change_password {
1021   list_svcs(
1022     'session_id' => $session_id,
1023     'svcdb'      => 'svc_acct',
1024   );
1025 };
1026
1027 sub process_change_password {
1028
1029   my $result = myaccount_passwd(
1030     'session_id'    => $session_id,
1031     map { $_ => $cgi->param($_) } qw( svcnum new_password new_password2 )
1032   );
1033
1034   if ( exists $result->{'error'} && $result->{'error'} ) {
1035
1036     $action = 'change_password';
1037     return {
1038       $cgi->Vars,
1039       %{ list_svcs( 'session_id' => $session_id,
1040                     'svcdb'      => 'svc_acct',
1041                   )
1042        },
1043       #'svcnum' => $cgi->param('svcnum'),
1044       'error'  => $result->{'error'}
1045     };
1046
1047  } else {
1048
1049    return $result;
1050
1051  }
1052
1053 }
1054
1055 sub forgot_password {
1056   login_info( 'agentnum' => scalar($cgi->param('agentnum')) );
1057 }
1058
1059 sub do_forgot_password {
1060   reset_passwd(
1061     map { $_ => scalar($cgi->param($_)) }
1062       qw( agentnum email username domain )
1063   );
1064 }
1065
1066 sub process_forgot_password {
1067   check_reset_passwd(
1068     map { $_ => scalar($cgi->param($_)) }
1069       qw( session_id )
1070   );
1071 }
1072
1073 sub process_forgot_password_session {
1074   $action = 'process_forgot_password';
1075   check_reset_passwd(
1076     'session_id' => $pw_session_id,
1077   );
1078 }
1079
1080 sub do_process_forgot_password {
1081   process_reset_passwd(
1082     map { $_ => scalar($cgi->param($_)) }
1083       qw( session_id new_password new_password2 )
1084   );
1085 }
1086
1087 #--
1088
1089 sub do_template {
1090   my $name = shift;
1091   my $fill_in = shift;
1092
1093   $cgi->delete_all();
1094   $fill_in->{'selfurl'} = $cgi->self_url;
1095   $fill_in->{'cgi'} = \$cgi;
1096   $fill_in->{'error'} = $cgi->param('error') if $cgi->param('error');
1097
1098   my $access_info = ($session_id and $session_id ne 'login')
1099                       ? access_info( 'session_id' => $session_id )
1100                       : {};
1101   $fill_in->{$_} = $access_info->{$_} foreach keys %$access_info;
1102
1103   # update the user's authentication
1104   my $timeout = $access_info->{'timeout'} || '3600';
1105   my $cookie = CGI::Cookie->new('-name'     => 'session',
1106                                 '-value'    => $session_id,
1107                                 '-expires'  => '+'.$timeout.'s',
1108                                 #'-secure'   => 1, # would be a good idea...
1109                                );
1110   if ( $name eq 'logout' ) {
1111     $cookie->expires(0);
1112   }
1113
1114   if ( $fill_in->{'format'} ) {
1115     # then override content-type, and return $fill_in->{'content'} instead
1116     # of filling in a template
1117     if ( $fill_in->{'format'} eq 'csv') {
1118       print $cgi->header('-expires' => 'now',
1119         '-Content-Type' => 'text/csv',
1120         '-Content-Disposition' => "attachment;filename=output.csv",
1121       );
1122     } elsif ( $fill_in->{'format'} eq 'xls' ) {
1123       print $cgi->header('-expires' => 'now',
1124         '-Content-Type' => 'application/vnd.ms-excel',
1125         '-Content-Disposition' => "attachment;filename=output.xls",
1126         '-Content-Length' => length($fill_in->{'content'}),
1127       );
1128     } elsif ( $fill_in->{'format'} eq 'png' ) {
1129       print $cgi->header('-expires' => 'now',
1130         '-Content-Type' => 'image/png',
1131       );
1132     }
1133     print $fill_in->{'content'};
1134   } else { # the usual case
1135     my $source = "$template_dir/$name.html";
1136     my $template = new Text::Template(
1137       TYPE       => 'FILE',
1138       SOURCE     => $source,
1139       DELIMITERS => [ '<%=', '%>' ],
1140       UNTAINT    => 1,
1141     )
1142       or die $Text::Template::ERROR;
1143
1144     my $data = $template->fill_in(
1145       PACKAGE => 'FS::SelfService::_selfservicecgi',
1146       HASH    => $fill_in,
1147     ) || "Error processing template $source"; # at least print _something_
1148     print $cgi->header( '-cookie' => $cookie,
1149                         '-expires' => 'now' );
1150     print $data;
1151   }
1152 }
1153
1154 #*FS::SelfService::_selfservicecgi::include = \&Text::Template::fill_in_file;
1155
1156 package FS::SelfService::_selfservicecgi;
1157
1158 use HTML::Entities;
1159 use FS::SelfService qw(
1160     regionselector popselector domainselector location_form didselector
1161 );
1162
1163 #false laziness w/agent.cgi
1164 use vars qw(@INCLUDE_ARGS);
1165 sub include {
1166   my $name = shift;
1167
1168   @INCLUDE_ARGS = @_;
1169
1170   my $template = new Text::Template( TYPE   => 'FILE',
1171                                      SOURCE => "$main::template_dir/$name.html",
1172                                      DELIMITERS => [ '<%=', '%>' ],
1173                                      UNTAINT => 1,
1174                                    )
1175     or die $Text::Template::ERROR;
1176
1177   $template->fill_in( PACKAGE => 'FS::SelfService::_selfservicecgi',
1178                       #HASH    => $fill_in
1179                     );
1180
1181 }
1182
1183