FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $Debug %kids $kids $max_kids $ssh_pid $keepalives );
   5 use subs qw( lock_write unlock_write myshutdown usage );
   6 use Fcntl qw(:flock);
   7 use POSIX qw(:sys_wait_h);
   8 use IO::Handle;
   9 use IO::Select;
  10 use IO::File;
  11 use Storable 2.09 qw(nstore_fd fd_retrieve);
  12 use Net::SSH qw(sshopen2);
  13 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
  14 use FS::UID qw(adminsuidsetup forksuidsetup);
  15 use FS::ClientAPI;
  16
  17 use FS::Conf;
  18 use FS::cust_bill;
  19 use FS::cust_pkg;
  20
  21 $Debug = 1; # 2 will turn on more logging
  22             # 3 will log packet contents, including passwords
  23
  24 $max_kids = '10'; #?
  25 $keepalives = 0; #let clientd turn it on, so we don't barf on old ones
  26 $kids = 0;
  27
  28 my $user = shift or die &usage;
  29 my $machine = shift or die &usage;
  30 my $tag = scalar(@ARGV) ? shift : '';
  31
  32 my $lock_file = "/usr/local/etc/freeside/selfservice.$machine.writelock";
  33
  34
  35 # to keep pid files unique w/multi machines (and installs!)
  36 # $FS::UID::datasrc not posible
  37 daemonize1("freeside-selfservice-server","$user.$machine");
  38
  39 #false laziness w/Daemon::drop_root
  40 my $freeside_gid = scalar(getgrnam('freeside'))
  41   or die "can't find freeside group\n";
  42
  43 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  44 chown $FS::UID::freeside_uid, $freeside_gid, $lock_file;
  45
  46 drop_root();
  47
  48 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  49
  50 adminsuidsetup $user;
  51
  52 #logfile("/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc); #MACHINE
  53 logfile("/usr/local/etc/freeside/selfservice.$machine.log");
  54
  55 daemonize2();
  56
  57
  58 my $conf = new FS::Conf;
  59
  60 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  61
  62 my $warnkids=0;
  63 while (1) {
  64   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  65   warn "connecting to $machine\n" if $Debug;
  66
  67   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  68
  69 #  nstore_fd(\*writer, {'hi'=>'there'});
  70
  71   warn "entering main loop\n" if $Debug;
  72   my $undisp = 0;
  73   my $keepalive_count = 0;
  74   my $s = IO::Select->new( $reader );
  75   while (1) {
  76
  77     &reap_kids;
  78
  79     warn "waiting for packet from client\n" if $Debug && !$undisp;
  80     $undisp = 1;
  81     my @handles = $s->can_read(5);
  82     unless ( @handles ) {
  83       myshutdown() if sigint() || sigterm();
  84       if ( $keepalives && $keepalive_count++ > 10 ) {
  85         $keepalive_count = 0;
  86         lock_write;
  87         nstore_fd( { _token => '_keepalive' }, $writer );
  88         unlock_write;
  89       }
  90       next;
  91     }
  92
  93     $undisp = 0;
  94
  95     warn "receiving packet from client\n" if $Debug;
  96
  97     my $packet = eval { fd_retrieve($reader); };
  98     if ( $@ ) {
  99       warn "Storable error receiving packet from client".
 100            " (assuming lost connection): $@\n"
 101         if $Debug;
 102       if ( $ssh_pid ) {
 103         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
 104         kill 'TERM', $ssh_pid;
 105         $ssh_pid = 0;
 106       }
 107       last;
 108     }
 109     warn "packet received\n".
 110          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
 111       if $Debug > 2;
 112
 113     if ( $packet->{_packet} eq '_enable_keepalive' ) {
 114       warn "enabling keep alives\n" if $Debug;
 115       $keepalives=1;
 116       next;
 117     }
 118
 119     #prevent runaway forking
 120     my $warnkids = 0;
 121     while ( $kids >= $max_kids ) {
 122       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
 123       &reap_kids;
 124       sleep 1;
 125     }
 126
 127     warn "forking child\n" if $Debug;
 128     defined( my $pid = fork ) or die "can't fork: $!";
 129     if ( $pid ) {
 130       $kids++;
 131       $kids{$pid} = 1;
 132       warn "child $pid spawned\n" if $Debug;
 133     } else { #kid time
 134
 135       ##get new db handle
 136       #$FS::UID::dbh->{InactiveDestroy} = 1;
 137       #forksuidsetup($user);
 138
 139       #get db handle
 140       adminsuidsetup($user);
 141
 142       my $type = $packet->{_packet};
 143       warn "calling $type handler\n" if $Debug;
 144       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 145       if ( $@ ) {
 146         warn my $error = "WARNING: error dispatching $type: $@";
 147         $rv = { _error => $error };
 148       }
 149       $rv->{_token} = $packet->{_token}; #identifier
 150
 151       open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
 152       lock_write;
 153       warn "sending response\n" if $Debug;
 154       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 155       $writer->flush or die "FATAL: can't flush: $!";
 156       unlock_write;
 157
 158       warn "child exiting\n" if $Debug;
 159       exit; #end-of-kid
 160     }
 161
 162   }
 163
 164   myshutdown if sigint() || sigterm();
 165   warn "connection lost, reconnecting\n" if $Debug;
 166   sleep 3;
 167
 168 }
 169
 170 ###
 171 # utility subroutines
 172 ###
 173
 174 sub reap_kids {
 175   #warn "reaping kids\n";
 176   foreach my $pid ( keys %kids ) {
 177     my $kid = waitpid($pid, WNOHANG);
 178     if ( $kid > 0 ) {
 179       $kids--;
 180       delete $kids{$kid};
 181     }
 182   }
 183   #warn "done reaping\n";
 184 }
 185
 186 sub myshutdown {
 187   &reap_kids;
 188   my $wait = 12; #wait up to 1 minute
 189   while ( $kids > 0 && $wait-- ) {
 190     warn "waiting for $kids children to terminate";
 191     sleep 5;
 192     &reap_kids;
 193   }
 194   warn "abandoning $kids children" if $kids;
 195   kill 'TERM', $ssh_pid if $ssh_pid;
 196   die "exiting";
 197 }
 198
 199 sub lock_write {
 200   warn "locking $lock_file mutex for write to write stream\n" if $Debug > 1;
 201
 202   #broken on freebsd?
 203   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 204
 205   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 206
 207 }
 208
 209 sub unlock_write {
 210   warn "unlocking $lock_file mutex\n" if $Debug > 1;
 211
 212   #broken on freebsd?
 213   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 214
 215   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 216
 217 }
 218
 219 sub usage {
 220   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 221 }
 222