FS/FS/tax_rate_location.pm

   1 package FS::tax_rate_location;
   2
   3 use strict;
   4 use base qw( FS::Record );
   5 use FS::Record qw( qsearch qsearchs dbh );
   6 use FS::Misc qw( csv_from_fixed );
   7
   8 =head1 NAME
   9
  10 FS::tax_rate_location - Object methods for tax_rate_location records
  11
  12 =head1 SYNOPSIS
  13
  14   use FS::tax_rate_location;
  15
  16   $record = new FS::tax_rate_location \%hash;
  17   $record = new FS::tax_rate_location { 'column' => 'value' };
  18
  19   $error = $record->insert;
  20
  21   $error = $new_record->replace($old_record);
  22
  23   $error = $record->delete;
  24
  25   $error = $record->check;
  26
  27 =head1 DESCRIPTION
  28
  29 An FS::tax_rate_location object represents an example.  FS::tax_rate_location inherits from
  30 FS::Record.  The following fields are currently supported:
  31
  32 =over 4
  33
  34 =item taxratelocationnum
  35
  36 Primary key (assigned automatically for new tax_rate_locations)
  37
  38 =item data_vendor
  39
  40 The tax data vendor
  41
  42 =item geocode
  43
  44 A unique geographic location code provided by the data vendor
  45
  46 =item city
  47
  48 City
  49
  50 =item county
  51
  52 County
  53
  54 =item state
  55
  56 State
  57
  58 =item disabled
  59
  60 If 'Y' this record is no longer active.
  61
  62
  63 =back
  64
  65 =head1 METHODS
  66
  67 =over 4
  68
  69 =item new HASHREF
  70
  71 Creates a new tax rate location.  To add the record to the database, see
  72  L<"insert">.
  73
  74 Note that this stores the hash reference, not a distinct copy of the hash it
  75 points to.  You can ask the object for a copy with the I<hash> method.
  76
  77 =cut
  78
  79 sub table { 'tax_rate_location'; }
  80
  81 =item insert
  82
  83 Adds this record to the database.  If there is an error, returns the error,
  84 otherwise returns false.
  85
  86 =cut
  87
  88 =item delete
  89
  90 Delete this record from the database.
  91
  92 =cut
  93
  94 sub delete {
  95   return "Can't delete tax rate locations.  Set disable to 'Y' instead.";
  96   # check that it is unused in any cust_bill_pkg_tax_location records instead?
  97 }
  98
  99 =item replace OLD_RECORD
 100
 101 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 102 returns the error, otherwise returns false.
 103
 104 =cut
 105
 106 =item check
 107
 108 Checks all fields to make sure this is a valid tax rate location.  If there is
 109 an error, returns the error, otherwise returns false.  Called by the insert
 110 and replace methods.
 111
 112 =cut
 113
 114 sub check {
 115   my $self = shift;
 116
 117   my $error =
 118     $self->ut_numbern('taxratelocationnum')
 119     || $self->ut_textn('data_vendor')
 120     || $self->ut_alpha('geocode')
 121     || $self->ut_textn('city')
 122     || $self->ut_textn('county')
 123     || $self->ut_textn('state')
 124     || $self->ut_enum('disabled', [ '', 'Y' ])
 125   ;
 126   return $error if $error;
 127
 128   my $t = qsearchs( 'tax_rate_location',
 129                     { map { $_ => $self->$_ } qw( data_vendor geocode ) },
 130                   );
 131
 132   return "geocode already in use for this vendor"
 133     if ( $t && $t->taxratelocationnum != $self->taxratelocationnum );
 134
 135   return "may only be disabled"
 136     if ( $t && scalar( grep { $t->$_ ne $self->$_ }
 137                        grep { $_ ne 'disabled' }
 138                        $self->fields
 139                      )
 140        );
 141
 142   $self->SUPER::check;
 143 }
 144
 145 =back
 146
 147 =head1 SUBROUTINES
 148
 149 =over 4
 150
 151 =item batch_import
 152
 153 =cut
 154
 155 sub batch_import {
 156   my ($param, $job) = @_;
 157
 158   my $fh = $param->{filehandle};
 159   my $format = $param->{'format'};
 160
 161   my %insert = ();
 162   my %delete = ();
 163
 164   my @fields;
 165   my $hook;
 166
 167   my @column_lengths = ();
 168   my @column_callbacks = ();
 169   if ( $format eq 'cch-fixed' || $format eq 'cch-fixed-update' ) {
 170     $format =~ s/-fixed//;
 171     my $trim = sub { my $r = shift; $r =~ s/^\s*//; $r =~ s/\s*$//; $r };
 172     push @column_lengths, qw( 28 25 2 10 );
 173     push @column_lengths, 1 if $format eq 'cch-update';
 174     push @column_callbacks, $trim foreach (@column_lengths);
 175   }
 176
 177   my $line;
 178   my ( $count, $last, $min_sec ) = (0, time, 5); #progressbar
 179   if ( $job || scalar(@column_callbacks) ) {
 180     my $error =
 181       csv_from_fixed(\$fh, \$count, \@column_lengths, \@column_callbacks);
 182     return $error if $error;
 183   }
 184
 185   if ( $format eq 'cch' || $format eq 'cch-update' ) {
 186     @fields = qw( city county state geocode );
 187     push @fields, 'actionflag' if $format eq 'cch-update';
 188
 189     $hook = sub {
 190       my $hash = shift;
 191
 192       $hash->{'data_vendor'} ='cch';
 193
 194       if (exists($hash->{'actionflag'}) && $hash->{'actionflag'} eq 'D') {
 195         delete($hash->{actionflag});
 196
 197         $hash->{deleted} = '';
 198         my $tax_rate_location = qsearchs('tax_rate_location', $hash);
 199         return "Can't find tax_rate_location to delete: ".
 200                join(" ", map { "$_ => ". $hash->{$_} } @fields)
 201           unless $tax_rate_location;
 202
 203         $tax_rate_location->disabled('Y');
 204         my $error = $tax_rate_location->replace;
 205         return $error if $error;
 206
 207         delete($hash->{$_}) foreach (keys %$hash);
 208       }
 209
 210       delete($hash->{'actionflag'});
 211
 212       '';
 213
 214     };
 215
 216   } elsif ( $format eq 'extended' ) {
 217     die "unimplemented\n";
 218     @fields = qw( );
 219     $hook = sub {};
 220   } else {
 221     die "unknown format $format";
 222   }
 223
 224   eval "use Text::CSV_XS;";
 225   die $@ if $@;
 226
 227   my $csv = new Text::CSV_XS;
 228
 229   my $imported = 0;
 230
 231   local $SIG{HUP} = 'IGNORE';
 232   local $SIG{INT} = 'IGNORE';
 233   local $SIG{QUIT} = 'IGNORE';
 234   local $SIG{TERM} = 'IGNORE';
 235   local $SIG{TSTP} = 'IGNORE';
 236   local $SIG{PIPE} = 'IGNORE';
 237
 238   my $oldAutoCommit = $FS::UID::AutoCommit;
 239   local $FS::UID::AutoCommit = 0;
 240   my $dbh = dbh;
 241
 242   while ( defined($line=<$fh>) ) {
 243     $csv->parse($line) or do {
 244       $dbh->rollback if $oldAutoCommit;
 245       return "can't parse: ". $csv->error_input();
 246     };
 247
 248     if ( $job ) {  # progress bar
 249       if ( time - $min_sec > $last ) {
 250         my $error = $job->update_statustext(
 251           int( 100 * $imported / $count )
 252         );
 253         die $error if $error;
 254         $last = time;
 255       }
 256     }
 257
 258     my @columns = $csv->fields();
 259
 260     my %tax_rate_location = ();
 261     foreach my $field ( @fields ) {
 262       $tax_rate_location{$field} = shift @columns;
 263     }
 264     if ( scalar( @columns ) ) {
 265       $dbh->rollback if $oldAutoCommit;
 266       return "Unexpected trailing columns in line (wrong format?): $line";
 267     }
 268
 269     my $error = &{$hook}(\%tax_rate_location);
 270     if ( $error ) {
 271       $dbh->rollback if $oldAutoCommit;
 272       return $error;
 273     }
 274
 275     if (scalar(keys %tax_rate_location)) { #inserts only
 276
 277       my $tax_rate_location = new FS::tax_rate_location( \%tax_rate_location );
 278       $error = $tax_rate_location->insert;
 279
 280       if ( $error ) {
 281         $dbh->rollback if $oldAutoCommit;
 282         return "can't insert tax_rate for $line: $error";
 283       }
 284
 285     }
 286
 287     $imported++;
 288
 289   }
 290
 291   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 292
 293   return "Empty file!" unless ($imported || $format eq 'cch-update');
 294
 295   ''; #no error
 296
 297 }
 298
 299 =head1 BUGS
 300
 301 Currently somewhat specific to CCH supplied data.
 302
 303 =head1 SEE ALSO
 304
 305 L<FS::Record>, schema.html from the base documentation.
 306
 307 =cut
 308
 309 1;
 310