FS/bin/freeside-cdr-asterisk_sql

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use vars qw( $DEBUG );
   5 use Date::Parse 'str2time';
   6 use Date::Format 'time2str';
   7 use FS::UID qw(adminsuidsetup dbh);
   8 use FS::Log;
   9 use FS::cdr;
  10 use FS::DBI;
  11 use Getopt::Std;
  12
  13 $DEBUG = 0;
  14
  15 my %opt;
  16 getopts('e:H:U:P:D:T:V:', \%opt);
  17 my $user = shift or die &usage;
  18
  19 my $engine = $opt{e} || 'mysql';
  20
  21 my $dsn = "dbi:$engine";
  22 $dsn .= ":database=$opt{D}"; # if $opt{D};
  23 $dsn .= ";host=$opt{H}" if $opt{H};
  24
  25 adminsuidsetup $user;
  26
  27 my $log = FS::Log->new( 'freeside-cdr-asterisk_sql' );
  28
  29 my $dbi = FS::DBI->connect($dsn, $opt{U}, $opt{P}) ;
  30
  31 if ( $dbi ) {
  32   log_msg( info => "Established connection to CDR database at dsn($dsn)" );
  33 } else {
  34   log_and_die( error =>
  35     sprintf 'Fatal error connecting to CDR database at dsn(%s): %s',
  36       $dsn,
  37       $FS::DBI::errstr
  38   );
  39 }
  40
  41 my $fsdbh = FS::UID::dbh;
  42
  43 my $table = $opt{T} || 'cdr';
  44
  45 # check for existence of freesidestatus
  46 if ( $engine =~ /^mysql/ ) {
  47   my $status = $dbi->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'freesidestatus'");
  48   if( ! @$status ) {
  49     log_msg( warn => "Adding freesidestatus column" );
  50     $dbi->do("ALTER TABLE $table ADD COLUMN freesidestatus varchar(32)")
  51       or log_and_die( error => $dbi->errstr );
  52   } else {
  53     log_msg( info => "freesidestatus column present" );
  54   }
  55 }
  56
  57 my @cols = ();
  58 if ( $opt{V} >= 12 ) {
  59   push @cols, qw( id start answer end );
  60 } else {
  61   push @cols, qw( calldate );
  62 }
  63
  64 push @cols,  qw(
  65   clid src dst dcontext channel lastapp lastdata duration
  66   billsec disposition amaflags accountcode userfield
  67 );
  68
  69 # check for existence of uniqueid
  70 if ( $engine =~ /^mysql/ ) {
  71   my $status = $dbi->selectall_arrayref("SHOW COLUMNS FROM $table WHERE Field = 'uniqueid'");
  72   if( @$status ) {
  73     push @cols, 'uniqueid';
  74   }
  75 } else {
  76   #assume there's a uniqueid
  77   push @cols, 'uniqueid';
  78 }
  79
  80 my $sql =
  81   'SELECT '.join(',', @cols). " FROM $table WHERE freesidestatus IS NULL";
  82 my $sth = $dbi->prepare($sql);
  83 $sth->execute
  84   or log_and_die( error => $sth->errstr );
  85
  86 log_msg( info => sprintf 'Importing %s records', $sth->rows );
  87
  88 my $cdr_batch = new FS::cdr_batch({
  89     'cdrbatch' => 'sql-import-'. time2str('%Y/%m/%d-%T',time),
  90   });
  91 if ( my $error = $cdr_batch->insert ) {
  92   log_and_die( error => $error );
  93 } else {
  94   log_msg( info =>
  95       sprintf 'cdrbatch %s %s',
  96         $cdr_batch->cdrbatch,
  97         $cdr_batch->cdrbatchnum
  98   );
  99 }
 100
 101 my $cdrbatchnum = $cdr_batch->cdrbatchnum;
 102
 103 my $imports = 0;
 104 my $updates = 0;
 105
 106 while ( my $row = $sth->fetchrow_hashref ) {
 107
 108   my $cdr = FS::cdr->new($row);
 109
 110   if ( $opt{V} >= 12 ) {
 111     $cdr->calldate($cdr->start);
 112     $cdr->startdate(str2time($cdr->start));
 113     $cdr->answerdate(str2time($cdr->answer));
 114     $cdr->enddate(str2time($cdr->end));
 115     $cdr->cdrid($cdr->id);
 116   } else {
 117     $cdr->startdate(str2time($cdr->calldate));
 118   }
 119
 120   $cdr->cdrbatchnum($cdrbatchnum);
 121
 122   if ( my $error = $cdr->insert ) {
 123     log_msg( error =>
 124       sprintf 'Non-fatal failure to import acctid(%s) from table(%s): %s',
 125         $row->acctid,
 126         $table,
 127         $error
 128     );
 129   } else {
 130
 131     $imports++;
 132
 133     my $usql = "UPDATE $table SET freesidestatus = 'done' WHERE ";
 134     my @args = ();
 135     if ( $opt{V} >= 12 ) {
 136       $usql .= ' id = '. $row->{'id'};
 137       @args = ( undef );
 138     } else {
 139       $usql .= ' calldate = ? AND src = ? AND dst = ?';
 140       @args = ( undef, $row->{'calldate'}, $row->{'src'}, $row->{'dst'}, );
 141     }
 142
 143     if ( $dbi->do($usql, @args) ) {
 144       $updates++;
 145     } else {
 146       log_msg( error =>
 147         sprintf 'Non-fatal failure set status(done) acctid(%s) table(%s): %s',
 148           $row->acctid,
 149           $table,
 150           $dbi->errstr
 151       );
 152     }
 153
 154   }
 155
 156 }
 157
 158 log_and_warn(
 159   info => "Done.\nImported $imports CDRs, marked $updates CDRs as done"
 160 );
 161
 162 $dbi->disconnect;
 163
 164 sub log_and_die {
 165   my ( $level, $message ) = @_;
 166   $log->$level( $message );
 167   die "[$level] $message\n";
 168 }
 169
 170 sub log_msg {
 171   my ( $level, $message ) = @_;
 172   $log->$level( $message );
 173   warn "[$level] $message\n"
 174     if $opt{v};
 175 }
 176
 177 sub log_and_warn {
 178   my ( $level, $message ) = @_;
 179   $log->$level( $message );
 180   warn "$message\n";
 181 }
 182
 183
 184 sub usage {
 185   "Usage: \n  freeside-cdr-asterisk_sql\n\t-e mysql|Pg|... [ -H host ]n\t-D database\n\t[ -T table ]\n\t[ -V asterisk_version]\n\t-U user\n\t-P password\n\tfreesideuser\n";
 186 }
 187
 188 =head1 NAME
 189
 190 freeside-cdr-asterisk_sql - Import CDRs from an Asterisk SQL database
 191
 192 =head1 SYNOPSIS
 193
 194   freeside-cdr-asterisk_sql -e mysql|Pg|... [ -H host ] -D database [ -T table ][ -V asterisk_version ] -U user -P password freesideuser
 195
 196 =head1 DESCRIPTION
 197
 198 Imports CDR records from an Asterisk SQL database.
 199
 200 -H: hostname
 201
 202 -e: Database engine (default mysql)
 203
 204 -D: database name
 205
 206 -T: table name (default cdr)
 207
 208 -U: username
 209
 210 -P: password
 211
 212 -V: Asterisk version.  Values of 12 or higher have a new database schema which no longer includes calldate.  Currently defaults to 11, but may default to 12+ or be required in a future, so best to always specify the version.
 213
 214 =cut
 215
 216 1;