FS/FS/quotation_pkg.pm

   1 package FS::quotation_pkg;
   2 use base qw( FS::TemplateItem_Mixin FS::Record );
   3
   4 use strict;
   5 use FS::Record qw( qsearchs dbh ); #qsearch
   6 use FS::part_pkg;
   7 use FS::quotation_pkg_discount; #so its loaded when TemplateItem_Mixin needs it
   8 use List::Util qw(sum);
   9
  10 =head1 NAME
  11
  12 FS::quotation_pkg - Object methods for quotation_pkg records
  13
  14 =head1 SYNOPSIS
  15
  16   use FS::quotation_pkg;
  17
  18   $record = new FS::quotation_pkg \%hash;
  19   $record = new FS::quotation_pkg { 'column' => 'value' };
  20
  21   $error = $record->insert;
  22
  23   $error = $new_record->replace($old_record);
  24
  25   $error = $record->delete;
  26
  27   $error = $record->check;
  28
  29 =head1 DESCRIPTION
  30
  31 An FS::quotation_pkg object represents a quotation package.
  32 FS::quotation_pkg inherits from FS::Record.  The following fields are currently
  33 supported:
  34
  35 =over 4
  36
  37 =item quotationpkgnum
  38
  39 primary key
  40
  41 =item pkgpart
  42
  43 pkgpart (L<FS::part_pkg>) of the package
  44
  45 =item locationnum
  46
  47 locationnum (L<FS::cust_location>) where the package will be in service
  48
  49 =item start_date
  50
  51 expected start date for the package, as a timestamp
  52
  53 =item contract_end
  54
  55 contract end date
  56
  57 =item quantity
  58
  59 quantity
  60
  61 =item waive_setup
  62
  63 'Y' to waive the setup fee
  64
  65 =item unitsetup
  66
  67 The amount per package that will be charged in setup/one-time fees.
  68
  69 =item unitrecur
  70
  71 The amount per package that will be charged per billing cycle.
  72
  73 =back
  74
  75 =head1 METHODS
  76
  77 =over 4
  78
  79 =item new HASHREF
  80
  81 Creates a new quotation package.  To add the quotation package to the database,
  82 see L<"insert">.
  83
  84 Note that this stores the hash reference, not a distinct copy of the hash it
  85 points to.  You can ask the object for a copy with the I<hash> method.
  86
  87 =cut
  88
  89 sub table { 'quotation_pkg'; }
  90
  91 sub display_table         { 'quotation_pkg'; }
  92
  93 #forget it, just overriding cust_bill_pkg_display entirely
  94 #sub display_table_orderby { 'quotationpkgnum'; } # something else?
  95 #                                                 #  (for invoice display order)
  96
  97 sub discount_table        { 'quotation_pkg_discount'; }
  98
  99 =item insert
 100
 101 Adds this record to the database.  If there is an error, returns the error,
 102 otherwise returns false.
 103
 104 =cut
 105
 106 sub insert {
 107   my ($self, %options) = @_;
 108
 109   my $dbh = dbh;
 110   my $oldAutoCommit = $FS::UID::AutoCommit;
 111   local $FS::UID::AutoCommit = 0;
 112
 113   my $error = $self->SUPER::insert;
 114
 115   if ( !$error and $self->discountnum ) {
 116     $error = $self->insert_discount;
 117     $error .= ' (setting discount)' if $error;
 118   }
 119
 120   # update $self and any discounts with their amounts
 121   if ( !$error ) {
 122     $error = $self->estimate;
 123     $error .= ' (calculating charges)' if $error;
 124   }
 125
 126   if ( $error ) {
 127     $dbh->rollback if $oldAutoCommit;
 128     return $error;
 129   } else {
 130     $dbh->commit if $oldAutoCommit;
 131     return '';
 132   }
 133 }
 134
 135 =item delete
 136
 137 Delete this record from the database.
 138
 139 =cut
 140
 141 sub delete {
 142   my $self = shift;
 143
 144   my $dbh = dbh;
 145   my $oldAutoCommit = $FS::UID::AutoCommit;
 146   local $FS::UID::AutoCommit = 0;
 147
 148   foreach ($self->quotation_pkg_discount) {
 149     my $error = $_->delete;
 150     if ( $error ) {
 151       $dbh->rollback if $oldAutoCommit;
 152       return $error . ' (deleting discount)';
 153     }
 154   }
 155
 156   my $error = $self->SUPER::delete;
 157   if ( $error ) {
 158     $dbh->rollback if $oldAutoCommit;
 159     return $error;
 160   } else {
 161     $dbh->commit if $oldAutoCommit;
 162     return '';
 163   }
 164
 165 }
 166
 167 =item replace OLD_RECORD
 168
 169 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 170 returns the error, otherwise returns false.
 171
 172 =item check
 173
 174 Checks all fields to make sure this is a valid quotation package.  If there is
 175 an error, returns the error, otherwise returns false.  Called by the insert
 176 and replace methods.
 177
 178 =cut
 179
 180 sub check {
 181   my $self = shift;
 182
 183   my $error =
 184     $self->ut_numbern('quotationpkgnum')
 185     || $self->ut_foreign_key(  'quotationnum', 'quotation',    'quotationnum' )
 186     || $self->ut_foreign_key(  'pkgpart',      'part_pkg',     'pkgpart'      )
 187     || $self->ut_foreign_keyn( 'locationnum', 'cust_location', 'locationnum'  )
 188     || $self->ut_numbern('start_date')
 189     || $self->ut_numbern('contract_end')
 190     || $self->ut_numbern('quantity')
 191     || $self->ut_moneyn('unitsetup')
 192     || $self->ut_moneyn('unitrecur')
 193     || $self->ut_enum('waive_setup', [ '', 'Y'] )
 194   ;
 195
 196   return $error if $error;
 197
 198   $self->SUPER::check;
 199 }
 200
 201 #it looks redundant with a v4.x+ auto-generated method, but need to override
 202 # FS::TemplateItem_Mixin's version
 203 sub part_pkg {
 204   my $self = shift;
 205   qsearchs('part_pkg', { 'pkgpart' => $self->pkgpart } );
 206 }
 207
 208 sub desc {
 209   my $self = shift;
 210   $self->part_pkg->pkg;
 211 }
 212
 213 =item estimate
 214
 215 Update the quotation_pkg record with the estimated setup and recurring
 216 charges for the package. Returns nothing on success, or an error message
 217 on failure.
 218
 219 =cut
 220
 221 sub estimate {
 222   my $self = shift;
 223   my $part_pkg = $self->part_pkg;
 224   my $quantity = $self->quantity || 1;
 225   my ($unitsetup, $unitrecur);
 226   # calculate base fees
 227   if ( $self->waive_setup eq 'Y' || $self->{'_NO_SETUP_KLUDGE'} ) {
 228     $unitsetup = '0.00';
 229   } else {
 230     $unitsetup = $part_pkg->base_setup;
 231   }
 232   if ( $self->{'_NO_RECUR_KLUDGE'} ) {
 233     $unitrecur = '0.00';
 234   } else {
 235     $unitrecur = $part_pkg->base_recur;
 236   }
 237
 238   #XXX add-on packages
 239
 240   $self->set('unitsetup', $unitsetup);
 241   $self->set('unitrecur', $unitrecur);
 242   my $error = $self->replace;
 243   return $error if $error;
 244
 245   # semi-duplicates calc_discount
 246   my $setup_discount = 0;
 247   my $recur_discount = 0;
 248
 249   my %setup_discounts; # quotationpkgdiscountnum => amount
 250   my %recur_discounts; # quotationpkgdiscountnum => amount
 251
 252   # XXX the order of applying discounts is ill-defined, which matters
 253   # if there are percentage and amount discounts on the same package.
 254   foreach my $pkg_discount ($self->quotation_pkg_discount) {
 255
 256     my $discount = $pkg_discount->discount;
 257     my $this_setup_discount = 0;
 258     my $this_recur_discount = 0;
 259
 260     if ( $discount->percent > 0 ) {
 261
 262       if ( $discount->setup ) {
 263         $this_setup_discount = ($discount->percent * $unitsetup / 100);
 264       }
 265       $this_recur_discount = ($discount->percent * $unitrecur / 100);
 266
 267     } elsif ( $discount->amount > 0 ) {
 268
 269       my $discount_left = $discount->amount;
 270       if ( $discount->setup ) {
 271         if ( $discount_left > $unitsetup - $setup_discount ) {
 272           # then discount the setup to zero
 273           $discount_left -= $unitsetup - $setup_discount;
 274           $this_setup_discount = $unitsetup - $setup_discount;
 275         } else {
 276           # not enough discount to fully cover the setup
 277           $this_setup_discount = $discount_left;
 278           $discount_left = 0;
 279         }
 280       }
 281       # same logic for recur
 282       if ( $discount_left > $unitrecur - $recur_discount ) {
 283         $this_recur_discount = $unitrecur - $recur_discount;
 284       } else {
 285         $this_recur_discount = $discount_left;
 286       }
 287
 288     }
 289
 290     # increment the total discountage
 291     $setup_discount += $this_setup_discount;
 292     $recur_discount += $this_recur_discount;
 293     # and update the pkg_discount object
 294     $pkg_discount->set('setup_amount', sprintf('%.2f', $setup_discount));
 295     $pkg_discount->set('recur_amount', sprintf('%.2f', $recur_discount));
 296     my $error = $pkg_discount->replace;
 297     return $error if $error;
 298   }
 299
 300   '';
 301 }
 302
 303 =item insert_discount
 304
 305 Associates this package with a discount (see L<FS::cust_pkg_discount>,
 306 possibly inserting a new discount on the fly (see L<FS::discount>). Properties
 307 of the discount will be taken from this object.
 308
 309 =cut
 310
 311 sub insert_discount {
 312   #my ($self, %options) = @_;
 313   my $self = shift;
 314
 315   my $cust_pkg_discount = FS::quotation_pkg_discount->new( {
 316     'quotationpkgnum' => $self->quotationpkgnum,
 317     'discountnum'     => $self->discountnum,
 318     #for the create a new discount case
 319     '_type'           => $self->discountnum__type,
 320     'amount'      => $self->discountnum_amount,
 321     'percent'     => $self->discountnum_percent,
 322     'months'      => $self->discountnum_months,
 323     'setup'       => $self->discountnum_setup,
 324   } );
 325
 326   $cust_pkg_discount->insert;
 327 }
 328
 329 sub _item_discount {
 330   my $self = shift;
 331   my @pkg_discounts = $self->pkg_discount;
 332   return if @pkg_discounts == 0;
 333
 334   my @ext;
 335   my $d = {
 336     _is_discount    => 1,
 337     description     => $self->mt('Discount'),
 338     setup_amount    => 0,
 339     recur_amount    => 0,
 340     amount          => 0,
 341     ext_description => \@ext,
 342     # maybe should show quantity/unit discount?
 343   };
 344   foreach my $pkg_discount (@pkg_discounts) {
 345     push @ext, $pkg_discount->description;
 346     $d->{setup_amount} -= $pkg_discount->setup_amount;
 347     $d->{recur_amount} -= $pkg_discount->recur_amount;
 348   }
 349   $d->{setup_amount} *= $self->quantity || 1;
 350   $d->{recur_amount} *= $self->quantity || 1;
 351   $d->{amount} = $d->{setup_amount} + $d->{recur_amount};
 352
 353   return $d;
 354 }
 355
 356 sub setup {
 357   my $self = shift;
 358   ($self->unitsetup - sum(map { $_->setup_amount } $self->pkg_discount))
 359     * ($self->quantity || 1);
 360 }
 361
 362 sub recur {
 363   my $self = shift;
 364   ($self->unitrecur - sum(map { $_->recur_amount } $self->pkg_discount))
 365     * ($self->quantity || 1);
 366 }
 367
 368 =item part_pkg_currency_option OPTIONNAME
 369
 370 Returns a two item list consisting of the currency of this quotation's customer
 371 or prospect, if any, and a value for the provided option.  If the customer or
 372 prospect has a currency, the value is the option value the given name and the
 373 currency (see L<FS::part_pkg_currency>).  Otherwise, if the customer or
 374 prospect has no currency, is the regular option value for the given name (see
 375 L<FS::part_pkg_option>).
 376
 377 =cut
 378
 379 #false laziness w/cust_pkg->part_pkg_currency_option
 380 sub part_pkg_currency_option {
 381   my( $self, $optionname ) = @_;
 382   my $part_pkg = $self->part_pkg;
 383   my $prospect_or_customer = $self->cust_main || $self->prospect_main;
 384   if ( my $currency = $prospect_or_customer->currency ) {
 385     ($currency, $part_pkg->part_pkg_currency_option($currency, $optionname) );
 386   } else {
 387     ('', $part_pkg->option($optionname) );
 388   }
 389 }
 390
 391
 392 =item cust_bill_pkg_display [ type => TYPE ]
 393
 394 =cut
 395
 396 sub cust_bill_pkg_display {
 397   my ( $self, %opt ) = @_;
 398
 399   my $type = $opt{type} if exists $opt{type};
 400   return () if $type eq 'U'; #quotations don't have usage
 401
 402   if ( $self->get('display') ) {
 403     return ( grep { defined($type) ? ($type eq $_->type) : 1 }
 404                @{ $self->get('display') }
 405            );
 406   } else {
 407
 408     #??
 409     my $setup = $self->new($self->hashref);
 410     $setup->{'_NO_RECUR_KLUDGE'} = 1;
 411     $setup->{'type'} = 'S';
 412     my $recur = $self->new($self->hashref);
 413     $recur->{'_NO_SETUP_KLUDGE'} = 1;
 414     $recur->{'type'} = 'R';
 415
 416     if ( $type eq 'S' ) {
 417       return ($setup);
 418     } elsif ( $type eq 'R' ) {
 419       return ($recur);
 420     } else {
 421       #return ($setup, $recur);
 422       return ($self);
 423     }
 424
 425   }
 426
 427 }
 428
 429 =item cust_main
 430
 431 Returns the customer (L<FS::cust_main> object).
 432
 433 =cut
 434
 435 sub cust_main {
 436   my $self = shift;
 437   my $quotation = FS::quotation->by_key($self->quotationnum) or return '';
 438   $quotation->cust_main;
 439 }
 440
 441 =item prospect_main
 442
 443 Returns the prospect (L<FS::prospect_main> object).
 444
 445 =cut
 446
 447 sub prospect_main {
 448   my $self = shift;
 449   my $quotation = FS::quotation->by_key($self->quotationnum) or return '';
 450   $quotation->prospect_main;
 451 }
 452
 453 =back
 454
 455 =head1 BUGS
 456
 457 Doesn't support taxes, fees, or add-on packages.
 458
 459 =head1 SEE ALSO
 460
 461 L<FS::Record>, schema.html from the base documentation.
 462
 463 =cut
 464
 465 1;
 466