FS/bin/freeside-selfservice-server

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $Debug %kids $kids $max_kids $ssh_pid %old_ssh_pid $keepalives );
   5 use subs qw( lock_write unlock_write myshutdown usage );
   6 use Fcntl qw(:flock);
   7 use POSIX qw(:sys_wait_h);
   8 use IO::Handle;
   9 use IO::Select;
  10 use IO::File;
  11 use Storable 2.09 qw(nstore_fd fd_retrieve);
  12 use Net::SSH qw(sshopen2);
  13 use FS::Daemon qw(daemonize1 drop_root logfile daemonize2 sigint sigterm);
  14 use FS::UID qw(adminsuidsetup forksuidsetup);
  15 use FS::ClientAPI;
  16
  17 use FS::Conf;
  18 use FS::cust_bill;
  19 use FS::cust_pkg;
  20
  21 $Debug = 1; # 2 will turn on more logging
  22             # 3 will log packet contents, including passwords
  23
  24 $max_kids = '10'; #?
  25 $keepalives = 0; #let clientd turn it on, so we don't barf on old ones
  26 $kids = 0;
  27
  28 my $user = shift or die &usage;
  29 my $machine = shift or die &usage;
  30 my $tag = scalar(@ARGV) ? shift : '';
  31
  32 my $lock_file = "/usr/local/etc/freeside/selfservice.$machine.writelock";
  33
  34
  35 # to keep pid files unique w/multi machines (and installs!)
  36 # $FS::UID::datasrc not posible
  37 daemonize1("freeside-selfservice-server","$user.$machine");
  38
  39 #false laziness w/Daemon::drop_root
  40 my $freeside_gid = scalar(getgrnam('freeside'))
  41   or die "can't find freeside group\n";
  42
  43 open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
  44 chown $FS::UID::freeside_uid, $freeside_gid, $lock_file;
  45
  46 drop_root();
  47
  48 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  49
  50 adminsuidsetup $user;
  51
  52 #logfile("/usr/local/etc/freeside/selfservice.". $FS::UID::datasrc); #MACHINE
  53 logfile("/usr/local/etc/freeside/selfservice.$machine.log");
  54
  55 daemonize2();
  56
  57
  58 my $conf = new FS::Conf;
  59
  60 my $clientd = "/usr/local/sbin/freeside-selfservice-clientd"; #better name?
  61
  62 my $warnkids=0;
  63 while (1) {
  64   my($writer,$reader,$error) = (new IO::Handle, new IO::Handle, new IO::Handle);
  65   warn "connecting to $machine\n" if $Debug;
  66
  67   $ssh_pid = sshopen2($machine,$reader,$writer,$clientd,$tag);
  68
  69 #  nstore_fd(\*writer, {'hi'=>'there'});
  70
  71   warn "entering main loop\n" if $Debug;
  72   my $undisp = 0;
  73   my $keepalive_count = 0;
  74   my $s = IO::Select->new( $reader );
  75   while (1) {
  76
  77     &reap_kids;
  78
  79     warn "waiting for packet from client\n" if $Debug && !$undisp;
  80     $undisp = 1;
  81     my @handles = $s->can_read(5);
  82     unless ( @handles ) {
  83       myshutdown() if sigint() || sigterm();
  84       if ( $keepalives && $keepalive_count++ > 10 ) {
  85         $keepalive_count = 0;
  86         lock_write;
  87         nstore_fd( { _token => '_keepalive' }, $writer );
  88         unlock_write;
  89       }
  90       next;
  91     }
  92
  93     $undisp = 0;
  94
  95     warn "receiving packet from client\n" if $Debug;
  96
  97     my $packet = eval { fd_retrieve($reader); };
  98     if ( $@ ) {
  99       warn "Storable error receiving packet from client".
 100            " (assuming lost connection): $@\n"
 101         if $Debug;
 102       if ( $ssh_pid ) {
 103         warn "sending TERM signal to ssh process $ssh_pid\n" if $Debug;
 104         kill 'TERM', $ssh_pid;
 105         $old_ssh_pid{$ssh_pid} = 1;
 106         $ssh_pid = 0;
 107       }
 108       last;
 109     }
 110     warn "packet received\n".
 111          join('', map { " $_=>$packet->{$_}\n" } keys %$packet )
 112       if $Debug > 2;
 113
 114     if ( $packet->{_packet} eq '_enable_keepalive' ) {
 115       warn "enabling keep alives\n" if $Debug;
 116       $keepalives=1;
 117       next;
 118     }
 119
 120     #prevent runaway forking
 121     my $warnkids = 0;
 122     while ( $kids >= $max_kids ) {
 123       warn "WARNING: maximum $kids children reached\n" unless $warnkids++;
 124       &reap_kids;
 125       sleep 1;
 126     }
 127
 128     warn "forking child\n" if $Debug;
 129     defined( my $pid = fork ) or die "can't fork: $!";
 130     if ( $pid ) {
 131       $kids++;
 132       $kids{$pid} = 1;
 133       warn "child $pid spawned\n" if $Debug;
 134     } else { #kid time
 135
 136       ##get new db handle
 137       $FS::UID::dbh->{InactiveDestroy} = 1;
 138       forksuidsetup($user);
 139
 140       #get db handle
 141       #adminsuidsetup($user);
 142
 143       my $type = $packet->{_packet};
 144       warn "calling $type handler\n" if $Debug;
 145       my $rv = eval { FS::ClientAPI->dispatch($type, $packet); };
 146       if ( $@ ) {
 147         warn my $error = "WARNING: error dispatching $type: $@";
 148         $rv = { _error => $error };
 149       }
 150       $rv->{_token} = $packet->{_token}; #identifier
 151
 152       open(LOCKFILE,">$lock_file") or die "can't open $lock_file: $!";
 153       lock_write;
 154       warn "sending response\n" if $Debug;
 155       nstore_fd($rv, $writer) or die "FATAL: can't send response: $!";
 156       $writer->flush or die "FATAL: can't flush: $!";
 157       unlock_write;
 158
 159       warn "child exiting\n" if $Debug;
 160       exit; #end-of-kid
 161     }
 162
 163   }
 164
 165   myshutdown if sigint() || sigterm();
 166   warn "connection lost, reconnecting\n" if $Debug;
 167   sleep 3;
 168
 169 }
 170
 171 ###
 172 # utility subroutines
 173 ###
 174
 175 sub reap_kids {
 176   #warn "reaping kids\n";
 177   foreach my $pid ( keys %kids ) {
 178     my $kid = waitpid($pid, WNOHANG);
 179     if ( $kid > 0 ) {
 180       $kids--;
 181       delete $kids{$kid};
 182     }
 183   }
 184
 185   foreach my $pid ( keys %old_ssh_pid ) {
 186     waitpid($pid, WNOHANG) and delete $old_ssh_pid{$pid};
 187   }
 188   #warn "done reaping\n";
 189 }
 190
 191 sub myshutdown {
 192   &reap_kids;
 193   my $wait = 12; #wait up to 1 minute
 194   while ( $kids > 0 && $wait-- ) {
 195     warn "waiting for $kids children to terminate";
 196     sleep 5;
 197     &reap_kids;
 198   }
 199   warn "abandoning $kids children" if $kids;
 200   kill 'TERM', $ssh_pid if $ssh_pid;
 201   die "exiting";
 202 }
 203
 204 sub lock_write {
 205   warn "locking $lock_file mutex for write to write stream\n" if $Debug > 1;
 206
 207   #broken on freebsd?
 208   #flock($writer, LOCK_EX) or die "FATAL: can't lock write stream: $!";
 209
 210   flock(LOCKFILE, LOCK_EX) or die "FATAL: can't lock $lock_file: $!";
 211
 212 }
 213
 214 sub unlock_write {
 215   warn "unlocking $lock_file mutex\n" if $Debug > 1;
 216
 217   #broken on freebsd?
 218   #flock($writer, LOCK_UN) or die "WARNING: can't release write lock: $!";
 219
 220   flock(LOCKFILE, LOCK_UN) or die "FATAL: can't unlock $lock_file: $!";
 221
 222 }
 223
 224 sub usage {
 225   die "Usage:\n\n  freeside-selfservice-server user machine\n";
 226 }
 227