FS/bin/freeside-queued

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $log_file $sigterm $sigint );
   5 use subs qw( _die _logmsg );
   6 use Fcntl qw(:flock);
   7 use POSIX qw(setsid);
   8 use Date::Format;
   9 use IO::File;
  10 use FS::UID qw(adminsuidsetup);
  11 use FS::Record qw(qsearchs);
  12 use FS::queue;
  13
  14 # no autoloading just yet
  15 use FS::cust_main;
  16 use FS::svc_acct;
  17 use Net::SSH;
  18
  19 my $pid_file = '/var/run/freeside-queued.pid';
  20
  21 $SIG{CHLD} = sub { wait }; #zombie prevention
  22
  23 my $user = shift or die &usage;
  24
  25 &daemonize;
  26
  27  $sigterm = 0;
  28  $sigint = 0;
  29 $SIG{INT} = sub { warn "SIGINT received; shutting down\n"; $sigint++; };
  30 $SIG{TERM} = sub { warn "SIGTERM received; shutting down\n"; $sigterm++; };
  31
  32 $> = $FS::UID::freeside_uid unless $>;
  33 adminsuidsetup $user;
  34
  35 $log_file = "/usr/local/etc/freeside/queuelog.". $FS::UID::datasrc;
  36
  37 $SIG{__DIE__} = \&_die;
  38 $SIG{__WARN__} = \&_logmsg;
  39
  40 warn "freesied-queued starting\n";
  41
  42 while (1) {
  43
  44   my $job = qsearchs(
  45     'queue',
  46     { 'status' => 'new' },
  47     '',
  48     'ORDER BY jobnum FOR UPDATE LIMIT 1'
  49   ) or do {
  50     sleep 5;
  51     next;
  52   };
  53
  54   my %hash = $job->hash;
  55   $hash{'status'} = 'locked';
  56   my $ljob = new FS::queue ( \%hash );
  57   my $error = $ljob->replace($job);
  58   die $error if $error;
  59
  60   my @args = $ljob->args;
  61
  62   #fork a child for each job (up to some maximum perhaps?)
  63   #single-threaded for now.
  64
  65   my $eval = "&". $ljob->job. '(@args);';
  66   warn "running $eval";
  67   eval $eval;
  68   if ( $@ ) {
  69     warn "job $eval failed";
  70     my %hash = $ljob->hash;
  71     $hash{'status'} = 'failed';
  72     my $fjob = new FS::queue( \%hash );
  73     my $error = $fjob->replace($ljob);
  74     die $error if $error;
  75   } else {
  76     $ljob->delete;
  77   }
  78
  79 } continue {
  80   if ( $sigterm ) {
  81     warn "received TERM signal; exiting\n";
  82     exit;
  83   }
  84   if ( $sigint ) {
  85     warn "received INT signal; exiting\n";
  86     exit;
  87   }
  88 }
  89
  90 sub usage {
  91   die "Usage:\n\n  freeside-queued user\n";
  92 }
  93
  94 sub _die {
  95   my $msg = shift;
  96   unlink $pid_file if -e $pid_file;
  97   _logmsg($msg);
  98 }
  99
 100 sub _logmsg {
 101   chomp( my $msg = shift );
 102   my $log = new IO::File ">>$log_file";
 103   flock($log, LOCK_EX);
 104   seek($log, 0, 2);
 105   print $log "[". time2str("%a %b %e %T %Y",time). "] [$$] $msg\n";
 106   flock($log, LOCK_UN);
 107   close $log;
 108 }
 109
 110 sub daemonize {
 111
 112   chdir "/" or die "Can't chdir to /: $!";
 113   open STDIN, '/dev/null'   or die "Can't read /dev/null: $!";
 114   defined(my $pid = fork) or die "Can't fork: $!";
 115   if ( $pid ) {
 116     print "freeside-queued started with pid $pid\n"; #logging to $log_file\n";
 117     exit unless $pid_file;
 118     my $pidfh = new IO::File ">$pid_file" or exit;
 119     print $pidfh "$pid\n";
 120     exit;
 121   }
 122   open STDOUT, '>/dev/null'
 123                             or die "Can't write to /dev/null: $!";
 124   setsid                  or die "Can't start a new session: $!";
 125   open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 126
 127 }
 128
 129 =head1 NAME
 130
 131 freeside-queued - Job queue daemon
 132
 133 =head1 SYNOPSIS
 134
 135   freeside-queued user
 136
 137 =head1 DESCRIPTION
 138
 139 Job queue daemon.  Should be running at all times.
 140
 141 user: from the mapsecrets file - see config.html from the base documentation
 142
 143 =head1 VERSION
 144
 145 =head1 BUGS
 146
 147 =head1 SEE ALSO
 148
 149 =cut
 150