FS/FS/tower.pm

   1 package FS::tower;
   2
   3 use strict;
   4 use base qw( FS::o2m_Common FS::Record );
   5 use FS::Record qw( qsearch qsearchs );
   6 use FS::tower_sector;
   7 use List::Util qw( max );
   8
   9 =head1 NAME
  10
  11 FS::tower - Object methods for tower records
  12
  13 =head1 SYNOPSIS
  14
  15   use FS::tower;
  16
  17   $record = new FS::tower \%hash;
  18   $record = new FS::tower { 'column' => 'value' };
  19
  20   $error = $record->insert;
  21
  22   $error = $new_record->replace($old_record);
  23
  24   $error = $record->delete;
  25
  26   $error = $record->check;
  27
  28 =head1 DESCRIPTION
  29
  30 An FS::tower object represents a tower.  FS::tower inherits from
  31 FS::Record.  The following fields are currently supported:
  32
  33 =over 4
  34
  35 =item towernum
  36
  37 primary key
  38
  39 =item towername
  40
  41 Tower name
  42
  43 =item disabled
  44
  45 Disabled flag, empty or 'Y'
  46
  47 =item up_rate
  48
  49 Up Rate for towner
  50
  51 =item down_rate
  52
  53 Down Rate for tower
  54
  55 =back
  56
  57 =head1 METHODS
  58
  59 =over 4
  60
  61 =item new HASHREF
  62
  63 Creates a new tower.  To add the tower to the database, see L<"insert">.
  64
  65 Note that this stores the hash reference, not a distinct copy of the hash it
  66 points to.  You can ask the object for a copy with the I<hash> method.
  67
  68 =cut
  69
  70 sub table { 'tower'; }
  71
  72 =item insert
  73
  74 Adds this record to the database.  If there is an error, returns the error,
  75 otherwise returns false.
  76
  77 =item delete
  78
  79 Delete this record from the database.
  80
  81 =item replace OLD_RECORD
  82
  83 Replaces the OLD_RECORD with this one in the database.  If there is an error,
  84 returns the error, otherwise returns false.
  85
  86 =item check
  87
  88 Checks all fields to make sure this is a valid tower.  If there is
  89 an error, returns the error, otherwise returns false.  Called by the insert
  90 and replace methods.
  91
  92 =cut
  93
  94 sub check {
  95   my $self = shift;
  96
  97   my $error =
  98     $self->ut_numbern('towernum')
  99     || $self->ut_text('towername')
 100     || $self->ut_enum('disabled', [ '', 'Y' ])
 101     || $self->ut_coordn('latitude')
 102     || $self->ut_coordn('longitude')
 103     || $self->ut_enum('coord_auto', [ '', 'Y' ])
 104     || $self->ut_floatn('altitude')
 105     || $self->ut_floatn('height')
 106     || $self->ut_floatn('veg_height')
 107     || $self->ut_alphan('color')
 108     || $self->ut_numbern('up_rate')
 109     || $self->ut_numbern('down_rate')
 110   ;
 111   return $error if $error;
 112
 113   $self->SUPER::check;
 114 }
 115
 116 =item default_sector
 117
 118 Returns the default sector.
 119
 120 =cut
 121
 122 sub default_sector {
 123   my $self = shift;
 124   qsearchs('tower_sector', { towernum => $self->towernum,
 125                              sectorname => '_default' });
 126 }
 127
 128 =item tower_sector
 129
 130 Returns the sectors of this tower, as FS::tower_sector objects (see
 131 L<FS::tower_sector>), except for the default sector.
 132
 133 =cut
 134
 135 sub tower_sector {
 136   my $self = shift;
 137   qsearch({
 138     'table'    => 'tower_sector',
 139     'hashref'  => { 'towernum'    => $self->towernum,
 140                     'sectorname'  => { op => '!=', value => '_default' },
 141                   },
 142     'order_by' => 'ORDER BY sectorname',
 143   });
 144 }
 145
 146 =item process_o2m
 147
 148 Wrapper for the default method (see L<FS::o2m_Common>) to manage the
 149 default sector.
 150
 151 =cut
 152
 153 sub process_o2m {
 154   my $self = shift;
 155   my %opt = @_;
 156   my $params = $opt{params};
 157
 158   # Adjust to make sure our default sector is in the list.
 159   my $default_sector = $self->default_sector
 160     or warn "creating default sector for tower ".$self->towernum."\n";
 161   my $idx = max(0, map { $_ =~ /^sectornum(\d+)$/ ? $1 : 0 } keys(%$params));
 162   $idx++; # append to the param list
 163   my $prefix = "sectornum$idx";
 164   # empty sectornum will create the default sector if it doesn't exist yet
 165   $params->{$prefix} = $default_sector ? $default_sector->sectornum : '';
 166   $params->{$prefix.'_sectorname'} = '_default';
 167   $params->{$prefix.'_ip_addr'} = $params->{'default_ip_addr'} || '';
 168
 169   $self->SUPER::process_o2m(%opt);
 170 }
 171
 172 sub _upgrade_data {
 173   # Create default sectors for any tower that doesn't have one.
 174   # Shouldn't do any harm if they're missing, but just for completeness.
 175   my $class = shift;
 176   foreach my $tower (qsearch('tower',{})) {
 177     next if $tower->default_sector;
 178     my $sector = FS::tower_sector->new({
 179         towernum => $tower->towernum,
 180         sectorname => '_default',
 181         ip_addr => '',
 182     });
 183     my $error = $sector->insert;
 184     die "error creating default sector: $error\n" if $error;
 185   }
 186   '';
 187 }
 188
 189 =back
 190
 191 =head1 BUGS
 192
 193 =head1 SEE ALSO
 194
 195 L<FS::tower_sector>, L<FS::svc_broadband>, L<FS::Record>
 196
 197 =cut
 198
 199 1;
 200