FS/FS/svc_phone.pm

   1 package FS::svc_phone;
   2 use base qw( FS::svc_Domain_Mixin FS::svc_PBX_Mixin
   3              FS::location_Mixin
   4              FS::svc_Common
   5            );
   6
   7 use strict;
   8 use vars qw( $DEBUG $me @pw_set $conf $phone_name_max
   9              $passwordmin $passwordmax
  10            );
  11 use Data::Dumper;
  12 use Scalar::Util qw( blessed );
  13 use List::Util qw( min );
  14 use Tie::IxHash;
  15 use FS::Conf;
  16 use FS::Record qw( qsearch qsearchs dbh );
  17 use FS::PagedSearch qw( psearch );
  18 use FS::Msgcat qw(gettext);
  19 use FS::part_svc;
  20 use FS::svc_pbx;
  21 use FS::svc_domain;
  22 use FS::cust_location;
  23 use FS::phone_avail;
  24
  25 $me = '[' . __PACKAGE__ . ']';
  26 $DEBUG = 0;
  27
  28 #avoid l 1 and o O 0
  29 @pw_set = ( 'a'..'k', 'm','n', 'p-z', 'A'..'N', 'P'..'Z' , '2'..'9' );
  30
  31 #ask FS::UID to run this stuff for us later
  32 FS::UID->install_callback( sub {
  33   $conf = new FS::Conf;
  34   $phone_name_max = $conf->config('svc_phone-phone_name-max_length');
  35   $passwordmin = $conf->config('sip_passwordmin') || 0;
  36   $passwordmax = $conf->config('sip_passwordmax') || 80;
  37 }
  38 );
  39
  40 =head1 NAME
  41
  42 FS::svc_phone - Object methods for svc_phone records
  43
  44 =head1 SYNOPSIS
  45
  46   use FS::svc_phone;
  47
  48   $record = new FS::svc_phone \%hash;
  49   $record = new FS::svc_phone { 'column' => 'value' };
  50
  51   $error = $record->insert;
  52
  53   $error = $new_record->replace($old_record);
  54
  55   $error = $record->delete;
  56
  57   $error = $record->check;
  58
  59   $error = $record->suspend;
  60
  61   $error = $record->unsuspend;
  62
  63   $error = $record->cancel;
  64
  65 =head1 DESCRIPTION
  66
  67 An FS::svc_phone object represents a phone number.  FS::svc_phone inherits
  68 from FS::Record.  The following fields are currently supported:
  69
  70 =over 4
  71
  72 =item svcnum
  73
  74 primary key
  75
  76 =item countrycode
  77
  78 =item phonenum
  79
  80 =item sim_imsi
  81
  82 SIM IMSI (http://en.wikipedia.org/wiki/International_mobile_subscriber_identity)
  83
  84 =item sip_password
  85
  86 =item pin
  87
  88 Voicemail PIN
  89
  90 =item phone_name
  91
  92 =item pbxsvc
  93
  94 Optional svcnum from svc_pbx
  95
  96 =item forwarddst
  97
  98 Forwarding destination
  99
 100 =item email
 101
 102 Email address for virtual fax (fax-to-email) services
 103
 104 =item lnp_status
 105
 106 LNP Status (can be null, native, portedin, portingin, portin-reject,
 107 portingout, portout-reject)
 108
 109 =item portable
 110
 111 =item lrn
 112
 113 =item lnp_desired_due_date
 114
 115 =item lnp_due_date
 116
 117 =item lnp_other_provider
 118
 119 If porting the number in or out, name of the losing or winning provider,
 120 respectively.
 121
 122 =item lnp_other_provider_account
 123
 124 Account number of other provider. See lnp_other_provider.
 125
 126 =item lnp_reject_reason
 127
 128 See lnp_status. If lnp_status is portin-reject or portout-reject, this is an
 129 optional reject reason.
 130
 131 =item e911_class
 132
 133 Class of Service for E911 service (per the NENA 2.1 standard).
 134
 135 =item e911_type
 136
 137 Type of Service for E911 service.
 138
 139 =item circuit_svcnum
 140
 141 The L<FS::svc_circuit> record for the physical circuit that transports this
 142 phone line.
 143
 144 =item sip_server
 145
 146 The hostname of the SIP server that this phone number is routed to.
 147
 148 =back
 149
 150 =head1 METHODS
 151
 152 =over 4
 153
 154 =item new HASHREF
 155
 156 Creates a new phone number.  To add the number to the database, see L<"insert">.
 157
 158 Note that this stores the hash reference, not a distinct copy of the hash it
 159 points to.  You can ask the object for a copy with the I<hash> method.
 160
 161 =cut
 162
 163 # the new method can be inherited from FS::Record, if a table method is defined
 164 #
 165 sub table_info {
 166  my %dis2 = ( disable_inventory=>1, disable_select=>1 );
 167   {
 168     'name' => 'Phone number',
 169     'sorts' => 'phonenum',
 170     'display_weight' => 60,
 171     'cancel_weight'  => 80,
 172     'fields' => {
 173         'svcnum'       => 'Service',
 174         'countrycode'  => { label => 'Country code',
 175                             type  => 'text',
 176                             disable_inventory => 1,
 177                             disable_select => 1,
 178                           },
 179         'phonenum'     => 'Phone number',
 180         'sim_imsi'     => 'IMSI', #http://en.wikipedia.org/wiki/International_mobile_subscriber_identity
 181         'pin'          => { label => 'Voicemail PIN', #'Personal Identification Number',
 182                             type  => 'text',
 183                             disable_inventory => 1,
 184                             disable_select => 1,
 185                           },
 186         'sip_password' => 'SIP password',
 187         'phone_name'   => 'Name',
 188         'pbxsvc'       => { label => 'PBX',
 189                             type  => 'select-svc_pbx.html',
 190                             disable_inventory => 1,
 191                             disable_select => 1, #UI wonky, pry works otherwise
 192                           },
 193         'domsvc'    => {
 194                          label     => 'Domain',
 195                          type      => 'select',
 196                          select_table => 'svc_domain',
 197                          select_key   => 'svcnum',
 198                          select_label => 'domain',
 199                          select_allow_empty => 1,
 200                          disable_inventory => 1,
 201                        },
 202         'circuit_svcnum'   => { label             => 'Circuit',
 203                                 type              => 'select',
 204                                 select_table      => 'svc_domain',
 205                                 select_key        => 'svcnum',
 206                                 select_label      => 'circuit_label',
 207                                 disable_inventory => 1,
 208                               },
 209
 210         'sms_carrierid'    => { label             => 'SMS Carrier',
 211                                 type              => 'select',
 212                                 select_table      => 'cdr_carrier',
 213                                 select_key        => 'carrierid',
 214                                 select_label      => 'carriername',
 215                                 disable_inventory => 1,
 216                               },
 217         'sms_account'      => { label => 'SMS Carrier Account', },
 218         'max_simultaneous' => { label=>'Maximum number of simultaneous users' },
 219         'locationnum' => {
 220                            label => 'E911 location',
 221                            disable_inventory => 1,
 222                            disable_select    => 1,
 223                          },
 224         'forwarddst' => {       label => 'Forward Destination',
 225                                 %dis2,
 226                         },
 227         'email' => {            label => 'Email',
 228                                 %dis2,
 229                     },
 230         'lnp_status' => {       label => 'LNP Status',
 231                                 type => 'select-lnp_status.html',
 232                                 %dis2,
 233                         },
 234         'lnp_reject_reason' => {
 235                                 label => 'LNP Reject Reason',
 236                                 %dis2,
 237                         },
 238         'portable' =>   {       label => 'Portable?', %dis2, },
 239         'lrn'   =>      {       label => 'LRN',
 240                                 disable_inventory => 1,
 241                         },
 242         'lnp_desired_due_date' =>
 243                         { label => 'LNP Desired Due Date', %dis2 },
 244         'lnp_due_date' =>
 245                         { label => 'LNP Due Date', %dis2 },
 246         'lnp_other_provider' =>
 247                         {       label => 'LNP Other Provider',
 248                                 disable_inventory => 1,
 249                         },
 250         'lnp_other_provider_account' =>
 251                         {       label => 'LNP Other Provider Account #',
 252                                 %dis2
 253                         },
 254         'e911_class' => {
 255                                 label => 'E911 Service Class',
 256                                 type  => 'select-e911_class',
 257                                 disable_inventory => 1,
 258                                 multiple => 1,
 259                         },
 260         'e911_type' => {
 261                                 label => 'E911 Service Type',
 262                                 type  => 'select-e911_type',
 263                                 disable_inventory => 1,
 264                                 multiple => 1,
 265                         },
 266         'sip_server'  => {
 267                                 label => 'SIP Host',
 268                                 %dis2,
 269                          },
 270     },
 271   };
 272 }
 273
 274 sub table { 'svc_phone'; }
 275
 276 sub table_dupcheck_fields { ( 'countrycode', 'phonenum' ); }
 277
 278 =item search_sql STRING
 279
 280 Class method which returns an SQL fragment to search for the given string.
 281
 282 =cut
 283
 284 sub search_sql {
 285   my( $class, $string ) = @_;
 286
 287   #my $conf = new FS::Conf;
 288
 289   if ( $conf->exists('svc_phone-allow_alpha_phonenum') ) {
 290     $string =~ s/\W//g;
 291   } else {
 292     $string =~ s/\D//g;
 293   }
 294
 295   my $ccode = (    $conf->exists('default_phone_countrycode')
 296                 && $conf->config('default_phone_countrycode')
 297               )
 298                 ? $conf->config('default_phone_countrycode')
 299                 : '1';
 300
 301   $string =~ s/^$ccode//;
 302
 303   $class->search_sql_field('phonenum', $string );
 304 }
 305
 306 =item label
 307
 308 Returns the phone number.
 309
 310 =cut
 311
 312 sub label {
 313   my $self = shift;
 314   my $phonenum = $self->phonenum; #XXX format it better
 315   my $label = $phonenum;
 316   $label .= '@'.$self->domain if $self->domsvc;
 317   $label .= ' ('.$self->phone_name.')' if $self->phone_name;
 318   $label;
 319 }
 320
 321 =item insert
 322
 323 Adds this phone number to the database.  If there is an error, returns the
 324 error, otherwise returns false.
 325
 326 =cut
 327
 328 sub insert {
 329   my $self = shift;
 330   my %options = @_;
 331
 332   if ( $DEBUG ) {
 333     warn "[$me] insert called on $self: ". Dumper($self).
 334          "\nwith options: ". Dumper(%options);
 335   }
 336
 337   local $SIG{HUP} = 'IGNORE';
 338   local $SIG{INT} = 'IGNORE';
 339   local $SIG{QUIT} = 'IGNORE';
 340   local $SIG{TERM} = 'IGNORE';
 341   local $SIG{TSTP} = 'IGNORE';
 342   local $SIG{PIPE} = 'IGNORE';
 343
 344   my $oldAutoCommit = $FS::UID::AutoCommit;
 345   local $FS::UID::AutoCommit = 0;
 346   my $dbh = dbh;
 347
 348   #false laziness w/cust_pkg.pm... move this to location_Mixin?  that would
 349   #make it more of a base class than a mixin... :)
 350   if ( $options{'cust_location'} ) {
 351     my $error = $options{'cust_location'}->find_or_insert;
 352     if ( $error ) {
 353       $dbh->rollback if $oldAutoCommit;
 354       return "inserting cust_location (transaction rolled back): $error";
 355     }
 356     $self->locationnum( $options{'cust_location'}->locationnum );
 357   }
 358   #what about on-the-fly edits?  if the ui supports it?
 359
 360   my $error = $self->SUPER::insert(%options);
 361   if ( $error ) {
 362     $dbh->rollback if $oldAutoCommit;
 363     return $error;
 364   }
 365
 366   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 367   '';
 368
 369 }
 370
 371 =item delete
 372
 373 Delete this record from the database.
 374
 375 =cut
 376
 377 sub delete {
 378   my $self = shift;
 379
 380   local $SIG{HUP} = 'IGNORE';
 381   local $SIG{INT} = 'IGNORE';
 382   local $SIG{QUIT} = 'IGNORE';
 383   local $SIG{TERM} = 'IGNORE';
 384   local $SIG{TSTP} = 'IGNORE';
 385   local $SIG{PIPE} = 'IGNORE';
 386
 387   my $oldAutoCommit = $FS::UID::AutoCommit;
 388   local $FS::UID::AutoCommit = 0;
 389   my $dbh = dbh;
 390
 391   foreach my $phone_device ( $self->phone_device ) {
 392     my $error = $phone_device->delete;
 393     if ( $error ) {
 394       $dbh->rollback if $oldAutoCommit;
 395       return $error;
 396     }
 397   }
 398
 399   my @phone_avail = qsearch('phone_avail', { 'svcnum' => $self->svcnum } );
 400   foreach my $phone_avail ( @phone_avail ) {
 401     $phone_avail->svcnum('');
 402     my $error = $phone_avail->replace;
 403     if ( $error ) {
 404       $dbh->rollback if $oldAutoCommit;
 405       return $error;
 406     }
 407   }
 408
 409   my $error = $self->SUPER::delete;
 410   if ( $error ) {
 411     $dbh->rollback if $oldAutoCommit;
 412     return $error;
 413   }
 414
 415   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 416   '';
 417
 418 }
 419
 420 =item replace OLD_RECORD
 421
 422 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 423 returns the error, otherwise returns false.
 424
 425 =cut
 426
 427 sub replace {
 428   my $new = shift;
 429
 430   my $old = ( blessed($_[0]) && $_[0]->isa('FS::Record') )
 431               ? shift
 432               : $new->replace_old;
 433
 434   my %options = @_;
 435
 436   if ( $DEBUG ) {
 437     warn "[$me] replacing $old with $new\n".
 438          "\nwith options: ". Dumper(%options);
 439   }
 440
 441   local $SIG{HUP} = 'IGNORE';
 442   local $SIG{INT} = 'IGNORE';
 443   local $SIG{QUIT} = 'IGNORE';
 444   local $SIG{TERM} = 'IGNORE';
 445   local $SIG{TSTP} = 'IGNORE';
 446   local $SIG{PIPE} = 'IGNORE';
 447
 448   my $oldAutoCommit = $FS::UID::AutoCommit;
 449   local $FS::UID::AutoCommit = 0;
 450   my $dbh = dbh;
 451
 452   #false laziness w/cust_pkg.pm... move this to location_Mixin?  that would
 453   #make it more of a base class than a mixin... :)
 454   if ( $options{'cust_location'}
 455          && ( ! $new->locationnum || $new->locationnum == -1 ) ) {
 456     my $error = $options{'cust_location'}->insert;
 457     if ( $error ) {
 458       $dbh->rollback if $oldAutoCommit;
 459       return "inserting cust_location (transaction rolled back): $error";
 460     }
 461     $new->locationnum( $options{'cust_location'}->locationnum );
 462   }
 463   #what about on-the-fly edits?  if the ui supports it?
 464
 465   # LNP data validation
 466  return 'Invalid LNP status' # if someone does really stupid stuff
 467     if (  ($old->lnp_status eq 'portingout' && $new->lnp_status eq 'portingin')
 468         || ($old->lnp_status eq 'portout-reject' && $new->lnp_status eq 'portingin')
 469         || ($old->lnp_status eq 'portin-reject' && $new->lnp_status eq 'portingout')
 470         || ($old->lnp_status eq 'portingin' && $new->lnp_status eq 'native')
 471         || ($old->lnp_status eq 'portin-reject' && $new->lnp_status eq 'native')
 472         || ($old->lnp_status eq 'portingin' && $new->lnp_status eq 'portingout')
 473         || ($old->lnp_status eq 'portingout' && $new->lnp_status eq 'portin-reject')
 474         );
 475
 476   my $error = $new->SUPER::replace($old, %options);
 477
 478   # if this changed the e911 location, notify exports
 479   if ($new->locationnum ne $old->locationnum) {
 480     my $new_location = $new->cust_location_or_main;
 481     my $old_location = $new->cust_location_or_main;
 482     $error ||= $new->export('relocate', $new_location, $old_location);
 483   }
 484
 485   if ( $error ) {
 486     $dbh->rollback if $oldAutoCommit;
 487     return $error if $error;
 488   }
 489
 490
 491   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 492   ''; #no error
 493 }
 494
 495 =item suspend
 496
 497 Called by the suspend method of FS::cust_pkg (see L<FS::cust_pkg>).
 498
 499 =item unsuspend
 500
 501 Called by the unsuspend method of FS::cust_pkg (see L<FS::cust_pkg>).
 502
 503 =item cancel
 504
 505 Called by the cancel method of FS::cust_pkg (see L<FS::cust_pkg>).
 506
 507 =item check
 508
 509 Checks all fields to make sure this is a valid phone number.  If there is
 510 an error, returns the error, otherwise returns false.  Called by the insert
 511 and replace methods.
 512
 513 =cut
 514
 515 # the check method should currently be supplied - FS::Record contains some
 516 # data checking routines
 517
 518 sub check {
 519   my $self = shift;
 520
 521   #my $conf = new FS::Conf;
 522
 523   my $x = $self->setfixed;
 524   return $x unless ref($x);
 525   my $part_svc = $x;
 526
 527   my $phonenum = $self->phonenum;
 528   my $phonenum_check_method;
 529   if ( $conf->exists('svc_phone-allow_alpha_phonenum') ) {
 530     $phonenum =~ s/\W//g;
 531     $phonenum_check_method = 'ut_alpha';
 532   } else {
 533     $phonenum =~ s/\D//g;
 534     $phonenum_check_method = 'ut_number';
 535   }
 536   $self->phonenum($phonenum);
 537
 538   $self->locationnum('') if !$self->locationnum || $self->locationnum == -1;
 539
 540   my $error =
 541     $self->ut_numbern('svcnum')
 542     || $self->ut_numbern('countrycode')
 543     || $self->$phonenum_check_method('phonenum')
 544     || $self->ut_numbern('sim_imsi')
 545     || $self->ut_anything('sip_password')
 546     || $self->ut_numbern('pin')
 547     || $self->ut_textn('phone_name')
 548     || $self->ut_foreign_keyn('pbxsvc', 'svc_pbx',    'svcnum' )
 549     || $self->ut_foreign_keyn('domsvc', 'svc_domain', 'svcnum' )
 550     || $self->ut_foreign_keyn('sms_carrierid', 'cdr_carrier', 'carrierid' )
 551     || $self->ut_alphan('sms_account')
 552     || $self->ut_numbern('max_simultaneous')
 553     || $self->ut_foreign_keyn('locationnum', 'cust_location', 'locationnum')
 554     || $self->ut_numbern('forwarddst')
 555     || $self->ut_textn('email')
 556     || $self->ut_numbern('lrn')
 557     || $self->ut_numbern('lnp_desired_due_date')
 558     || $self->ut_numbern('lnp_due_date')
 559     || $self->ut_textn('lnp_other_provider')
 560     || $self->ut_textn('lnp_other_provider_account')
 561     || $self->ut_enumn('lnp_status', ['','portingin','portingout','portedin',
 562                                 'native', 'portin-reject', 'portout-reject'])
 563     || $self->ut_enumn('portable', ['','Y'])
 564     || $self->ut_textn('lnp_reject_reason')
 565     || $self->ut_domainn('sip_server')
 566   ;
 567   return $error if $error;
 568
 569   return 'Illegal IMSI (not 14-15 digits)' #shorter?
 570     if length($self->sim_imsi)
 571     && ( length($self->sim_imsi) < 14 || length($self->sim_imsi) > 15 );
 572
 573     # LNP data validation
 574     return 'Cannot set LNP fields: no LNP in progress'
 575         if ( ($self->lnp_desired_due_date || $self->lnp_due_date
 576             || $self->lnp_other_provider || $self->lnp_other_provider_account
 577             || $self->lnp_reject_reason)
 578             && (!$self->lnp_status || $self->lnp_status eq 'native') );
 579     return 'Cannot set LNP reject reason: no LNP in progress or status is not reject'
 580         if ($self->lnp_reject_reason && (!$self->lnp_status
 581                             || $self->lnp_status !~ /^port(in|out)-reject$/) );
 582     return 'Cannot port-out a non-portable number'
 583         if (!$self->portable && $self->lnp_status eq 'portingout');
 584
 585
 586   return 'Name ('. $self->phone_name.
 587          ") is longer than $phone_name_max characters"
 588     if $phone_name_max && length($self->phone_name) > $phone_name_max;
 589
 590   $self->countrycode(1) unless $self->countrycode;
 591
 592   unless ( length($self->pin) ) {
 593     my $random_pin = $conf->config('svc_phone-random_pin');
 594     if ( defined($random_pin) && $random_pin =~ /^\d+$/ ) {
 595       $self->pin(
 596         join('', map int(rand(10)), 0..($random_pin-1))
 597       );
 598     }
 599   }
 600
 601   if ( length($self->sip_password) ) {
 602
 603     return "SIP password must be longer than $passwordmin characters"
 604       if length($self->sip_password) < $passwordmin;
 605     return "SIP password must be shorter than $passwordmax characters"
 606       if length($self->sip_password) > $passwordmax;
 607
 608   } elsif ( $part_svc->part_svc_column('sip_password')->columnflag ne 'F' ) {
 609
 610     # option for this?
 611     $self->sip_password(
 612       join('', map $pw_set[ int(rand $#pw_set) ], (1..min($passwordmax,16)) )
 613     );
 614
 615   }
 616
 617   if ($self->e911_class and !exists(e911_classes()->{$self->e911_class})) {
 618     return "undefined e911 class '".$self->e911_class."'";
 619   }
 620   if ($self->e911_type and !exists(e911_types()->{$self->e911_type})) {
 621     return "undefined e911 type '".$self->e911_type."'";
 622   }
 623
 624   $self->SUPER::check;
 625 }
 626
 627 =item _check duplicate
 628
 629 Internal method to check for duplicate phone numers.
 630
 631 =cut
 632
 633 #false laziness w/svc_acct.pm's _check_duplicate.
 634 sub _check_duplicate {
 635   my $self = shift;
 636
 637   my $global_unique = $conf->config('global_unique-phonenum') || 'none';
 638   return '' if $global_unique eq 'disabled';
 639
 640   $self->lock_table;
 641
 642   my @dup_ccphonenum =
 643     grep { !$self->svcnum || $_->svcnum != $self->svcnum }
 644     qsearch( 'svc_phone', {
 645       'countrycode' => $self->countrycode,
 646       'phonenum'    => $self->phonenum,
 647     });
 648
 649   return gettext('phonenum_in_use')
 650     if $global_unique eq 'countrycode+phonenum' && @dup_ccphonenum;
 651
 652   my $part_svc = qsearchs('part_svc', { 'svcpart' => $self->svcpart } );
 653   unless ( $part_svc ) {
 654     return 'unknown svcpart '. $self->svcpart;
 655   }
 656
 657   if ( @dup_ccphonenum ) {
 658
 659     my $exports = FS::part_export::export_info('svc_phone');
 660     my %conflict_ccphonenum_svcpart = ( $self->svcpart => 'SELF', );
 661
 662     foreach my $part_export ( $part_svc->part_export ) {
 663
 664       #this will catch to the same exact export
 665       my @svcparts = map { $_->svcpart } $part_export->export_svc;
 666
 667       $conflict_ccphonenum_svcpart{$_} = $part_export->exportnum
 668         foreach @svcparts;
 669
 670     }
 671
 672     foreach my $dup_ccphonenum ( @dup_ccphonenum ) {
 673       my $dup_svcpart = $dup_ccphonenum->cust_svc->svcpart;
 674       if ( exists($conflict_ccphonenum_svcpart{$dup_svcpart}) ) {
 675         return "duplicate phone number ".
 676                $self->countrycode. ' '. $self->phonenum.
 677                ": conflicts with svcnum ". $dup_ccphonenum->svcnum.
 678                " via exportnum ". $conflict_ccphonenum_svcpart{$dup_svcpart};
 679       }
 680     }
 681
 682   }
 683
 684   return '';
 685
 686 }
 687
 688 =item check_pin
 689
 690 Checks the supplied PIN against the PIN in the database.  Returns true for a
 691 sucessful authentication, false if no match.
 692
 693 =cut
 694
 695 sub check_pin {
 696   my($self, $check_pin) = @_;
 697   length($self->pin) && $check_pin eq $self->pin;
 698 }
 699
 700 =item radius_reply
 701
 702 =cut
 703
 704 sub radius_reply {
 705   my $self = shift;
 706   #XXX Session-Timeout!  holy shit, need rlm_perl to ask for this in realtime
 707   ();
 708 }
 709
 710 =item radius_check
 711
 712 =cut
 713
 714 sub radius_check {
 715   my $self = shift;
 716   my %check = ();
 717
 718   #my $conf = new FS::Conf;
 719
 720   my $password;
 721   if ( $conf->config('svc_phone-radius-password') eq 'countrycode_phonenum' ) {
 722     $password = $self->countrycode. $self->phonenum;
 723   } else {
 724     $password = $conf->config('svc_phone-radius-default_password');
 725   }
 726   $check{'User-Password'} = $password;
 727
 728   %check;
 729 }
 730
 731 sub radius_groups {
 732   ();
 733 }
 734
 735 =item sms_cdr_carrier
 736
 737 Returns the L<FS::cdr_carrier> assigned as the SMS carrier for this phone.
 738
 739 =cut
 740
 741 sub sms_cdr_carrier {
 742   my $self = shift;
 743   return '' unless $self->sms_carrierid;
 744   qsearchs('cdr_carrier',  { 'carrierid' => $self->sms_carrierid } );
 745 }
 746
 747 =item sms_carriername
 748
 749 Returns the name of the SMS carrier, or an empty string if there isn't one.
 750
 751 =cut
 752
 753 sub sms_carriername {
 754   my $self = shift;
 755   my $cdr_carrier = $self->sms_cdr_carrier or return '';
 756   $cdr_carrier->carriername;
 757 }
 758
 759 =item svc_circuit
 760
 761 Returns the L<FS::svc_circuit> assigned as the trunk for this phone line.
 762
 763 =item circuit_label
 764
 765 Returns the label of the circuit (the part_svc label followed by the
 766 circuit ID), or an empty string if there isn't one.
 767
 768 =cut
 769
 770 sub svc_circuit {
 771   my $self = shift;
 772   my $svcnum = $self->get('circuit_svcnum') or return '';
 773   return FS::svc_circuit->by_key($svcnum);
 774 }
 775
 776 sub circuit_label {
 777   my $self = shift;
 778   my $svc_circuit = $self->svc_circuit or return '';
 779   return join(' ', $svc_circuit->part_svc->svc, $svc_circuit->circuit_id);
 780 }
 781
 782 =item phone_device
 783
 784 Returns any FS::phone_device records associated with this service.
 785
 786 =cut
 787
 788 #override location_Mixin version cause we want to try the cust_pkg location
 789 #in between us and cust_main
 790 # XXX what to do in the unlinked case???  return a pseudo-object that returns
 791 # empty fields?
 792 sub cust_location_or_main {
 793   my $self = shift;
 794   return $self->cust_location if $self->locationnum;
 795   my $cust_pkg = $self->cust_svc->cust_pkg;
 796   $cust_pkg ? $cust_pkg->cust_location_or_main : '';
 797 }
 798
 799 =item phone_name_or_cust
 800
 801 Returns the C<phone_name> field if it has a value, or the package contact
 802 name if there is one, or the customer contact name.
 803
 804 =cut
 805
 806 sub phone_name_or_cust {
 807   my $self = shift;
 808   if ( $self->phone_name ) {
 809     return $self->phone_name;
 810   }
 811   my $cust_pkg = $self->cust_svc->cust_pkg or return '';
 812   if ( $cust_pkg->contactnum ) {
 813     return $cust_pkg->contact->firstlast;
 814   } else {
 815     return $cust_pkg->cust_main->name_short;
 816   }
 817 }
 818
 819 =item psearch_cdrs OPTIONS
 820
 821 Returns a paged search (L<FS::PagedSearch>) for Call Detail Records
 822 associated with this service.  By default, "associated with" means that
 823 either the "src" or the "charged_party" field of the CDR matches the
 824 "phonenum" field of the service.  To access the CDRs themselves, call
 825 "->fetch" on the resulting object.
 826
 827 =over 2
 828
 829 Accepts the following options:
 830
 831 =item for_update => 1: SELECT the CDRs "FOR UPDATE".
 832
 833 =item status => "" (or "processing-tiered", "done"): Return only CDRs with that processing status.
 834
 835 =item inbound => 1: Return CDRs for inbound calls (that is, those that match
 836 on 'dst').  With "status", will filter on inbound processing status.
 837
 838 =item default_prefix => "XXX": Also accept the phone number of the service prepended
 839 with the chosen prefix.
 840
 841 =item begin, end: Start and end of a date range, as unix timestamp.
 842
 843 =item cdrtypenum: Only return CDRs with this type.
 844
 845 =item calltypenum: Only return CDRs with this call type.
 846
 847 =item disable_src => 1: Only match on 'charged_party', not 'src'.
 848
 849 =item disable_charged_party => 1: Only match on 'src', not 'charged_party'.
 850
 851 =item nonzero: Only return CDRs where duration > 0.
 852
 853 =item by_svcnum: not supported for svc_phone
 854
 855 =item billsec_sum: Instead of returning all of the CDRs, return a single
 856 record (as an L<FS::cdr> object) with the sum of the 'billsec' field over
 857 the entire result set.
 858
 859 =back
 860
 861 =cut
 862
 863 sub psearch_cdrs {
 864
 865   my($self, %options) = @_;
 866   my @fields;
 867   my %hash;
 868   my @where;
 869
 870   if ( $options{'inbound'} ) {
 871
 872     @fields = ( 'dst' );
 873     if ( exists($options{'status'}) ) {
 874       my $status = $options{'status'};
 875       if ( $status ) {
 876         push @where, 'EXISTS ( SELECT 1 FROM cdr_termination '.
 877           'WHERE cdr.acctid = cdr_termination.acctid '.
 878           "AND cdr_termination.status = '$status' ". #quoting kludge
 879           'AND cdr_termination.termpart = 1 )';
 880       } else {
 881         push @where, 'NOT EXISTS ( SELECT 1 FROM cdr_termination '.
 882           'WHERE cdr.acctid = cdr_termination.acctid '.
 883           'AND cdr_termination.termpart = 1 )';
 884       }
 885     }
 886
 887   } else {
 888
 889     push @fields, 'charged_party' unless $options{'disable_charged_party'};
 890     push @fields, 'src' unless $options{'disable_src'};
 891     $hash{'freesidestatus'} = $options{'status'}
 892       if exists($options{'status'});
 893   }
 894
 895   if ($options{'cdrtypenum'}) {
 896     $hash{'cdrtypenum'} = $options{'cdrtypenum'};
 897   }
 898   if ($options{'calltypenum'}) {
 899     $hash{'calltypenum'} = $options{'calltypenum'};
 900   }
 901
 902   my $for_update = $options{'for_update'} ? 'FOR UPDATE' : '';
 903
 904   my $number = $self->phonenum;
 905
 906   my $prefix = $options{'default_prefix'};
 907
 908   my @orwhere =  map " $_ = '$number'        ", @fields;
 909   push @orwhere, map " $_ = '$prefix$number' ", @fields
 910     if defined($prefix) && length($prefix);
 911   if ( $prefix && $prefix =~ /^\+(\d+)$/ ) {
 912     push @orwhere, map " $_ = '$1$number' ", @fields
 913   }
 914
 915   push @where, ' ( '. join(' OR ', @orwhere ). ' ) ';
 916
 917   if ( $options{'begin'} ) {
 918     push @where, 'startdate >= '. $options{'begin'};
 919   }
 920   if ( $options{'end'} ) {
 921     push @where, 'startdate < '.  $options{'end'};
 922   }
 923   if ( $options{'nonzero'} ) {
 924     push @where, 'duration > 0';
 925   }
 926
 927   my $extra_sql = ( keys(%hash) ? ' AND ' : ' WHERE ' ). join(' AND ', @where );
 928
 929   psearch( {
 930       'table'      => 'cdr',
 931       'hashref'    => \%hash,
 932       'extra_sql'  => $extra_sql,
 933       'order_by'   => $options{'billsec_sum'} ? '' : "ORDER BY startdate $for_update",
 934       'select'     => $options{'billsec_sum'} ? 'sum(billsec) as billsec_sum' : '*',
 935   } );
 936 }
 937
 938 =item get_cdrs (DEPRECATED)
 939
 940 Like psearch_cdrs, but returns all the L<FS::cdr> objects at once, in a
 941 single list.  Arguments are the same as for psearch_cdrs.  This can take
 942 an unreasonably large amount of memory and is best avoided.
 943
 944 =cut
 945
 946 sub get_cdrs {
 947   my $self = shift;
 948   my $psearch = $self->psearch_cdrs(@_);
 949   qsearch ( $psearch->{query} )
 950 }
 951
 952 =item sum_cdrs
 953
 954 Takes the same options as psearch_cdrs, but returns a single row containing
 955 "count" (the number of CDRs) and the sums of the following fields: duration,
 956 billsec, rated_price, rated_seconds, rated_minutes.
 957
 958 Note that if any calls are not rated, their rated_* fields will be null.
 959 If you want to use those fields, pass the 'status' option to limit to
 960 calls that have been rated.  This is intentional; please don't "fix" it.
 961
 962 =cut
 963
 964 sub sum_cdrs {
 965   my $self = shift;
 966   my $psearch = $self->psearch_cdrs(@_);
 967   $psearch->{query}->{'select'} = join(',',
 968     'COUNT(*) AS count',
 969     map { "SUM($_) AS $_" }
 970       qw(duration billsec rated_price rated_seconds rated_minutes)
 971   );
 972   # hack
 973   $psearch->{query}->{'extra_sql'} =~ s/ ORDER BY.*$//;
 974   qsearchs ( $psearch->{query} );
 975 }
 976
 977 =back
 978
 979 =head1 CLASS METHODS
 980
 981 =over 4
 982
 983 =item e911_classes
 984
 985 Returns a hashref of allowed values and descriptions for the C<e911_class>
 986 field.
 987
 988 =item e911_types
 989
 990 Returns a hashref of allowed values and descriptions for the C<e911_type>
 991 field.
 992
 993 =cut
 994
 995 sub e911_classes {
 996   tie my %x, 'Tie::IxHash', (
 997     1 => 'Residence',
 998     2 => 'Business',
 999     3 => 'Residence PBX',
1000     4 => 'Business PBX',
1001     5 => 'Centrex',
1002     6 => 'Coin 1 Way out',
1003     7 => 'Coin 2 Way',
1004     8 => 'Mobile',
1005     9 => 'Residence OPX',
1006     0 => 'Business OPX',
1007     A => 'Customer Operated Coin Telephone',
1008     #B => not available
1009     G => 'Wireless Phase I',
1010     H => 'Wireless Phase II',
1011     I => 'Wireless Phase II with Phase I information',
1012     V => 'VoIP Services Default',
1013     C => 'VoIP Residence',
1014     D => 'VoIP Business',
1015     E => 'VoIP Coin/Pay Phone',
1016     F => 'VoIP Wireless',
1017     J => 'VoIP Nomadic',
1018     K => 'VoIP Enterprise Services',
1019     T => 'Telematics',
1020   );
1021   \%x;
1022 }
1023
1024 sub e911_types {
1025   tie my %x, 'Tie::IxHash', (
1026     0 => 'Not FX nor Non-Published',
1027     1 => 'FX in 911 serving area',
1028     2 => 'FX outside 911 serving area',
1029     3 => 'Non-Published',
1030     4 => 'Non-Published FX in serving area',
1031     5 => 'Non-Published FX outside serving area',
1032     6 => 'Local Ported Number',
1033     7 => 'Interim Ported Number',
1034   );
1035   \%x;
1036 }
1037
1038 =back
1039
1040 =head1 BUGS
1041
1042 =head1 SEE ALSO
1043
1044 L<FS::svc_Common>, L<FS::Record>, L<FS::cust_svc>, L<FS::part_svc>,
1045 L<FS::cust_pkg>, schema.html from the base documentation.
1046
1047 =cut
1048
1049 1;
1050