bin/cdr-opensips.import

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use vars qw( $DEBUG );
   5 use Date::Parse 'str2time';
   6 use Date::Format 'time2str';
   7 use FS::UID qw(adminsuidsetup dbh);
   8 use FS::cdr;
   9 use DBI;
  10 use Getopt::Std;
  11
  12 my %opt;
  13 getopts('H:U:P:D:T:', \%opt);
  14 my $user = shift or die &usage;
  15
  16 my $dsn = 'dbi:mysql';
  17 $dsn .= ":database=$opt{D}" if $opt{D};
  18 $dsn .= ":host=$opt{H}" if $opt{H};
  19
  20 my $mysql = DBI->connect($dsn, $opt{U}, $opt{P})
  21   or die $DBI::errstr;
  22
  23 adminsuidsetup $user;
  24
  25 my $fsdbh = FS::UID::dbh;
  26
  27 # check for existence of freesidestatus
  28 my $table = $opt{T} || 'acc';
  29 my $status = $mysql->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'freesidestatus'");
  30 if( ! @$status ) {
  31   print "Adding freesidestatus column...\n";
  32   $mysql->do("ALTER TABLE $table ADD COLUMN freesidestatus varchar(32)")
  33     or die $mysql->errstr;
  34 }
  35 else {
  36   print "freesidestatus column present\n";
  37 }
  38
  39 my @cols = ( qw(
  40   id caller_id callee_id method from_tag to_tag callid sip_code sip_reason
  41   time )
  42 );
  43
  44 my $sql = 'SELECT '.join(',', @cols). " FROM $table WHERE freesidestatus IS NULL AND sip_code = 200"; # only want successful calls
  45 my $sth = $mysql->prepare($sql);
  46 $sth->execute;
  47 print "Importing ".$sth->rows." records...\n";
  48
  49 my $cdr_batch = new FS::cdr_batch({
  50     'cdrbatch' => 'mysql-import-'. time2str('%Y/%m/%d-%T',time),
  51   });
  52 my $error = $cdr_batch->insert;
  53 die $error if $error;
  54 my $cdrbatchnum = $cdr_batch->cdrbatchnum;
  55 my $imports = 0;
  56 my $updates = 0;
  57
  58 my %cdrs;
  59 my $row;
  60 while ( $row = $sth->fetchrow_hashref ) {
  61   my ($callid) = $row->{'callid'} =~ /(.*)@/;
  62   my ($src) = $row->{'caller_id'} =~ /^sip:(\d+)@/;
  63   my ($dst) = $row->{'callee_id'} =~ /^sip:(\d+)@/;
  64
  65   my $cdr = $cdrs{$callid};
  66   if ( !$cdr ) {
  67     $cdr = $cdrs{$callid} = FS::cdr->new ({
  68       uniqueid    => $callid,
  69       cdrbatchnum => $cdrbatchnum,
  70     });
  71   }
  72   my $date = str2time($row->{'time'});
  73   if ( $row->{'method'} eq 'INVITE' ) {
  74     $cdr->startdate($date);
  75     $cdr->src($src);
  76     $cdr->dst($dst);
  77   }
  78   elsif ( $row->{'method'} eq 'ACK' ) {
  79     $cdr->answerdate($date);
  80   }
  81   elsif ( $row->{'method'} eq 'BYE' ) {
  82     $cdr->enddate($date);
  83   }
  84   if ( $cdr->startdate and $cdr->answerdate and $cdr->enddate ) {
  85     $cdr->duration($cdr->enddate - $cdr->startdate);
  86     $cdr->billsec($cdr->enddate - $cdr->answerdate);
  87     my $error = $cdr->insert;
  88     if($error) {
  89       print "failed import: $error\n";
  90     }
  91     else {
  92       $imports++;
  93       if( $updates += $mysql->do("UPDATE $table SET freesidestatus = 'done'
  94           WHERE sip_code = 200 AND callid = ?",
  95           undef,
  96           $row->{'callid'}
  97         ) ) { #nothing
  98       }
  99       else {
 100         print "failed to set status: ".$mysql->errstr."\n";
 101       }
 102       delete $cdrs{$callid};
 103     }
 104   }
 105 }
 106 print "Done.\nImported $imports CDRs, marked $updates accounting events as done.\n";
 107 if ( keys(%cdrs) ) {
 108   print "Skipped ".scalar(keys(%cdrs))." incomplete calls.\n";
 109 }
 110 $mysql->disconnect;
 111
 112 sub usage {
 113   "Usage: \n  cdr-opensips.import\n\t[ -H host ]\n\t-D database\n\t-U user\n\t-P password\n\tfreesideuser\n";
 114 }
 115