FS/FS/quotation_pkg.pm

   1 package FS::quotation_pkg;
   2 use base qw( FS::TemplateItem_Mixin FS::Record );
   3
   4 use strict;
   5 use FS::Record qw( qsearchs qsearch dbh );
   6 use FS::part_pkg;
   7 use FS::quotation_pkg_discount; #so its loaded when TemplateItem_Mixin needs it
   8 use FS::quotation_pkg_detail;
   9 use List::Util qw(sum);
  10
  11 =head1 NAME
  12
  13 FS::quotation_pkg - Object methods for quotation_pkg records
  14
  15 =head1 SYNOPSIS
  16
  17   use FS::quotation_pkg;
  18
  19   $record = new FS::quotation_pkg \%hash;
  20   $record = new FS::quotation_pkg { 'column' => 'value' };
  21
  22   $error = $record->insert;
  23
  24   $error = $new_record->replace($old_record);
  25
  26   $error = $record->delete;
  27
  28   $error = $record->check;
  29
  30 =head1 DESCRIPTION
  31
  32 An FS::quotation_pkg object represents a quotation package.
  33 FS::quotation_pkg inherits from FS::Record.  The following fields are currently
  34 supported:
  35
  36 =over 4
  37
  38 =item quotationpkgnum
  39
  40 primary key
  41
  42 =item pkgpart
  43
  44 pkgpart (L<FS::part_pkg>) of the package
  45
  46 =item locationnum
  47
  48 locationnum (L<FS::cust_location>) where the package will be in service
  49
  50 =item start_date
  51
  52 expected start date for the package, as a timestamp
  53
  54 =item contract_end
  55
  56 contract end date
  57
  58 =item quantity
  59
  60 quantity
  61
  62 =item waive_setup
  63
  64 'Y' to waive the setup fee
  65
  66 =item unitsetup
  67
  68 The amount per package that will be charged in setup/one-time fees.
  69
  70 =item unitrecur
  71
  72 The amount per package that will be charged per billing cycle.
  73
  74 =item freq
  75
  76 The length of the billing cycle. If zero it's a one-time charge; if any
  77 other number it's that many months; other values are in L<FS::Misc::pkg_freqs>.
  78
  79 =back
  80
  81 =head1 METHODS
  82
  83 =over 4
  84
  85 =item new HASHREF
  86
  87 Creates a new quotation package.  To add the quotation package to the database,
  88 see L<"insert">.
  89
  90 Note that this stores the hash reference, not a distinct copy of the hash it
  91 points to.  You can ask the object for a copy with the I<hash> method.
  92
  93 =cut
  94
  95 sub table { 'quotation_pkg'; }
  96
  97 sub display_table         { 'quotation_pkg'; }
  98
  99 #forget it, just overriding cust_bill_pkg_display entirely
 100 #sub display_table_orderby { 'quotationpkgnum'; } # something else?
 101 #                                                 #  (for invoice display order)
 102
 103 sub discount_table        { 'quotation_pkg_discount'; }
 104
 105 # detail table uses non-quotation fieldnames, see billpkgnum below
 106 sub detail_table          { 'quotation_pkg_detail'; }
 107
 108 =item billpkgnum
 109
 110 Sets/returns quotationpkgnum, for ease of integration with TemplateItem_Mixin::details
 111
 112 =cut
 113
 114 sub billpkgnum {
 115   my $self = shift;
 116   $self->quotationpkgnum(@_);
 117 }
 118
 119 =item insert
 120
 121 Adds this record to the database.  If there is an error, returns the error,
 122 otherwise returns false.
 123
 124 =cut
 125
 126 sub insert {
 127   my ($self, %options) = @_;
 128
 129   my $dbh = dbh;
 130   my $oldAutoCommit = $FS::UID::AutoCommit;
 131   local $FS::UID::AutoCommit = 0;
 132
 133   my $error = $self->SUPER::insert;
 134
 135   if ( !$error and $self->discountnum ) {
 136     warn "inserting discount #".$self->discountnum."\n";
 137     $error = $self->insert_discount;
 138     $error .= ' (setting discount)' if $error;
 139   }
 140
 141   if ( $error ) {
 142     $dbh->rollback if $oldAutoCommit;
 143     return $error;
 144   } else {
 145     $dbh->commit if $oldAutoCommit;
 146     return '';
 147   }
 148 }
 149
 150 =item delete
 151
 152 Delete this record from the database.
 153
 154 =cut
 155
 156 sub delete {
 157   my $self = shift;
 158
 159   my $dbh = dbh;
 160   my $oldAutoCommit = $FS::UID::AutoCommit;
 161   local $FS::UID::AutoCommit = 0;
 162
 163   my $error = $self->delete_details;
 164   if ( $error ) {
 165     $dbh->rollback if $oldAutoCommit;
 166     return $error;
 167   }
 168
 169   foreach ($self->quotation_pkg_discount, $self->quotation_pkg_tax) {
 170     $error = $_->delete;
 171     if ( $error ) {
 172       $dbh->rollback if $oldAutoCommit;
 173       return $error . ' (deleting discount)';
 174     }
 175   }
 176
 177   $error = $self->SUPER::delete;
 178   if ( $error ) {
 179     $dbh->rollback if $oldAutoCommit;
 180     return $error;
 181   } else {
 182     $dbh->commit if $oldAutoCommit;
 183   }
 184
 185   $self->quotation->estimate;
 186 }
 187
 188 =item replace OLD_RECORD
 189
 190 Replaces the OLD_RECORD with this one in the database.  If there is an error,
 191 returns the error, otherwise returns false.
 192
 193 =item check
 194
 195 Checks all fields to make sure this is a valid quotation package.  If there is
 196 an error, returns the error, otherwise returns false.  Called by the insert
 197 and replace methods.
 198
 199 =cut
 200
 201 sub check {
 202   my $self = shift;
 203
 204   my @freqs = ('', keys (%{ FS::Misc->pkg_freqs }));
 205
 206   my $error =
 207     $self->ut_numbern('quotationpkgnum')
 208     || $self->ut_foreign_key(  'quotationnum', 'quotation',    'quotationnum' )
 209     || $self->ut_foreign_key(  'pkgpart',      'part_pkg',     'pkgpart'      )
 210     || $self->ut_foreign_keyn( 'locationnum', 'cust_location', 'locationnum'  )
 211     || $self->ut_numbern('start_date')
 212     || $self->ut_numbern('contract_end')
 213     || $self->ut_numbern('quantity')
 214     || $self->ut_moneyn('unitsetup')
 215     || $self->ut_moneyn('unitrecur')
 216     || $self->ut_enum('freq', \@freqs)
 217     || $self->ut_enum('waive_setup', [ '', 'Y'] )
 218   ;
 219
 220   if ($self->locationnum eq '') {
 221     # use the customer default
 222     my $quotation = $self->quotation;
 223     if ($quotation->custnum) {
 224       $self->set('locationnum', $quotation->cust_main->ship_locationnum);
 225     } elsif ($quotation->prospectnum) {
 226       # use the first non-disabled location for that prospect
 227       my $cust_location = qsearchs('cust_location',
 228         { prospectnum => $quotation->prospectnum,
 229           disabled => '' });
 230       $self->set('locationnum', $cust_location->locationnum) if $cust_location;
 231     } # else the quotation is invalid
 232   }
 233
 234   return $error if $error;
 235
 236   $self->SUPER::check;
 237 }
 238
 239 #it looks redundant with a v4.x+ auto-generated method, but need to override
 240 # FS::TemplateItem_Mixin's version
 241 sub part_pkg {
 242   my $self = shift;
 243   qsearchs('part_pkg', { 'pkgpart' => $self->pkgpart } );
 244 }
 245
 246 sub desc {
 247   my $self = shift;
 248   $self->part_pkg->pkg;
 249 }
 250
 251 =cut
 252
 253 =item insert_discount
 254
 255 Associates this package with a discount (see L<FS::cust_pkg_discount>,
 256 possibly inserting a new discount on the fly (see L<FS::discount>). Properties
 257 of the discount will be taken from this object.
 258
 259 =cut
 260
 261 sub insert_discount {
 262   #my ($self, %options) = @_;
 263   my $self = shift;
 264
 265   my $quotation_pkg_discount = FS::quotation_pkg_discount->new( {
 266     'quotationpkgnum' => $self->quotationpkgnum,
 267     'discountnum'     => $self->discountnum,
 268     #for the create a new discount case
 269     '_type'           => $self->discountnum__type,
 270     'amount'      => $self->discountnum_amount,
 271     'percent'     => $self->discountnum_percent,
 272     'months'      => $self->discountnum_months,
 273     'setup'       => $self->discountnum_setup,
 274   } );
 275
 276   $quotation_pkg_discount->insert;
 277 }
 278
 279 sub _item_discount {
 280   my $self = shift;
 281   my %options = @_;
 282   my $setuprecur = $options{'setuprecur'};
 283
 284   # kind of silly treating this as multiple records, but it works, and will
 285   # work if we allow multiple discounts at some point
 286   my @pkg_discounts = $self->pkg_discount;
 287   return if @pkg_discounts == 0;
 288
 289   my @ext;
 290   my $d = {
 291     _is_discount    => 1,
 292     description     => $self->mt('Discount'),
 293     amount          => 0,
 294     ext_description => \@ext,
 295     # maybe should show quantity/unit discount?
 296   };
 297   foreach my $pkg_discount (@pkg_discounts) {
 298     push @ext, $pkg_discount->description;
 299     my $amount = $pkg_discount->get($setuprecur.'_amount');
 300     $d->{amount} -= $amount;
 301   }
 302   $d->{amount} = sprintf('%.2f', $d->{amount} * $self->quantity);
 303
 304   return $d;
 305 }
 306
 307 sub setup {
 308   my $self = shift;
 309   ($self->unitsetup - sum(0, map { $_->setup_amount } $self->pkg_discount))
 310     * ($self->quantity || 1);
 311
 312 }
 313
 314 sub setup_tax {
 315   my $self = shift;
 316   sum(0, map { $_->setup_amount } $self->quotation_pkg_tax);
 317 }
 318
 319 sub recur {
 320   my $self = shift;
 321   ($self->unitrecur - sum(0, map { $_->recur_amount } $self->pkg_discount))
 322     * ($self->quantity || 1)
 323 }
 324
 325 sub recur_tax {
 326   my $self = shift;
 327   sum(0, map { $_->recur_amount } $self->quotation_pkg_tax);
 328 }
 329
 330 =item part_pkg_currency_option OPTIONNAME
 331
 332 Returns a two item list consisting of the currency of this quotation's customer
 333 or prospect, if any, and a value for the provided option.  If the customer or
 334 prospect has a currency, the value is the option value the given name and the
 335 currency (see L<FS::part_pkg_currency>).  Otherwise, if the customer or
 336 prospect has no currency, is the regular option value for the given name (see
 337 L<FS::part_pkg_option>).
 338
 339 =cut
 340
 341 #false laziness w/cust_pkg->part_pkg_currency_option
 342 sub part_pkg_currency_option {
 343   my( $self, $optionname ) = @_;
 344   my $part_pkg = $self->part_pkg;
 345   my $prospect_or_customer = $self->cust_main || $self->prospect_main;
 346   if ( my $currency = $prospect_or_customer->currency ) {
 347     ($currency, $part_pkg->part_pkg_currency_option($currency, $optionname) );
 348   } else {
 349     ('', $part_pkg->option($optionname) );
 350   }
 351 }
 352
 353 =item delete_details
 354
 355 Deletes all quotation_pkgs_details associated with this pkg (see L<FS::quotation_pkg_detail>).
 356
 357 =cut
 358
 359 sub delete_details {
 360   my $self = shift;
 361
 362   my $oldAutoCommit = $FS::UID::AutoCommit;
 363   local $FS::UID::AutoCommit = 0;
 364   my $dbh = dbh;
 365
 366   foreach my $detail ( qsearch('quotation_pkg_detail',{ 'billpkgnum' => $self->quotationpkgnum }) ) {
 367     my $error = $detail->delete;
 368     if ( $error ) {
 369       $dbh->rollback if $oldAutoCommit;
 370       return "error removing old detail: $error";
 371     }
 372   }
 373
 374   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 375   '';
 376
 377 }
 378
 379 =item set_details [ DETAIL, DETAIL, ... ]
 380
 381 Sets quotation details for this package (see L<FS::quotation_pkg_detail>).
 382
 383 If there is an error, returns the error, otherwise returns false.
 384
 385 =cut
 386
 387 sub set_details {
 388   my( $self, @details ) = @_;
 389
 390   my $oldAutoCommit = $FS::UID::AutoCommit;
 391   local $FS::UID::AutoCommit = 0;
 392   my $dbh = dbh;
 393
 394   my $error = $self->delete_details;
 395   if ( $error ) {
 396     $dbh->rollback if $oldAutoCommit;
 397     return $error;
 398   }
 399
 400   foreach my $detail ( @details ) {
 401     my $quotation_pkg_detail = new FS::quotation_pkg_detail {
 402       'billpkgnum' => $self->quotationpkgnum,
 403       'detail'     => $detail,
 404     };
 405     $error = $quotation_pkg_detail->insert;
 406     if ( $error ) {
 407       $dbh->rollback if $oldAutoCommit;
 408       return "error adding new detail: $error";
 409     }
 410   }
 411
 412   $dbh->commit or die $dbh->errstr if $oldAutoCommit;
 413   '';
 414
 415 }
 416
 417 =item cust_bill_pkg_display [ type => TYPE ]
 418
 419 =cut
 420
 421 sub cust_bill_pkg_display {
 422   my ( $self, %opt ) = @_;
 423
 424   my $type = $opt{type} if exists $opt{type};
 425   return () if $type eq 'U'; #quotations don't have usage
 426
 427   if ( $self->get('display') ) {
 428     return ( grep { defined($type) ? ($type eq $_->type) : 1 }
 429                @{ $self->get('display') }
 430            );
 431   } else {
 432
 433     #??
 434     my $setup = $self->new($self->hashref);
 435     $setup->{'_NO_RECUR_KLUDGE'} = 1;
 436     $setup->{'type'} = 'S';
 437     my $recur = $self->new($self->hashref);
 438     $recur->{'_NO_SETUP_KLUDGE'} = 1;
 439     $recur->{'type'} = 'R';
 440
 441     if ( $type eq 'S' ) {
 442       return ($setup);
 443     } elsif ( $type eq 'R' ) {
 444       return ($recur);
 445     } else {
 446       #return ($setup, $recur);
 447       return ($self);
 448     }
 449
 450   }
 451
 452 }
 453
 454 =item cust_main
 455
 456 Returns the customer (L<FS::cust_main> object).
 457
 458 =cut
 459
 460 sub cust_main {
 461   my $self = shift;
 462   my $quotation = $self->quotation or return '';
 463   $quotation->cust_main;
 464 }
 465
 466 =item prospect_main
 467
 468 Returns the prospect (L<FS::prospect_main> object).
 469
 470 =cut
 471
 472 sub prospect_main {
 473   my $self = shift;
 474   my $quotation = $self->quotation or return '';
 475   $quotation->prospect_main;
 476 }
 477
 478 sub tax_locationnum {
 479   my $self = shift;
 480   $self->locationnum;
 481 }
 482
 483 sub _upgrade_data {
 484   my $class = shift;
 485   my @quotation_pkg_without_location =
 486     qsearch( 'quotation_pkg', { locationnum => '' } );
 487   if (@quotation_pkg_without_location) {
 488     warn "setting default location on quotation_pkg records\n";
 489     foreach my $quotation_pkg (@quotation_pkg_without_location) {
 490       # check() will fix this
 491       my $error = $quotation_pkg->replace;
 492       if ($error) {
 493         die "quotation #".$quotation_pkg->quotationnum.": $error\n";
 494       }
 495     }
 496   }
 497   '';
 498 }
 499
 500 =back
 501
 502 =head1 BUGS
 503
 504 Doesn't support fees, or add-on packages.
 505
 506 =head1 SEE ALSO
 507
 508 L<FS::Record>, schema.html from the base documentation.
 509
 510 =cut
 511
 512 1;
 513