FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $FREESIDE_LOG $FREESIDE_LOCK );
   5 use vars qw( $Debug %kids $kids $max_kids $ssh_pid %old_ssh_pid $keepalives );
   6 use subs qw( lock_write unlock_write myshutdown usage );
   7 use Fcntl qw(:flock);
   8 use POSIX qw(:sys_wait_h);
   9 use IO::Handle;
  10 use IO::Select;
  11 use IO::File;
  12 use Storable 2.09 qw(nstore_fd fd_retrieve);
  13 use Net::SSH qw(sshopen2);
  14 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
  15 use FS::UID qw(adminsuidsetup forksuidsetup);
  16 use FS::ClientAPI;
  17 use FS::ClientAPI_SessionCache;
  18
  19 use FS::Conf;
  20 use FS::cust_svc;
  21
  22 $FREESIDE_LOG = "%%%FREESIDE_LOG%%%";
  23 $FREESIDE_LOCK = "%%%FREESIDE_LOCK%%%";
  24
  25 $Debug = 1; # 2 will turn on more logging
  26             # 3 will log packet contents, including passwords
  27
  28 $max_kids = '10'; #?
  29 $keepalives = 0; #let clientd turn it on, so we don't barf on old ones
  30 $kids = 0;
  31
  32 my $user = shift or die &usage;
  33 my $machine = shift or die &usage;
  34 my $tag = scalar(@ARGV) ? shift : '';
  35
  36 my $lock_file = "$FREESIDE_LOCK/selfservice.$machine.writelock";
  37
  38 # to keep pid files unique w/multi machines (and installs!)
  39 # $FS::UID::datasrc not posible
  40 daemonize1("freeside-selfservice-server","$user.$machine");
  41
  42 #false laziness w/Daemon::drop_root
  43 my $freeside_gid = scalar(getgrnam('freeside'))
  44   or die "can't find freeside group\n";
  45
  46 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  47 chown $FS::UID::freeside_uid, $freeside_gid, $lock_file;
  48
  49 drop_root();
  50
  51 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  52
  53 adminsuidsetup $user;
  54
  55 #logfile("/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc); #MACHINE
  56 logfile("$FREESIDE_LOG/selfservice.$machine.log");
  57
  58 daemonize2();
  59
  60 my $conf = new FS::Conf;
  61 if ( $conf->exists('selfservice-ignore_quantity') ) {
  62   $FS::cust_svc::ignore_quantity = 1;
  63   $FS::cust_svc::ignore_quantity = 1; #now it is used twice.
  64 }
  65
  66 #clear the signup info cache so an "/etc/init.d/freeside restart" will pick
  67 #up new info... (better as a callback in Signup.pm?)
  68 my $cache = new FS::ClientAPI_SessionCache( {
  69   'namespace' => 'FS::ClientAPI::Signup',
  70 } );
  71 $cache->remove('signup_info_cache');
  72
  73 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  74
  75 my $warnkids=0;
  76 while (1) {
  77   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  78   warn "connecting to $machine\n" if $Debug;
  79
  80   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  81
  82 #  nstore_fd(\*writer, {'hi'=>'there'});
  83
  84   warn "entering main loop\n" if $Debug;
  85   my $undisp = 0;
  86   my $keepalive_count = 0;
  87   my $s = IO::Select->new( $reader );
  88   while (1) {
  89
  90     &reap_kids;
  91
  92     warn "waiting for packet from client\n" if $Debug && !$undisp;
  93     $undisp = 1;
  94     my @handles = $s->can_read(5);
  95     unless ( @handles ) {
  96       myshutdown() if sigint() || sigterm();
  97       if ( $keepalives && $keepalive_count++ > 10 ) {
  98         $keepalive_count = 0;
  99         lock_write;
 100         nstore_fd( { _token => '_keepalive' }, $writer );
 101         unlock_write;
 102       }
 103       next;
 104     }
 105
 106     $undisp = 0;
 107
 108     warn "receiving packet from client\n" if $Debug;
 109
 110     my $packet = eval { fd_retrieve($reader); };
 111     if ( $@ ) {
 112       warn "Storable error receiving packet from client".
 113            " (assuming lost connection): $@\n"
 114         if $Debug;
 115       if ( $ssh_pid ) {
 116         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
 117         kill 'TERM', $ssh_pid;
 118         $old_ssh_pid{$ssh_pid} = 1;
 119         $ssh_pid = 0;
 120       }
 121       last;
 122     }
 123     warn "packet received\n".
 124          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
 125       if $Debug > 2;
 126
 127     if ( $packet->{_packet} eq '_enable_keepalive' ) {
 128       warn "enabling keep alives\n" if $Debug;
 129       $keepalives=1;
 130       next;
 131     }
 132
 133     #prevent runaway forking
 134     my $warnkids = 0;
 135     while ( $kids >= $max_kids ) {
 136       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
 137       &reap_kids;
 138       sleep 1;
 139     }
 140
 141     warn "forking child\n" if $Debug;
 142     defined( my $pid = fork ) or die "can't fork: $!";
 143     if ( $pid ) {
 144       $kids++;
 145       $kids{$pid} = 1;
 146       warn "child $pid spawned\n" if $Debug;
 147     } else { #kid time
 148
 149       ##get new db handle
 150       $FS::UID::dbh->{InactiveDestroy} = 1;
 151       forksuidsetup($user);
 152
 153       #get db handle
 154       #adminsuidsetup($user);
 155
 156       my $type = $packet->{_packet};
 157       warn "calling $type handler\n" if $Debug;
 158       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 159       if ( $@ ) {
 160         warn my $error = "WARNING: error dispatching $type: $@";
 161         $rv = { _error => $error };
 162       }
 163       $rv->{_token} = $packet->{_token}; #identifier
 164
 165       open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
 166       lock_write;
 167       warn "sending response\n" if $Debug;
 168       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 169       $writer->flush or die "FATAL: can't flush: $!";
 170       unlock_write;
 171
 172       warn "child exiting\n" if $Debug;
 173       exit; #end-of-kid
 174     }
 175
 176   }
 177
 178   myshutdown if sigint() || sigterm();
 179   warn "connection lost, reconnecting\n" if $Debug;
 180   sleep 3;
 181
 182 }
 183
 184 ###
 185 # utility subroutines
 186 ###
 187
 188 sub reap_kids {
 189   #warn "reaping kids\n";
 190   foreach my $pid ( keys %kids ) {
 191     my $kid = waitpid($pid, WNOHANG);
 192     if ( $kid > 0 ) {
 193       $kids--;
 194       delete $kids{$kid};
 195     }
 196   }
 197
 198   foreach my $pid ( keys %old_ssh_pid ) {
 199     waitpid($pid, WNOHANG) and delete $old_ssh_pid{$pid};
 200   }
 201   #warn "done reaping\n";
 202 }
 203
 204 sub myshutdown {
 205   &reap_kids;
 206   my $wait = 12; #wait up to 1 minute
 207   while ( $kids > 0 && $wait-- ) {
 208     warn "waiting for $kids children to terminate";
 209     sleep 5;
 210     &reap_kids;
 211   }
 212   warn "abandoning $kids children" if $kids;
 213   kill 'TERM', $ssh_pid if $ssh_pid;
 214   die "exiting";
 215 }
 216
 217 sub lock_write {
 218   warn "locking $lock_file mutex for write to write stream\n" if $Debug > 1;
 219
 220   #broken on freebsd?
 221   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 222
 223   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 224
 225 }
 226
 227 sub unlock_write {
 228   warn "unlocking $lock_file mutex\n" if $Debug > 1;
 229
 230   #broken on freebsd?
 231   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 232
 233   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 234
 235 }
 236
 237 sub usage {
 238   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 239 }
 240