bin/cdr-vitelity.import

   1 #!/usr/bin/perl
   2
   3 =pod
   4
   5 cdr-vitelity.import [ -v ] [ -k ]
   6                     -s date -e date
   7                     username
   8                     [ exportnum ]
   9
  10 Download CDRs using the Vitelity API.
  11
  12 -v: Be verbose.
  13
  14 -k: Keep the .csv file for debugging purposes, instead of deleting it.
  15
  16 -s date: Import only records on or after 'date'  Now required as the Vitelity
  17 API has changed.
  18
  19 -e date: Import only records before 'date'.  Now required as the Vitelity API
  20 has changed.
  21
  22 username: a Freeside user
  23
  24 exportnum: Run only for that export.  If not specified, this will run for
  25 all Vitelity exports.
  26
  27 =cut
  28
  29 use strict;
  30 use FS::UID qw(adminsuidsetup dbh);
  31 use FS::Record qw(qsearchs qsearch);
  32 use FS::cdr;
  33 use FS::part_export;
  34 use Getopt::Std;
  35 use File::Temp;
  36 use Date::Format 'time2str';
  37 use Date::Parse 'str2time';
  38
  39 my %opt;
  40 getopts('vks:e:', \%opt);
  41
  42 my $user = shift or die &usage;
  43 my $exportnum = shift;
  44 my $dbh = adminsuidsetup $user;
  45
  46 my $start = $opt{'s'} ? str2time($opt{'s'}) : die &usage('-s is now required');
  47 my $end   = $opt{'e'} ? str2time($opt{'e'}) : die &usage('-e is now required');
  48
  49 local $FS::UID::AutoCommit = 0;
  50
  51 my @part_exports;
  52 if ( $exportnum ) {
  53   @part_exports = ( qsearchs('part_export', { 'exportnum' => $exportnum }) )
  54     or die "exportnum $exportnum not found\n";
  55 }
  56 else {
  57   @part_exports = qsearch('part_export', { 'exporttype' => 'vitelity' })
  58     or die "no Vitelity exports found\n";
  59 }
  60
  61 foreach my $export (@part_exports) {
  62   my $exportnum = $export->exportnum;
  63   print "Processing exportnum $exportnum.\n" if $opt{'v'};
  64   $export->isa('FS::part_export::vitelity')
  65     or die "exportnum $exportnum is not a Vitelity export\n";
  66
  67   if ( $opt{'r'} ) {
  68     my $result = $export->vitelity_command('resetcdrlist');
  69     if ( $result ne 'ok' ) {
  70       $dbh->rollback;
  71       die "Failed to reset CDR list: $result\n";
  72     }
  73   }
  74
  75   my $dir = $FS::UID::cache_dir . "/cache.". $FS::UID::datasrc;
  76   my $temp = new File::Temp ( TEMPLATE => 'download.XXXXXXXX',
  77                               SUFFIX   => '.csv',
  78                               DIR      => $dir,
  79                               UNLINK   => !$opt{'k'} )
  80     or die "can't open temporary file to store download: $!\n";
  81   print "Downloading to ".$temp->filename."\n" if $opt{'v'};
  82
  83   print "Sending API request..." if $opt{'v'};
  84   my @records = eval { $export->vitelity_command('getcdr') };
  85   if ( $@ ) {
  86     print "download error: $@\n";
  87     exit(-1);
  88   }
  89   print "received ".scalar(@records)." records\n" if $opt{'v'};
  90   if ( !@records ) {
  91     print "No records to process.\n" if $opt{'v'};
  92     exit(1);
  93   }
  94
  95   print $temp "Date,Source,Destination,Seconds,CallerID,Disposition,Cost\n";
  96
  97   my $regex = qr/^(\d{4})-(\d{2})-(\d{2})/;
  98   my $s = time2str('%m-%d-%Y', $start);
  99   my $e = time2str('%m-%d-%Y', $end);
 100   my $count = 0;
 101   while (my $rec = shift @records) {
 102     my $date = substr($rec, 0, 10);
 103     next if ($start and $s gt $date);
 104     next if ($end and $e le $date);
 105     print $temp $rec, "\n";
 106     $count++;
 107   }
 108   close $temp;
 109   print "Selected $count records in date range." if $opt{'v'} and ($s or $e);
 110
 111   my $format = 'vitelity';
 112   my $batchname = "vitelity-$exportnum-".time2str('%Y/%m/%d-%T',time);
 113
 114   print "Importing batch..." if $opt{'v'};
 115   my $error = FS::cdr::batch_import( {
 116     'file'            => $temp->filename,
 117     'format'          => $format,
 118     'batch_namevalue' => $batchname,
 119   } );
 120
 121   if ( $error ) {
 122     $dbh->rollback;
 123     print "error: $error";
 124     exit(-2);
 125   }
 126 }
 127 $dbh->commit;
 128 print "done.\n";
 129 exit(0);
 130
 131 sub usage {
 132   my $err = @_ ? shift."\n\n" : '';
 133 $err."Usage:
 134 cdr-vitelity.import [ -v ] [ -k ]
 135                     -s date -e date
 136                     username
 137                     [ exportnum ]
 138 ";
 139 }
 140