FS/bin/freeside-queued

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $log_file $sigterm $sigint );
   5 use subs qw( _die _logmsg );
   6 use Fcntl qw(:flock);
   7 use POSIX qw(setsid);
   8 use Date::Format;
   9 use IO::File;
  10 use FS::UID qw(adminsuidsetup forksuidsetup driver_name);
  11 use FS::Record qw(qsearchs);
  12 use FS::queue;
  13
  14 # no autoloading just yet
  15 use FS::cust_main;
  16 use FS::svc_acct;
  17 use Net::SSH 0.05;
  18
  19 my $pid_file = '/var/run/freeside-queued.pid';
  20
  21 my $user = shift or die &usage;
  22
  23 &daemonize;
  24
  25 sub REAPER { my $pid = wait; $SIG{CHLD} = \&REAPER; }
  26 $SIG{CHLD} =  \&REAPER;
  27
  28  $sigterm = 0;
  29  $sigint = 0;
  30 $SIG{INT} = sub { warn "SIGINT received; shutting down\n"; $sigint++; };
  31 $SIG{TERM} = sub { warn "SIGTERM received; shutting down\n"; $sigterm++; };
  32
  33 $> = $FS::UID::freeside_uid unless $>;
  34 $< = $>;
  35 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  36 adminsuidsetup $user;
  37
  38 $log_file = "/usr/local/etc/freeside/queuelog.". $FS::UID::datasrc;
  39
  40 $SIG{__DIE__} = \&_die;
  41 $SIG{__WARN__} = \&_logmsg;
  42
  43 warn "freeside-queued starting\n";
  44
  45 while (1) {
  46
  47   my $job = qsearchs(
  48     'queue',
  49     { 'status' => 'new' },
  50     '',
  51     driver_name =~ /^mysql$/i
  52       ? 'ORDER BY jobnum LIMIT 1 FOR UPDATE'
  53       : 'ORDER BY jobnum FOR UPDATE LIMIT 1'
  54   ) or do {
  55     sleep 5;
  56     next;
  57   };
  58
  59   my %hash = $job->hash;
  60   $hash{'status'} = 'locked';
  61   my $ljob = new FS::queue ( \%hash );
  62   my $error = $ljob->replace($job);
  63   die $error if $error;
  64
  65   my @args = $ljob->args;
  66
  67   # number of children limit?
  68   defined( my $pid = fork ) or do {
  69     warn "WARNING: can't fork: $!\n";
  70     my %hash = $job->hash;
  71     $hash{'status'} = 'failed';
  72     $hash{'statustext'} = "[freeside-queued] can't fork: $!";
  73     my $ljob = new FS::queue ( \%hash );
  74     my $error = $ljob->replace($job);
  75     die $error if $error;
  76   };
  77
  78   unless ( $pid ) { #kid time
  79
  80     #get new db handles
  81     $FS::UID::dbh->{InactiveDestroy} = 1;
  82     $FS::svc_acct::icradius_dbh->{InactiveDestroy} = 1
  83       if $FS::svc_acct::icradius_dbh;
  84     forksuidsetup($user);
  85
  86     my $eval = "&". $ljob->job. '(@args);';
  87     warn "running $eval";
  88     eval $eval;
  89     if ( $@ ) {
  90       warn "job $eval failed";
  91       my %hash = $ljob->hash;
  92       $hash{'status'} = 'failed';
  93       $hash{'statustext'} = $@;
  94       my $fjob = new FS::queue( \%hash );
  95       my $error = $fjob->replace($ljob);
  96       die $error if $error;
  97     } else {
  98       $ljob->delete;
  99     }
 100
 101     exit;
 102     #end-of-kid
 103   }
 104
 105 } continue {
 106   if ( $sigterm ) {
 107     warn "received TERM signal; exiting\n";
 108     exit;
 109   }
 110   if ( $sigint ) {
 111     warn "received INT signal; exiting\n";
 112     exit;
 113   }
 114 }
 115
 116 sub usage {
 117   die "Usage:\n\n  freeside-queued user\n";
 118 }
 119
 120 sub _die {
 121   my $msg = shift;
 122   unlink $pid_file if -e $pid_file;
 123   _logmsg($msg);
 124 }
 125
 126 sub _logmsg {
 127   chomp( my $msg = shift );
 128   my $log = new IO::File ">>$log_file";
 129   flock($log, LOCK_EX);
 130   seek($log, 0, 2);
 131   print $log "[". time2str("%a %b %e %T %Y",time). "] [$$] $msg\n";
 132   flock($log, LOCK_UN);
 133   close $log;
 134 }
 135
 136 sub daemonize {
 137
 138   chdir "/" or die "Can't chdir to /: $!";
 139   open STDIN, '/dev/null'   or die "Can't read /dev/null: $!";
 140   defined(my $pid = fork) or die "Can't fork: $!";
 141   if ( $pid ) {
 142     print "freeside-queued started with pid $pid\n"; #logging to $log_file\n";
 143     exit unless $pid_file;
 144     my $pidfh = new IO::File ">$pid_file" or exit;
 145     print $pidfh "$pid\n";
 146     exit;
 147   }
 148   open STDOUT, '>/dev/null'
 149                             or die "Can't write to /dev/null: $!";
 150   setsid                  or die "Can't start a new session: $!";
 151   open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 152
 153 }
 154
 155 =head1 NAME
 156
 157 freeside-queued - Job queue daemon
 158
 159 =head1 SYNOPSIS
 160
 161   freeside-queued user
 162
 163 =head1 DESCRIPTION
 164
 165 Job queue daemon.  Should be running at all times.
 166
 167 user: from the mapsecrets file - see config.html from the base documentation
 168
 169 =head1 VERSION
 170
 171 =head1 BUGS
 172
 173 =head1 SEE ALSO
 174
 175 =cut
 176