FS/bin/freeside-sqlradius-radacctd

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( @part_export );
   5 use subs qw(myshutdown);
   6 use POSIX qw(:sys_wait_h);
   7 #use IO::File;
   8 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
   9 use FS::UID qw(adminsuidsetup); #forksuidsetup driver_name dbh myconnect);
  10 use FS::Record qw(qsearch); # qsearchs);
  11 use FS::part_export;
  12 #use FS::svc_acct;
  13 #use FS::cust_svc;
  14
  15 my $user = shift or die &usage;
  16
  17 #daemonize1('freeside-sqlradius-radacctd', $user); #keep unique pid files w/multi installs
  18 daemonize1('freeside-sqlradius-radacctd');
  19
  20 drop_root();
  21
  22 #$ENV{HOME} = (getpwuid($>))[7]; #for ssh
  23
  24 adminsuidsetup $user;
  25
  26 logfile( "/usr/local/etc/freeside/sqlradius-radacctd-log.". $FS::UID::datasrc );
  27
  28 daemonize2();
  29
  30 #--
  31
  32 #don't just look for ->can('usage_sessions'), we're sqlradius-specific
  33 # (radiator is supposed to be setup with a radacct table)
  34
  35 @part_export =
  36   qsearch('part_export', { 'exporttype' => 'sqlradius' } );
  37 push @part_export,
  38   qsearch('part_export', { 'exporttype' => 'sqlradius_withdomain' } );
  39 push @part_export,
  40   qsearch('part_export', { 'exporttype' => 'radiator' } );
  41
  42 @part_export = grep { ! $_->option('ignore_accounting') } @part_export;
  43
  44 die "no sqlradius or sqlradius_withdomain exports without ignore_accounting"
  45   unless @part_export;
  46
  47 while (1) {
  48
  49   #fork off one kid per export (machine)
  50   # _>{'_radacct_kid'} is an evil kludge
  51   foreach my $part_export ( grep ! $_->{'_radacct_kid'}, @part_export ) {
  52
  53     defined( my $pid = fork ) or do {
  54       warn "WARNING: can't fork to spawn child for ". $part_export->machine;
  55       next;
  56     };
  57
  58     if ( $pid ) {
  59       $part_export->{'_radacct_kid'} = $pid;
  60       warn "child $pid spawned for ". $part_export->machine;
  61     } else { #kid time
  62
  63       adminsuidsetup($user); #get our own db handle
  64
  65       until ( sigint || sigterm ) {
  66         $part_export->update_svc_acct();
  67         sleep 1;
  68       }
  69
  70       warn "child for ". $part_export->machine. " done";
  71       exit;
  72
  73     } #eo kid
  74
  75   }
  76
  77   #reap up any kids that died...
  78   &reap_kids;
  79
  80   myshutdown() if sigterm() || sigint();
  81
  82   sleep 5;
  83 }
  84
  85 #--
  86
  87 sub myshutdown {
  88   &reap_kids;
  89
  90   #kill all the kids
  91   kill 'TERM', $_ foreach grep $_, map $_->{'_radacct_kid'}, @part_export;
  92
  93   my $wait = 12; #wait up to 1 minute
  94   while ( ( grep $_->{'_radacct_kid'}, @part_export ) && $wait-- ) {
  95     warn "waiting for children to terminate";
  96     sleep 5;
  97     &reap_kids;
  98   }
  99   warn "abandoning children" if grep $_->{'_radacct_kid'}, @part_export;
 100   die "exiting";
 101 }
 102
 103 sub reap_kids {
 104   #warn "reaping kids\n";
 105   foreach my $part_export ( grep $_->{'_radacct_kid'}, @part_export ) {
 106     my $pid = $part_export->{'_radacct_kid'};
 107     my $kid = waitpid($pid, WNOHANG);
 108     if ( $kid > 0 ) {
 109       $part_export->{'_radacct_kid'} = '';
 110     }
 111   }
 112   #warn "done reaping\n";
 113 }
 114
 115 sub usage {
 116   die "Usage:\n\n  freeside-sqlradius-radacctd user\n";
 117 }
 118
 119 =head1 NAME
 120
 121 freeside-sqlradius-radacctd - Real-time radacct import daemon
 122
 123 =head1 SYNOPSIS
 124
 125   freeside-sqlradius-radacctd username
 126
 127 =head1 DESCRIPTION
 128
 129 Imports records from an the SQL radacct tables of all sqlradius and
 130 sqlradius_withdomain exports (except those with the ignore_accounting flag) and
 131 updates the svc_acct.seconds for each account.  Runs as a daemon and updates
 132 the database in real-time.
 133
 134 B<username> is a username added by freeside-adduser.
 135
 136 =head1 RADIUS DATABASE CHANGES
 137
 138 ALTER TABLE radacct ADD COLUMN FreesideStatus varchar(32) NULL;
 139
 140 If you want to ignore the existing accountg records, also do:
 141
 142 UPDATE TABLE radacct SET FreesideStatus = 'done' WHERE FreesideStatus IS NULL;
 143
 144 =head1 SEE ALSO
 145
 146 =cut
 147
 148 1;
 149