FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $FREESIDE_LOG $FREESIDE_LOCK );
   5 use vars qw( $Debug %kids $kids $max_kids $ssh_pid %old_ssh_pid $keepalives );
   6 use subs qw( lock_write unlock_write myshutdown usage );
   7 use Fcntl qw(:flock);
   8 use POSIX qw(:sys_wait_h);
   9 use IO::Handle;
  10 use IO::Select;
  11 use IO::File;
  12 use Storable 2.09 qw(nstore_fd fd_retrieve);
  13 use Net::SSH qw(sshopen2);
  14 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
  15 use FS::UID qw(adminsuidsetup forksuidsetup);
  16 use FS::ClientAPI;
  17 use FS::ClientAPI_SessionCache;
  18 use FS::Record qw( qsearch qsearchs );
  19
  20 use FS::Conf;
  21 use FS::cust_svc;
  22 use FS::agent;
  23
  24 $FREESIDE_LOG = "%%%FREESIDE_LOG%%%";
  25 $FREESIDE_LOCK = "%%%FREESIDE_LOCK%%%";
  26
  27 $Debug = 1; # 2 will turn on more logging
  28             # 3 will log packet contents, including passwords
  29
  30 $max_kids = '10'; #?
  31 $keepalives = 0; #let clientd turn it on, so we don't barf on old ones
  32 $kids = 0;
  33
  34 my $user = shift or die &usage;
  35 my $machine = shift or die &usage;
  36 my $tag = scalar(@ARGV) ? shift : '';
  37
  38 my $lock_file = "$FREESIDE_LOCK/selfservice.$machine.writelock";
  39
  40 # to keep pid files unique w/multi machines (and installs!)
  41 # $FS::UID::datasrc not posible
  42 daemonize1("freeside-selfservice-server","$user.$machine");
  43
  44 #false laziness w/Daemon::drop_root
  45 my $freeside_gid = scalar(getgrnam('freeside'))
  46   or die "can't find freeside group\n";
  47
  48 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  49 chown $FS::UID::freeside_uid, $freeside_gid, $lock_file;
  50
  51 drop_root();
  52
  53 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  54
  55 adminsuidsetup $user;
  56
  57 #logfile("/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc); #MACHINE
  58 logfile("$FREESIDE_LOG/selfservice.$machine.log");
  59
  60 daemonize2();
  61
  62 my $conf = new FS::Conf;
  63 if ( $conf->exists('selfservice-ignore_quantity') ) {
  64   $FS::cust_svc::ignore_quantity = 1;
  65   $FS::cust_svc::ignore_quantity = 1; #now it is used twice.
  66 }
  67
  68 #clear the signup info cache so an "/etc/init.d/freeside restart" will pick
  69 #up new info... (better as a callback in Signup.pm?)
  70 my $cache = new FS::ClientAPI_SessionCache( {
  71   'namespace' => 'FS::ClientAPI::Signup',
  72 } );
  73 $cache->remove('signup_info_cache');
  74
  75 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  76
  77 my $warnkids=0;
  78 while (1) {
  79   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  80   warn "connecting to $machine\n" if $Debug;
  81
  82   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  83
  84 #  nstore_fd(\*writer, {'hi'=>'there'});
  85
  86   warn "entering main loop\n" if $Debug;
  87   my $undisp = 0;
  88   my $keepalive_count = 0;
  89   my $s = IO::Select->new( $reader );
  90   while (1) {
  91
  92     &reap_kids;
  93
  94     warn "waiting for packet from client\n" if $Debug && !$undisp;
  95     $undisp = 1;
  96     my @handles = $s->can_read(5);
  97     unless ( @handles ) {
  98       myshutdown() if sigint() || sigterm();
  99       if ( $keepalives && $keepalive_count++ > 10 ) {
 100         $keepalive_count = 0;
 101         lock_write;
 102
 103         nstore_fd( { _token => '_keepalive' }, $writer );
 104         foreach my $agent ( qsearch( 'agent', { disabled => '' } ) ) {
 105           my $config = qsearchs( 'conf', { name  => 'selfservice-bulk_ftp_dir',
 106                                            agentnum => $agent->agentnum,
 107                                } )
 108             or next;
 109
 110           my $session =
 111             FS::ClientAPI->dispatch( 'Agent/agent_login',
 112                                      { username => $agent->username,
 113                                        password => $agent->_password,
 114                                      }
 115             );
 116
 117           nstore_fd( { _token     => '_ftp_scan',
 118                        dir        => $config->value,
 119                        session_id => $session->{session_id},
 120                      },
 121                      $writer
 122           );
 123         }
 124         unlock_write;
 125       }
 126       next;
 127     }
 128
 129     $undisp = 0;
 130
 131     warn "receiving packet from client\n" if $Debug;
 132
 133     my $packet = eval { fd_retrieve($reader); };
 134     if ( $@ ) {
 135       warn "Storable error receiving packet from client".
 136            " (assuming lost connection): $@\n"
 137         if $Debug;
 138       if ( $ssh_pid ) {
 139         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
 140         kill 'TERM', $ssh_pid;
 141         $old_ssh_pid{$ssh_pid} = 1;
 142         $ssh_pid = 0;
 143       }
 144       last;
 145     }
 146     warn "packet received\n".
 147          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
 148       if $Debug > 2;
 149
 150     if ( $packet->{_packet} eq '_enable_keepalive' ) {
 151       warn "enabling keep alives\n" if $Debug;
 152       $keepalives=1;
 153       next;
 154     }
 155
 156     #prevent runaway forking
 157     my $warnkids = 0;
 158     while ( $kids >= $max_kids ) {
 159       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
 160       &reap_kids;
 161       sleep 1;
 162     }
 163
 164     warn "forking child\n" if $Debug;
 165     defined( my $pid = fork ) or die "can't fork: $!";
 166     if ( $pid ) {
 167       $kids++;
 168       $kids{$pid} = 1;
 169       warn "child $pid spawned\n" if $Debug;
 170     } else { #kid time
 171
 172       ##get new db handle
 173       $FS::UID::dbh->{InactiveDestroy} = 1;
 174       forksuidsetup($user);
 175
 176       #get db handle
 177       #adminsuidsetup($user);
 178
 179       my $type = $packet->{_packet};
 180       warn "calling $type handler\n" if $Debug;
 181       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 182       if ( $@ ) {
 183         warn my $error = "WARNING: error dispatching $type: $@";
 184         $rv = { _error => $error };
 185       }
 186       $rv->{_token} = $packet->{_token}; #identifier
 187
 188       open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
 189       lock_write;
 190       warn "sending response\n" if $Debug;
 191       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 192       $writer->flush or die "FATAL: can't flush: $!";
 193       unlock_write;
 194
 195       warn "child exiting\n" if $Debug;
 196       exit; #end-of-kid
 197     }
 198
 199   }
 200
 201   myshutdown if sigint() || sigterm();
 202   warn "connection lost, reconnecting\n" if $Debug;
 203   sleep 3;
 204
 205 }
 206
 207 ###
 208 # utility subroutines
 209 ###
 210
 211 sub reap_kids {
 212   #warn "reaping kids\n";
 213   foreach my $pid ( keys %kids ) {
 214     my $kid = waitpid($pid, WNOHANG);
 215     if ( $kid > 0 ) {
 216       $kids--;
 217       delete $kids{$kid};
 218     }
 219   }
 220
 221   foreach my $pid ( keys %old_ssh_pid ) {
 222     waitpid($pid, WNOHANG) and delete $old_ssh_pid{$pid};
 223   }
 224   #warn "done reaping\n";
 225 }
 226
 227 sub myshutdown {
 228   &reap_kids;
 229   my $wait = 12; #wait up to 1 minute
 230   while ( $kids > 0 && $wait-- ) {
 231     warn "waiting for $kids children to terminate";
 232     sleep 5;
 233     &reap_kids;
 234   }
 235   warn "abandoning $kids children" if $kids;
 236   kill 'TERM', $ssh_pid if $ssh_pid;
 237   die "exiting";
 238 }
 239
 240 sub lock_write {
 241   warn "locking $lock_file mutex for write to write stream\n" if $Debug > 1;
 242
 243   #broken on freebsd?
 244   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 245
 246   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 247
 248 }
 249
 250 sub unlock_write {
 251   warn "unlocking $lock_file mutex\n" if $Debug > 1;
 252
 253   #broken on freebsd?
 254   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 255
 256   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 257
 258 }
 259
 260 sub usage {
 261   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 262 }
 263