FS/bin/freeside-torrus-srvderive

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Sys::SigAction qw( set_sig_handler );
   5 use Date::Parse;
   6 use Date::Format;
   7 use FS::Daemon ':all'; #daemonize1 drop_root daemonize2 myexit logfile sig*
   8 use FS::UID qw( adminsuidsetup dbh driver_name );
   9 use FS::Record qw( qsearch str2time_sql str2time_sql_closing concat_sql );
  10 use FS::torrus_srvderive;
  11
  12 our $DEBUG = 2;
  13
  14 my $user = shift or die &usage;
  15 $FS::Daemon::PID_NEWSTYLE = 1;
  16 daemonize1('torrus-srvderive');
  17
  18 drop_root();
  19
  20 adminsuidsetup($user);
  21
  22 logfile( "%%%FREESIDE_LOG%%%/torrus-srvderive-log.". $FS::UID::datasrc );
  23
  24 daemonize2();
  25
  26 our $conf = new FS::Conf;
  27
  28 die "not running: network_monitoring_system not Torrus_Internal\n"
  29   unless _shouldrun();
  30
  31 #--
  32
  33 my $str2time = str2time_sql();
  34 my $c = str2time_sql_closing();
  35
  36 my $_date = concat_sql([ 'srvexport.srv_date', "' '", 'srvexport.srv_time' ]);
  37 $_date = "CAST( $_date AS TIMESTAMP )" if driver_name =~ /^Pg/i;
  38 $_date = str2time_sql. $_date.  str2time_sql_closing;
  39
  40 my $other_date = concat_sql([ 'other.srv_date', "' '", 'other.srv_time' ]);
  41 $other_date = "CAST( $other_date AS TIMESTAMP )" if driver_name =~ /^Pg/i;
  42 $other_date = str2time_sql. $other_date.  str2time_sql_closing;
  43
  44 my $in  = concat_sql([ '?', "'_IN'" ]);
  45 my $out = concat_sql([ '?', "'_OUT'" ]);
  46
  47 my $sql = "
  48   SELECT DISTINCT srv_date, srv_time FROM srvexport
  49     WHERE NOT EXISTS (
  50                        SELECT 1 FROM srvexport AS other
  51                          WHERE other.serviceid IN ( $in, $out )
  52                            AND srvexport.srv_date = other.srv_date
  53                            AND ABS( $_date - $other_date ) <= 60
  54                      )
  55 ";
  56
  57 my $orderlimit = "
  58     ORDER BY srv_date, srv_time
  59     LIMIT 50
  60 ";
  61
  62
  63 MAIN: while (1) {
  64
  65   my $found = 0;
  66
  67   foreach my $torrus_srvderive ( qsearch('torrus_srvderive', {}) ) {
  68
  69     my $serviceid = $torrus_srvderive->serviceid;
  70
  71     my @serviceids = $torrus_srvderive->component_serviceids;
  72
  73     my @in = ();
  74     for my $dir ('_IN', '_OUT') {
  75       push @in, map dbh->quote("$_$dir"), @serviceids;
  76     }
  77     my $in = join(',', @in);
  78
  79     my $ssql = "
  80       $sql AND EXISTS (
  81                        SELECT 1 FROM srvexport AS other
  82                          WHERE other.serviceid IN ($in)
  83                            AND srvexport.srv_date = other.srv_date
  84                            AND ABS( $_date - $other_date ) <= 60
  85                      )
  86     ";
  87
  88     $ssql .= " AND srv_date >= '". $torrus_srvderive->last_srv_date. "' "
  89       if $torrus_srvderive->last_srv_date;
  90
  91     $ssql .= $orderlimit;
  92
  93     warn "searching for times to add $serviceid\n" if $DEBUG;
  94     warn $ssql if $DEBUG > 2;
  95     my $sth = dbh->prepare($ssql) or die $DBI::errstr; #better recovery here?
  96
  97     warn "executing search\n" if $DEBUG;
  98
  99     eval {
 100       my $h = set_sig_handler(
 101         'ALRM', sub {
 102           local $SIG{__DIE__};
 103           warn "search timed out\n";
 104           dbh->clone()->do("KILL QUERY ". dbh->{"mysql_thread_id"})
 105             if driver_name eq 'mysql';
 106           die '_timeout';
 107         },
 108         { mask=>['ALRM'] , safe=>1 }
 109       );
 110       alarm(5*60); # 15*60);
 111       $sth->execute($serviceid, $serviceid) or die $sth->errstr;
 112       alarm(0);
 113     };
 114     alarm(0);
 115     if ( $@ =~ /^_timeout/ ) {
 116       warn "search timed out; reconnecting and restarting\n";
 117       adminsuidsetup($user);
 118       next MAIN;
 119     } elsif ( $@ ) {
 120       die $@;
 121     }
 122
 123     warn "search executed; checking results\n" if $DEBUG;
 124
 125     my $prev = 0;
 126     while ( my $row = $sth->fetchrow_arrayref ) {
 127       last if sigterm() || sigint();
 128
 129       my( $srv_date, $srv_time ) = @$row;
 130       my $cur = str2time( "$srv_date $srv_time" );
 131       next if $cur-$prev <= 60;
 132       last if time - $cur <= 300;
 133
 134       warn "no $serviceid for $srv_date $srv_time; adding\n"
 135         if $DEBUG;
 136       $found++;
 137
 138       for my $dir ('_IN', '_OUT') {
 139
 140         my $sin = join(',', map dbh->quote("$_$dir"), @serviceids);
 141
 142         my $sum = "
 143           SELECT COALESCE(SUM(value),0) FROM srvexport AS other
 144             WHERE other.serviceid IN ($sin)
 145               AND ABS( $cur - $other_date ) <= 60
 146         ";
 147
 148         my $isql = "
 149           INSERT INTO srvexport ( srv_date, srv_time, serviceid, value, intvl )
 150             VALUES ( ?, ?, ?, ($sum), ? )
 151         ";
 152         my @param = ( time2str('%Y-%m-%d', $cur), #srv_date
 153                       time2str('%X', $cur),       #srv_time
 154                       "$serviceid$dir",
 155                       300, #intvl ...
 156                     );
 157         warn $isql. ' with param '. join(',',@param). "\n"
 158           if $DEBUG > 2;
 159
 160         my $isth = dbh->prepare($isql) or die $DBI::errstr; #better recovery?
 161
 162         #stupid mysql deadlocks all the time on insert, so we need to recover
 163         unless ( $isth->execute(@param) ) {
 164           warn "Error inserting data for $serviceid$dir (restarting): ".
 165                $isth->errstr;
 166           dbh->rollback; #or die dbh->errstr;
 167           sleep 5;
 168           next MAIN;
 169         }
 170
 171       }
 172
 173       if ( $srv_date ne $torrus_srvderive->last_srv_date ) {
 174         warn "updating last_srv_date of $serviceid to $srv_date\n" if $DEBUG;
 175         $torrus_srvderive->last_srv_date($srv_date);
 176         my $error = $torrus_srvderive->replace;
 177         die $error if $error;
 178       }
 179       dbh->commit or die dbh->errstr;
 180
 181       $prev = $cur;
 182     }
 183     warn "done with $serviceid\n" if $DEBUG;
 184
 185   } #foreach my $torrus_srvderive
 186   dbh->commit or die dbh->errstr;
 187
 188   myexit() if sigterm() || sigint();
 189   warn "restarting main loop\n" if $DEBUG > 1;
 190   sleep 60 unless $found;
 191 }
 192
 193 sub _shouldrun {
 194      $conf->exists('network_monitoring_system')
 195   && $conf->config('network_monitoring_system') eq 'Torrus_Internal';
 196 }
 197
 198 sub usage {
 199   die "Usage:\n\n  freeside-cdrrewrited user\n";
 200 }
 201
 202
 203 =head1 NAME
 204
 205 freeside-torrus-srvderive - Freeside's Torrus virtual port daemon.
 206
 207 =head1 SYNOPSIS
 208
 209   freeside-torrus-srvderive
 210
 211 =head1 DESCRIPTION
 212
 213 Runs continuously, searches for samples in the srvexport table which do not
 214 have an entry for combined virtual ports, and adds them.
 215
 216 =head1 SEE ALSO
 217
 218 =cut
 219
 220 1;
 221