FS/bin/freeside-queued

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $log_file $sigterm $sigint );
   5 use subs qw( _die _logmsg );
   6 use Fcntl qw(:flock);
   7 use POSIX qw(setsid);
   8 use Date::Format;
   9 use IO::File;
  10 use FS::UID qw(adminsuidsetup forksuidsetup);
  11 use FS::Record qw(qsearchs);
  12 use FS::queue;
  13
  14 # no autoloading just yet
  15 use FS::cust_main;
  16 use FS::svc_acct;
  17 use Net::SSH;
  18
  19 my $pid_file = '/var/run/freeside-queued.pid';
  20
  21 my $user = shift or die &usage;
  22
  23 &daemonize;
  24
  25 sub REAPER { my $pid = wait; $SIG{CHLD} = \&REAPER; }
  26 $SIG{CHLD} =  \&REAPER;
  27
  28  $sigterm = 0;
  29  $sigint = 0;
  30 $SIG{INT} = sub { warn "SIGINT received; shutting down\n"; $sigint++; };
  31 $SIG{TERM} = sub { warn "SIGTERM received; shutting down\n"; $sigterm++; };
  32
  33 $> = $FS::UID::freeside_uid unless $>;
  34 $< = $>;
  35 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  36 adminsuidsetup $user;
  37
  38 $log_file = "/usr/local/etc/freeside/queuelog.". $FS::UID::datasrc;
  39
  40 $SIG{__DIE__} = \&_die;
  41 $SIG{__WARN__} = \&_logmsg;
  42
  43 warn "freesied-queued starting\n";
  44
  45 while (1) {
  46
  47   my $job = qsearchs(
  48     'queue',
  49     { 'status' => 'new' },
  50     '',
  51     'ORDER BY jobnum FOR UPDATE LIMIT 1'
  52   ) or do {
  53     sleep 5;
  54     next;
  55   };
  56
  57   my %hash = $job->hash;
  58   $hash{'status'} = 'locked';
  59   my $ljob = new FS::queue ( \%hash );
  60   my $error = $ljob->replace($job);
  61   die $error if $error;
  62
  63   my @args = $ljob->args;
  64
  65   # number of children limit?
  66   defined( my $pid = fork ) or do {
  67     warn "WARNING: can't fork: $!\n";
  68     my %hash = $job->hash;
  69     $hash{'status'} = 'failed';
  70     my $ljob = new FS::queue ( \%hash );
  71     my $error = $ljob->replace($job);
  72     die $error if $error;
  73   };
  74
  75   unless ( $pid ) { #kid time
  76
  77     #get new db handles
  78     $FS::UID::dbh->{InactiveDestroy} = 1;
  79     $FS::svc_acct::icradius_dbh->{InactiveDestroy}
  80       if $FS::svc_acct::icradius_dbh;
  81     forksuidsetup($user);
  82
  83     my $eval = "&". $ljob->job. '(@args);';
  84     warn "running $eval";
  85     eval $eval;
  86     if ( $@ ) {
  87       warn "job $eval failed";
  88       my %hash = $ljob->hash;
  89       $hash{'status'} = 'failed';
  90       my $fjob = new FS::queue( \%hash );
  91       my $error = $fjob->replace($ljob);
  92       die $error if $error;
  93     } else {
  94       $ljob->delete;
  95     }
  96
  97     exit;
  98     #end-of-kid
  99   }
 100
 101 } continue {
 102   if ( $sigterm ) {
 103     warn "received TERM signal; exiting\n";
 104     exit;
 105   }
 106   if ( $sigint ) {
 107     warn "received INT signal; exiting\n";
 108     exit;
 109   }
 110 }
 111
 112 sub usage {
 113   die "Usage:\n\n  freeside-queued user\n";
 114 }
 115
 116 sub _die {
 117   my $msg = shift;
 118   unlink $pid_file if -e $pid_file;
 119   _logmsg($msg);
 120 }
 121
 122 sub _logmsg {
 123   chomp( my $msg = shift );
 124   my $log = new IO::File ">>$log_file";
 125   flock($log, LOCK_EX);
 126   seek($log, 0, 2);
 127   print $log "[". time2str("%a %b %e %T %Y",time). "] [$$] $msg\n";
 128   flock($log, LOCK_UN);
 129   close $log;
 130 }
 131
 132 sub daemonize {
 133
 134   chdir "/" or die "Can't chdir to /: $!";
 135   open STDIN, '/dev/null'   or die "Can't read /dev/null: $!";
 136   defined(my $pid = fork) or die "Can't fork: $!";
 137   if ( $pid ) {
 138     print "freeside-queued started with pid $pid\n"; #logging to $log_file\n";
 139     exit unless $pid_file;
 140     my $pidfh = new IO::File ">$pid_file" or exit;
 141     print $pidfh "$pid\n";
 142     exit;
 143   }
 144   open STDOUT, '>/dev/null'
 145                             or die "Can't write to /dev/null: $!";
 146   setsid                  or die "Can't start a new session: $!";
 147   open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 148
 149 }
 150
 151 =head1 NAME
 152
 153 freeside-queued - Job queue daemon
 154
 155 =head1 SYNOPSIS
 156
 157   freeside-queued user
 158
 159 =head1 DESCRIPTION
 160
 161 Job queue daemon.  Should be running at all times.
 162
 163 user: from the mapsecrets file - see config.html from the base documentation
 164
 165 =head1 VERSION
 166
 167 =head1 BUGS
 168
 169 =head1 SEE ALSO
 170
 171 =cut
 172