FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $FREESIDE_LOG $FREESIDE_LOCK );
   5 use vars qw( $Debug %kids $kids $max_kids $ssh_pid %old_ssh_pid $keepalives );
   6 use subs qw( lock_write unlock_write myshutdown usage );
   7 use Fcntl qw(:flock);
   8 use POSIX qw(:sys_wait_h);
   9 use IO::Handle;
  10 use IO::Select;
  11 use IO::File;
  12 use Storable 2.09 qw(nstore_fd fd_retrieve);
  13 use Net::SSH qw(sshopen2);
  14 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
  15 use FS::UID qw(adminsuidsetup forksuidsetup);
  16 use FS::ClientAPI;
  17
  18 use FS::Conf;
  19 use FS::cust_bill;
  20 use FS::cust_pkg;
  21
  22 $FREESIDE_LOG = "%%%FREESIDE_LOG%%%";
  23 $FREESIDE_LOCK = "%%%FREESIDE_LOCK%%%";
  24
  25 $Debug = 1; # 2 will turn on more logging
  26             # 3 will log packet contents, including passwords
  27
  28 $max_kids = '10'; #?
  29 $keepalives = 0; #let clientd turn it on, so we don't barf on old ones
  30 $kids = 0;
  31
  32 my $user = shift or die &usage;
  33 my $machine = shift or die &usage;
  34 my $tag = scalar(@ARGV) ? shift : '';
  35
  36 my $lock_file = "$FREESIDE_LOCK/selfservice.$machine.writelock";
  37
  38 # to keep pid files unique w/multi machines (and installs!)
  39 # $FS::UID::datasrc not posible
  40 daemonize1("freeside-selfservice-server","$user.$machine");
  41
  42 #false laziness w/Daemon::drop_root
  43 my $freeside_gid = scalar(getgrnam('freeside'))
  44   or die "can't find freeside group\n";
  45
  46 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  47 chown $FS::UID::freeside_uid, $freeside_gid, $lock_file;
  48
  49 drop_root();
  50
  51 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  52
  53 adminsuidsetup $user;
  54
  55 #logfile("/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc); #MACHINE
  56 logfile("$FREESIDE_LOG/selfservice.$machine.log");
  57
  58 daemonize2();
  59
  60 my $conf = new FS::Conf;
  61
  62 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  63
  64 my $warnkids=0;
  65 while (1) {
  66   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  67   warn "connecting to $machine\n" if $Debug;
  68
  69   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  70
  71 #  nstore_fd(\*writer, {'hi'=>'there'});
  72
  73   warn "entering main loop\n" if $Debug;
  74   my $undisp = 0;
  75   my $keepalive_count = 0;
  76   my $s = IO::Select->new( $reader );
  77   while (1) {
  78
  79     &reap_kids;
  80
  81     warn "waiting for packet from client\n" if $Debug && !$undisp;
  82     $undisp = 1;
  83     my @handles = $s->can_read(5);
  84     unless ( @handles ) {
  85       myshutdown() if sigint() || sigterm();
  86       if ( $keepalives && $keepalive_count++ > 10 ) {
  87         $keepalive_count = 0;
  88         lock_write;
  89         nstore_fd( { _token => '_keepalive' }, $writer );
  90         unlock_write;
  91       }
  92       next;
  93     }
  94
  95     $undisp = 0;
  96
  97     warn "receiving packet from client\n" if $Debug;
  98
  99     my $packet = eval { fd_retrieve($reader); };
 100     if ( $@ ) {
 101       warn "Storable error receiving packet from client".
 102            " (assuming lost connection): $@\n"
 103         if $Debug;
 104       if ( $ssh_pid ) {
 105         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
 106         kill 'TERM', $ssh_pid;
 107         $old_ssh_pid{$ssh_pid} = 1;
 108         $ssh_pid = 0;
 109       }
 110       last;
 111     }
 112     warn "packet received\n".
 113          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
 114       if $Debug > 2;
 115
 116     if ( $packet->{_packet} eq '_enable_keepalive' ) {
 117       warn "enabling keep alives\n" if $Debug;
 118       $keepalives=1;
 119       next;
 120     }
 121
 122     #prevent runaway forking
 123     my $warnkids = 0;
 124     while ( $kids >= $max_kids ) {
 125       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
 126       &reap_kids;
 127       sleep 1;
 128     }
 129
 130     warn "forking child\n" if $Debug;
 131     defined( my $pid = fork ) or die "can't fork: $!";
 132     if ( $pid ) {
 133       $kids++;
 134       $kids{$pid} = 1;
 135       warn "child $pid spawned\n" if $Debug;
 136     } else { #kid time
 137
 138       ##get new db handle
 139       $FS::UID::dbh->{InactiveDestroy} = 1;
 140       forksuidsetup($user);
 141
 142       #get db handle
 143       #adminsuidsetup($user);
 144
 145       my $type = $packet->{_packet};
 146       warn "calling $type handler\n" if $Debug;
 147       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 148       if ( $@ ) {
 149         warn my $error = "WARNING: error dispatching $type: $@";
 150         $rv = { _error => $error };
 151       }
 152       $rv->{_token} = $packet->{_token}; #identifier
 153
 154       open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
 155       lock_write;
 156       warn "sending response\n" if $Debug;
 157       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 158       $writer->flush or die "FATAL: can't flush: $!";
 159       unlock_write;
 160
 161       warn "child exiting\n" if $Debug;
 162       exit; #end-of-kid
 163     }
 164
 165   }
 166
 167   myshutdown if sigint() || sigterm();
 168   warn "connection lost, reconnecting\n" if $Debug;
 169   sleep 3;
 170
 171 }
 172
 173 ###
 174 # utility subroutines
 175 ###
 176
 177 sub reap_kids {
 178   #warn "reaping kids\n";
 179   foreach my $pid ( keys %kids ) {
 180     my $kid = waitpid($pid, WNOHANG);
 181     if ( $kid > 0 ) {
 182       $kids--;
 183       delete $kids{$kid};
 184     }
 185   }
 186
 187   foreach my $pid ( keys %old_ssh_pid ) {
 188     waitpid($pid, WNOHANG) and delete $old_ssh_pid{$pid};
 189   }
 190   #warn "done reaping\n";
 191 }
 192
 193 sub myshutdown {
 194   &reap_kids;
 195   my $wait = 12; #wait up to 1 minute
 196   while ( $kids > 0 && $wait-- ) {
 197     warn "waiting for $kids children to terminate";
 198     sleep 5;
 199     &reap_kids;
 200   }
 201   warn "abandoning $kids children" if $kids;
 202   kill 'TERM', $ssh_pid if $ssh_pid;
 203   die "exiting";
 204 }
 205
 206 sub lock_write {
 207   warn "locking $lock_file mutex for write to write stream\n" if $Debug > 1;
 208
 209   #broken on freebsd?
 210   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 211
 212   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 213
 214 }
 215
 216 sub unlock_write {
 217   warn "unlocking $lock_file mutex\n" if $Debug > 1;
 218
 219   #broken on freebsd?
 220   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 221
 222   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 223
 224 }
 225
 226 sub usage {
 227   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 228 }
 229