FS/bin/freeside-eftca-upload

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use Getopt::Std;
   5 use Date::Format qw(time2str);
   6 use File::Temp qw(tempdir);
   7 use Net::SFTP::Foreign;
   8 use FS::UID qw(adminsuidsetup dbh);
   9 use FS::Record qw(qsearch qsearchs);
  10 use FS::pay_batch;
  11 use FS::Conf;
  12 use FS::Log;
  13
  14 use vars qw( $opt_a $opt_v );
  15 getopts('av');
  16
  17 #$Net::SFTP::Foreign::debug = -1;
  18
  19 sub HELP_MESSAGE { "
  20   Usage:
  21     freeside-eftca-upload [ -v ] user batchnum
  22     freeside-eftca-upload -a [ -v ] user\n
  23 " }
  24
  25 my $user = shift or die &HELP_MESSAGE;
  26 adminsuidsetup $user;
  27
  28 my $log = FS::Log->new('freeside-eftca-upload');
  29 log_info( "EFT Canada upload started\n" );
  30
  31 my @batches;
  32
  33 if($opt_a) {
  34   local $@;
  35
  36   my %criteria= ( 'status' => 'O', 'payby' => 'CHEK' );
  37   $criteria{'type'} = 'DEBIT' unless FS::pay_batch->can_handle_electronic_refunds('eft_canada');
  38
  39   eval {
  40     @batches = qsearch('pay_batch', \%criteria)
  41   };
  42   log_error_and_die ("Fatal database error: $@")
  43     if $@;
  44
  45   log_info_and_die( "Finished: No open batches found.\n" )
  46     unless @batches;
  47 }
  48 else {
  49   my $batchnum = shift;
  50   die &HELP_MESSAGE if !$batchnum;
  51
  52   local $@;
  53   eval { @batches = qsearchs('pay_batch', { batchnum => $batchnum } ); };
  54   log_error_and_die("Fatal database error: $@")
  55     if $@;
  56
  57   log_error_and_die( "Can't find payment batch '$batchnum'\n" ) if !@batches;
  58 }
  59
  60 my $conf = new FS::Conf;
  61
  62 my $tmpdir = tempdir( CLEANUP => 1 ); #DIR=>somewhere?
  63
  64 foreach my $pay_batch (@batches) {
  65
  66   my $batchnum = $pay_batch->batchnum;
  67   my $filename = time2str('%Y%m%d', time) . '-' . sprintf('%06d.csv',$batchnum);
  68   log_info( "Exporting batch $batchnum to $filename...\n" );
  69   my $text = $pay_batch->export_batch(format => 'eft_canada');
  70   unless ($text) {
  71     log_info( "Batch is empty, resolving..." );
  72     next;
  73   }
  74   open OUT, ">$tmpdir/$filename";
  75   print OUT $text;
  76   close OUT;
  77
  78   my @batchconf = $conf->config('batchconfig-eft_canada', $pay_batch->agentnum);
  79   my $user = $batchconf[0]
  80     or log_error_and_die( "no EFT Canada batch username configured\n" );
  81   my $pass = $batchconf[1]
  82     or log_error_and_die( "no EFT Canada batch password configured\n" );
  83
  84   my $host = 'ftp.eftcanada.com';
  85   log_info( "Connecting to $user\@$host...\n" );
  86
  87   my $sftp = Net::SFTP::Foreign->new( host     => $host,
  88                                       user     => $user,
  89                                       password => $pass,
  90                                       timeout  => 30,
  91                                     );
  92   log_error_and_die("failed to connect to '$user\@$host'\n(".$sftp->error.")\n")
  93       if $sftp->error;
  94
  95   $sftp->put("$tmpdir/$filename", "$filename")
  96     or log_error_and_die( "failed to upload file (".$sftp->error.")\n" );
  97
  98   undef $sftp; #$sftp->disconnect;
  99
 100   # Auto-approve and close the batch.  Some false laziness with manual_approve.
 101   my $batchnum = $pay_batch->batchnum;
 102   my $error;
 103
 104   local $@;
 105   eval {
 106     foreach my $cpb ( qsearch('cust_pay_batch', { 'batchnum' => $batchnum } )) {
 107       $cpb->setfield('paid', $cpb->amount);
 108       $error = $cpb->approve($batchnum);
 109       last if $error;
 110     }
 111   };
 112   log_error_and_die("Fatal database error: $@")
 113     if $@;
 114
 115   $error ||= $pay_batch->set_status('R');
 116   log_error_and_die( "error closing batch $batchnum: $error\n\n" )
 117     if $error;
 118 }
 119
 120 log_info( "Finished!\n" );
 121
 122 sub log_info {
 123   my $log_message = shift;
 124   $log->info( $log_message );
 125   print STDERR $log_message if $opt_v;
 126 }
 127
 128 sub log_info_and_die {
 129   my $log_message = shift;
 130   $log->info( $log_message );
 131   die $log_message;
 132 }
 133
 134 sub log_error_and_die {
 135   my $log_message = shift;
 136   $log->error( $log_message );
 137   die $log_message;
 138 }
 139
 140 =head1 NAME
 141
 142 freeside-eftca-upload - Transmit a payment batch to EFT Canada via SFTP.
 143
 144 =head1 SYNOPSIS
 145
 146   freeside-eftca-upload [ -a ] [ -v ] user batchnum
 147
 148 =head1 DESCRIPTION
 149
 150 Command line tool to upload a payment batch to the EFT Canada gateway.  The
 151 batch will be exported to a comma-delimited file and transmitted via SFTP.
 152 Use L<freeside-eftca-download> to retrieve the response file.
 153
 154 -a: Send all open batches, instead of specifying a batchnum.
 155
 156 -v: Be verbose.
 157
 158 user: freeside username
 159
 160 batchnum: pay_batch primary key
 161
 162 =head1 SEE ALSO
 163
 164 L<FS::pay_batch>
 165
 166 =cut
 167
 168 1;
 169