FS/bin/freeside-torrus-srvderive

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use POSIX qw( :sys_wait_h );
   5 use Sys::SigAction qw( set_sig_handler );
   6 use Date::Parse;
   7 use Date::Format;
   8 use IPC::Run qw( run ); #timeout );
   9 use FS::Daemon ':all'; #daemonize1 drop_root daemonize2 myexit logfile sig*
  10 use FS::UID qw( adminsuidsetup forksuidsetup dbh driver_name );
  11 use FS::Record qw( qsearch str2time_sql str2time_sql_closing concat_sql );
  12 use FS::torrus_srvderive;
  13
  14 our $DEBUG = 2;
  15 our $max_kids = 16;
  16 our $search_timeout = 2*60*60; #60*60; #30*60; # 15*60 5*60; #$torrus_srvderive->last_srv_date ? 5*60 : 15*60);
  17 our %kids;
  18
  19 my $user = shift or die &usage;
  20 $FS::Daemon::PID_NEWSTYLE = 1;
  21 daemonize1('torrus-srvderive');
  22
  23 drop_root();
  24
  25 adminsuidsetup($user);
  26
  27 logfile( "%%%FREESIDE_LOG%%%/torrus-srvderive-log.". $FS::UID::datasrc );
  28
  29 daemonize2();
  30
  31 our $conf = new FS::Conf;
  32
  33 die "not running: network_monitoring_system not Torrus_Internal\n"
  34   unless _shouldrun();
  35
  36 #--
  37
  38 my $str2time = str2time_sql();
  39 my $c = str2time_sql_closing();
  40
  41 my $_date = concat_sql([ 'srvexport.srv_date', "' '", 'srvexport.srv_time' ]);
  42 $_date = "CAST( $_date AS TIMESTAMP )" if driver_name =~ /^Pg/i;
  43 $_date = str2time_sql. $_date.  str2time_sql_closing;
  44
  45 my $other_date = concat_sql([ 'other.srv_date', "' '", 'other.srv_time' ]);
  46 $other_date = "CAST( $other_date AS TIMESTAMP )" if driver_name =~ /^Pg/i;
  47 $other_date = str2time_sql. $other_date.  str2time_sql_closing;
  48
  49 my $in  = concat_sql([ '?', "'_IN'" ]);
  50 my $out = concat_sql([ '?', "'_OUT'" ]);
  51
  52 my $sql = "
  53   SELECT DISTINCT srv_date, srv_time FROM srvexport
  54     WHERE NOT EXISTS (
  55                        SELECT 1 FROM srvexport AS other
  56                          WHERE other.serviceid IN ( $in, $out )
  57                            AND srvexport.srv_date = other.srv_date
  58                            AND ABS( $_date - $other_date ) <= 60
  59                      )
  60 ";
  61
  62 my $orderlimit = "
  63     ORDER BY srv_date, srv_time
  64     LIMIT 200
  65 ";
  66
  67 if ( driver_name =~ /mysql/i ) {
  68   dbh->do('SET SESSION TRANSACTION ISOLATION LEVEL READ UNCOMMITTED');
  69   dbh->commit or die dbh->errstr;
  70 }
  71
  72 our $kids = 0;
  73
  74 #MAIN: while (1) {
  75 while (1) {
  76
  77   my $found = 0;
  78
  79   #SERVICEID: foreach my $torrus_srvderive ( qsearch('torrus_srvderive', {}) ) {
  80   foreach my $torrus_srvderive ( qsearch('torrus_srvderive', {}) ) {
  81
  82     &reap_kids;
  83     if ( $kids >= $max_kids ) {
  84       sleep 5;
  85       myexit() if sigterm() || sigint();
  86       redo;
  87     }
  88
  89     defined( my $pid = fork ) or do {
  90       #warn "WARNING: can't fork: $!\n";
  91       #next; #don't increment the kid counter
  92       die "can't fork: $!\n";
  93     };
  94
  95     if ( $pid ) {
  96       $kids++;
  97       $kids{$pid} = 1;
  98     } else { #kid time
  99
 100       #get new db handle
 101       $FS::UID::dbh->{InactiveDestroy} = 1;
 102
 103       forksuidsetup($user);
 104
 105       my $serviceid = $torrus_srvderive->serviceid;
 106
 107       my @serviceids = $torrus_srvderive->component_serviceids;
 108       exit unless @serviceids; #don't try to search for empty virtual ports
 109
 110       #nonlocking select statements; rows in this table never change
 111       if ( driver_name =~ /mysql/i ) {
 112         dbh->do('SET SESSION TRANSACTION ISOLATION LEVEL READ UNCOMMITTED');
 113         dbh->commit or die dbh->errstr;
 114       }
 115
 116       my @in = ();
 117       for my $dir ('_IN', '_OUT') {
 118         push @in, map dbh->quote("$_$dir"), @serviceids;
 119       }
 120       my $in = join(',', @in);
 121
 122       if ( ! $torrus_srvderive->last_srv_date ) {
 123         warn "finding initial last_srv_date for $serviceid\n" if $DEBUG;
 124         my $dsql = "SELECT srv_date FROM srvexport WHERE serviceid IN ($in)
 125                     ORDER BY srv_date LIMIT 1";
 126         my $dsth = dbh->prepare($dsql) or die $DBI::errstr;
 127         $dsth->execute or die $dsth->errstr;
 128         my $date = $dsth->fetchrow_arrayref->[0];
 129         if ( $date ) {
 130           warn "found initial last_srv_date of $date; updating $serviceid\n"
 131             if $DEBUG;
 132           $torrus_srvderive->last_srv_date($date);
 133           my $error = $torrus_srvderive->replace;
 134           die $error if $error;
 135         } else {
 136           warn "no initial last_srv_date for $serviceid; skipping\n" if $DEBUG;
 137           exit;
 138         }
 139       }
 140
 141       #alternate (hopefully more efficient) path: if we're more than a day
 142       #behind, call native torrus srvderive
 143       my $last_srv_date = $torrus_srvderive->last_srv_date;
 144       my $currdate = time2str('%Y-%m-%d', time);
 145       if ( $last_srv_date ne $currdate
 146            && time - str2time($last_srv_date) > (24+6)*60*60 #6 hour window for
 147          ) {                                                 #yesterday
 148         warn "serviceid $serviceid last_srv_date != $currdate\n" if $DEBUG;
 149
 150         #delete records from last_srv_date
 151         my $dsql =
 152           'DELETE FROM srvexport WHERE srv_date = ? AND serviceid IN(?,?)';
 153         my $dsth = dbh->prepare($dsql) or die $DBI::errstr;
 154         warn "$dsql $last_srv_date ${serviceid}_IN ${serviceid}_OUT\n"
 155           if $DEBUG;
 156         $dsth->execute($last_srv_date, $serviceid.'_IN', $serviceid.'_OUT')
 157           or die $dsth->errstr;
 158         dbh->commit or die dbh->errstr;
 159
 160         sleep 20;
 161
 162         foreach my $dir ('_IN','_OUT') {
 163
 164           #XX TORRUS_PATH
 165           my @cmd = ( '/usr/local/bin/torrus', 'srvderive',
 166                         "--start=$last_srv_date", "--end=$currdate",
 167                         "--out=$serviceid$dir", "--func=SUM",
 168                         map "$_$dir", @serviceids
 169                     );
 170
 171           warn "calling native srvderive: ". join(' ', @cmd). "\n" if $DEBUG;
 172           my $out_and_err = '';
 173           run( \@cmd, '>&', \$out_and_err ) #verbose?  timeout?
 174             or die "error calling native srvder: $out_and_err\n";
 175
 176         }
 177         warn "native srvderive done" if $DEBUG;
 178
 179         sleep 20;
 180
 181         $torrus_srvderive->last_srv_date($currdate);
 182         my $error = $torrus_srvderive->replace;
 183         die $error if $error;
 184
 185         #don't bother trying today's immediately
 186         warn "done with $serviceid for now\n" if $DEBUG;
 187         exit; #end-of-kid
 188
 189       }
 190
 191       my $ssql = "
 192         $sql AND EXISTS (
 193                          SELECT 1 FROM srvexport AS other
 194                            WHERE other.serviceid IN ($in)
 195                              AND srvexport.srv_date = other.srv_date
 196                              AND ABS( $_date - $other_date ) <= 60
 197                        )
 198       ";
 199
 200       $ssql .= " AND srv_date >= '". $torrus_srvderive->last_srv_date. "' "
 201         if $torrus_srvderive->last_srv_date;
 202
 203       $ssql .= $orderlimit;
 204
 205       warn "searching for times to add $serviceid\n" if $DEBUG;
 206       warn $ssql if $DEBUG > 2;
 207       my $sth = dbh->prepare($ssql) or die $DBI::errstr; #better recovery here?
 208
 209       eval {
 210         my $h = set_sig_handler( 'ALRM', sub { die "_timeout\n"; } );
 211         alarm($search_timeout);
 212         $sth->execute($serviceid, $serviceid) or die $sth->errstr;
 213         alarm(0);
 214       };
 215       alarm(0);
 216
 217       if ( $@ && $@ eq "_timeout\n" ) {
 218         #warn "search timed out; reconnecting and restarting\n";
 219         warn "search timed out\n";
 220         dbh->clone()->do("KILL QUERY ". dbh->{"mysql_thread_id"})
 221           if driver_name =~ /mysql/i;
 222         dbh->rollback; #or die dbh->errstr;
 223         #adminsuidsetup($user);
 224         #next SERVICEID; #MAIN;
 225         exit;
 226       } elsif ( $@ ) {
 227         die $@;
 228       }
 229
 230       warn "search for $serviceid finished; checking results\n" if $DEBUG;
 231
 232       my $prev = 0;
 233       while ( my $row = $sth->fetchrow_arrayref ) {
 234         last if sigterm() || sigint();
 235
 236         my( $srv_date, $srv_time ) = @$row;
 237         my $cur = str2time( "$srv_date $srv_time" );
 238         next if $cur-$prev <= 60;
 239         last if time - $cur <= 300;
 240
 241         warn "no $serviceid for $srv_date $srv_time; adding\n"
 242           if $DEBUG;
 243         $found++;
 244
 245         for my $dir ('_IN', '_OUT') {
 246
 247           my $sin = join(',', map dbh->quote("$_$dir"), @serviceids);
 248
 249           my $srv_date = time2str('%Y-%m-%d', $cur);
 250
 251           my $sum = "
 252             SELECT COALESCE(SUM(value),0) FROM srvexport AS other
 253               WHERE other.serviceid IN ($sin)
 254                 AND other.srv_date = '$srv_date'
 255                 AND ABS( $cur - $other_date ) <= 60
 256           ";
 257           my $ssth = dbh->prepare($sum) or die $DBI::errstr;
 258           $ssth->execute or die $ssth->errstr; #better recovery?
 259           my $value = $ssth->fetchrow_arrayref->[0];
 260
 261           my $isql = "
 262             INSERT INTO srvexport (srv_date, srv_time, serviceid, value, intvl)
 263               VALUES ( ?, ?, ?, ?, ? )
 264           ";
 265           my @param = ( $srv_date,
 266                         time2str('%X', $cur), #srv_time
 267                         "$serviceid$dir",     #serviceid
 268                         $value,
 269                         300,                  #intvl ...
 270                       );
 271           warn $isql. ' with param '. join(',',@param). "\n"
 272             if $DEBUG > 2;
 273
 274           my $isth = dbh->prepare($isql) or die $DBI::errstr; #better recovery?
 275
 276           #stupid mysql deadlocks all the time on insert, so we need to recover
 277           unless ( $isth->execute(@param) ) {
 278             #warn "Error inserting data for $serviceid$dir (restarting): ".
 279             #     $isth->errstr;
 280             warn "Error inserting data for $serviceid$dir: ". $isth->errstr;
 281             dbh->rollback; #or die dbh->errstr;
 282             #sleep 5;
 283             #next SERVICEID; #MAIN;
 284             exit;
 285           }
 286
 287         }
 288
 289         if ( $srv_date ne $torrus_srvderive->last_srv_date ) {
 290           warn "updating last_srv_date of $serviceid to $srv_date\n" if $DEBUG;
 291           $torrus_srvderive->last_srv_date($srv_date);
 292           my $error = $torrus_srvderive->replace;
 293           die $error if $error;
 294         }
 295         dbh->commit or die dbh->errstr;
 296
 297         $prev = $cur;
 298       }
 299       warn "done with $serviceid\n" if $DEBUG;
 300
 301       exit;
 302       #end-of-kid
 303     }
 304
 305   } #foreach my $torrus_srvderive
 306   dbh->commit or die dbh->errstr;
 307
 308   myexit() if sigterm() || sigint();
 309   warn "restarting main loop\n" if $DEBUG > 1;
 310   #sleep 60 unless $found;
 311 }
 312
 313 sub _shouldrun {
 314      $conf->exists('network_monitoring_system')
 315   && $conf->config('network_monitoring_system') eq 'Torrus_Internal';
 316 }
 317
 318 sub usage {
 319   die "Usage:\n\n  freeside-cdrrewrited user\n";
 320 }
 321
 322 sub reap_kids {
 323   foreach my $pid ( keys %kids ) {
 324     my $kid = waitpid($pid, WNOHANG);
 325     if ( $kid > 0 ) {
 326       $kids--;
 327       delete $kids{$kid};
 328     }
 329   }
 330 }
 331
 332 =head1 NAME
 333
 334 freeside-torrus-srvderive - Freeside's Torrus virtual port daemon.
 335
 336 =head1 SYNOPSIS
 337
 338   freeside-torrus-srvderive
 339
 340 =head1 DESCRIPTION
 341
 342 Runs continuously, searches for samples in the srvexport table which do not
 343 have an entry for combined virtual ports, and adds them.
 344
 345 =head1 SEE ALSO
 346
 347 =cut
 348
 349 1;
 350