FS/bin/freeside-queued

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use vars qw( $log_file $sigterm $sigint );
   5 use subs qw( _die _logmsg );
   6 use Fcntl qw(:flock);
   7 use POSIX qw(setsid);
   8 use Date::Format;
   9 use IO::File;
  10 use FS::UID qw(adminsuidsetup);
  11 use FS::Record qw(qsearchs);
  12 use FS::queue;
  13
  14 # no autoloading just yet
  15 use FS::cust_main;
  16 use FS::svc_acct;
  17 use Net::SSH;
  18
  19 my $pid_file = '/var/run/freeside-queued.pid';
  20
  21 $SIG{CHLD} = sub { wait }; #zombie prevention
  22
  23 my $user = shift or die &usage;
  24
  25 &daemonize;
  26
  27  $sigterm = 0;
  28  $sigint = 0;
  29 $SIG{INT} = sub { warn "SIGINT received; shutting down\n"; $sigint++; };
  30 $SIG{TERM} = sub { warn "SIGTERM received; shutting down\n"; $sigterm++; };
  31
  32 $> = $FS::UID::freeside_uid unless $>;
  33 $ENV{HOME} = (getpwuid($>))[7]; #for ssh
  34 adminsuidsetup $user;
  35
  36 $log_file = "/usr/local/etc/freeside/queuelog.". $FS::UID::datasrc;
  37
  38 $SIG{__DIE__} = \&_die;
  39 $SIG{__WARN__} = \&_logmsg;
  40
  41 warn "freesied-queued starting\n";
  42
  43 while (1) {
  44
  45   my $job = qsearchs(
  46     'queue',
  47     { 'status' => 'new' },
  48     '',
  49     'ORDER BY jobnum FOR UPDATE LIMIT 1'
  50   ) or do {
  51     sleep 5;
  52     next;
  53   };
  54
  55   my %hash = $job->hash;
  56   $hash{'status'} = 'locked';
  57   my $ljob = new FS::queue ( \%hash );
  58   my $error = $ljob->replace($job);
  59   die $error if $error;
  60
  61   my @args = $ljob->args;
  62
  63   #fork a child for each job (up to some maximum perhaps?)
  64   #single-threaded for now.
  65
  66   my $eval = "&". $ljob->job. '(@args);';
  67   warn "running $eval";
  68   eval $eval;
  69   if ( $@ ) {
  70     warn "job $eval failed";
  71     my %hash = $ljob->hash;
  72     $hash{'status'} = 'failed';
  73     my $fjob = new FS::queue( \%hash );
  74     my $error = $fjob->replace($ljob);
  75     die $error if $error;
  76   } else {
  77     $ljob->delete;
  78   }
  79
  80 } continue {
  81   if ( $sigterm ) {
  82     warn "received TERM signal; exiting\n";
  83     exit;
  84   }
  85   if ( $sigint ) {
  86     warn "received INT signal; exiting\n";
  87     exit;
  88   }
  89 }
  90
  91 sub usage {
  92   die "Usage:\n\n  freeside-queued user\n";
  93 }
  94
  95 sub _die {
  96   my $msg = shift;
  97   unlink $pid_file if -e $pid_file;
  98   _logmsg($msg);
  99 }
 100
 101 sub _logmsg {
 102   chomp( my $msg = shift );
 103   my $log = new IO::File ">>$log_file";
 104   flock($log, LOCK_EX);
 105   seek($log, 0, 2);
 106   print $log "[". time2str("%a %b %e %T %Y",time). "] [$$] $msg\n";
 107   flock($log, LOCK_UN);
 108   close $log;
 109 }
 110
 111 sub daemonize {
 112
 113   chdir "/" or die "Can't chdir to /: $!";
 114   open STDIN, '/dev/null'   or die "Can't read /dev/null: $!";
 115   defined(my $pid = fork) or die "Can't fork: $!";
 116   if ( $pid ) {
 117     print "freeside-queued started with pid $pid\n"; #logging to $log_file\n";
 118     exit unless $pid_file;
 119     my $pidfh = new IO::File ">$pid_file" or exit;
 120     print $pidfh "$pid\n";
 121     exit;
 122   }
 123   open STDOUT, '>/dev/null'
 124                             or die "Can't write to /dev/null: $!";
 125   setsid                  or die "Can't start a new session: $!";
 126   open STDERR, '>&STDOUT' or die "Can't dup stdout: $!";
 127
 128 }
 129
 130 =head1 NAME
 131
 132 freeside-queued - Job queue daemon
 133
 134 =head1 SYNOPSIS
 135
 136   freeside-queued user
 137
 138 =head1 DESCRIPTION
 139
 140 Job queue daemon.  Should be running at all times.
 141
 142 user: from the mapsecrets file - see config.html from the base documentation
 143
 144 =head1 VERSION
 145
 146 =head1 BUGS
 147
 148 =head1 SEE ALSO
 149
 150 =cut
 151