FS/FS/pay_batch/RBC.pm

   1 package FS::pay_batch::RBC;
   2
   3 use strict;
   4 use vars qw(@ISA %import_info %export_info $name);
   5 use Date::Format 'time2str';
   6 use FS::Conf;
   7 use Encode 'encode';
   8 use feature 'state';
   9
  10 my $conf;
  11 my ($client_num, $shortname, $longname, $trans_code, $testmode, $i, $declined, $totaloffset);
  12
  13 $name = 'RBC';
  14 # Royal Bank of Canada ACH Direct Payments Service
  15
  16 # Meaning of initial characters in records:
  17 # 0 - header row, skipped by begin_condition
  18 # 1 - Debit Detail Record (only when subtype is 0)
  19 # 2 - Credit Detail Record, we die with a parse error (shouldn't appear in freeside-generated batches)
  20 # 3 - Account Trailer Record (appears after Returned items, we skip)
  21 # 4 - Client Trailer Record, indicates end of batch in end_condition
  22 #
  23 # Subtypes (27th char) indicate different kinds of Debit/Credit records
  24 # 0 - Credit/Debit Detail Record
  25 # 3 - Error Message Record
  26 # 4 - Foreign Currency Information Records
  27 # We skip all subtypes except 0
  28 #
  29 # additional info available at https://www.rbcroyalbank.com/ach/cid-213166.html
  30 %import_info = (
  31   'filetype'    => 'fixed',
  32   #this only really applies to Debit Detail, but we otherwise only need first char
  33   'formatre'    =>
  34   '^(.).{3}(.{10}).{5}(.{4}).{3}(.).{11}(.{19}).{6}(.{30}).{17}(.{9})(.{18}).{6}(.{14}).{23}(.).{9}\r?$',
  35   'fields' => [ qw(
  36     recordtype
  37     clientnum
  38     batchnum
  39     subtype
  40     paybatchnum
  41     custname
  42     bank
  43     payinfo
  44     paid
  45     status
  46     ) ],
  47   'hook' => sub {
  48     # pull client_num from config and check it against what's in the batch
  49     state $clientnum ||= do {
  50       my $conf = FS::Conf->new;
  51       my @config = $conf->config("batchconfig-RBC");
  52       $config[0];
  53     };
  54
  55     my $hash = shift;
  56     $hash->{'paid'} = sprintf("%.2f", $hash->{'paid'} / 100 );
  57     $hash->{'_date'} = time;
  58     $hash->{'payinfo'} =~ s/^(\S+).*/$1/; # these often have trailing spaces
  59     $hash->{'payinfo'} = $hash->{'payinfo'} . '@' . $hash->{'bank'};
  60
  61     if ( $clientnum and $hash->{clientnum} ne $clientnum ) {
  62       die "RBC client number in batch (".$hash->{clientnum}.") does not ".
  63         "match configuration.\n";
  64     }
  65     '';
  66   },
  67   'approved'    => sub {
  68       my $hash = shift;
  69       ($hash->{'status'} eq ' ') || ($hash->{'status'} eq 'W');
  70   },
  71   'declined'    => sub {
  72       my $hash = shift;
  73       my $status = $hash->{'status'};
  74       my $message = '';
  75       if ($status eq 'E') {
  76         $message = 'Reversed payment';
  77       } elsif ($status eq 'R') {
  78         $message = 'Rejected payment';
  79       } elsif ($status eq 'U') {
  80         $message = 'Returned payment';
  81       } elsif ($status eq 'T') {
  82         $message = 'Error';
  83       } else {
  84         return 0;
  85       }
  86       $hash->{'error_message'} = $message;
  87       $declined->{$hash->{'paybatchnum'}} = 1;
  88       return 1;
  89   },
  90   'begin_condition' => sub {
  91       my $hash = shift;
  92       # Debit Detail Record
  93       if ($hash->{recordtype} eq '1') {
  94         $declined = {};
  95         $totaloffset = 0;
  96         return 1;
  97       # Credit Detail Record, will immediately trigger end condition & error
  98       } elsif ($hash->{recordtype} eq '2') {
  99         return 1;
 100       } else {
 101         return 0;
 102       }
 103   },
 104   'end_hook'    => sub {
 105       my( $hash, $total, $line ) = @_;
 106       return "Can't process Credit Detail Record, aborting import"
 107         if ($hash->{'recordtype'} eq '2');
 108       $total += $totaloffset;
 109       $total = sprintf("%.2f", $total);
 110       # We assume here that this is an 'All Records' or 'Input Records' report.
 111       my $batch_total = sprintf("%.2f", substr($line, 59, 18) / 100);
 112       return "Our total $total does not match bank total $batch_total!"
 113         if $total != $batch_total;
 114       return '';
 115   },
 116   'end_condition' => sub {
 117       my $hash = shift;
 118       return ($hash->{recordtype} eq '4')  # Client Trailer Record
 119           || ($hash->{recordtype} eq '2'); # Credit Detail Record, will throw error in end_hook
 120   },
 121   'skip_condition' => sub {
 122       my $hash = shift;
 123       #we already declined it this run, no takebacks
 124       if ($declined->{$hash->{'paybatchnum'}}) {
 125         #file counts this as part of total, but we skip
 126         $totaloffset += sprintf("%.2f", $hash->{'paid'} / 100 )
 127           if $hash->{'status'} eq ' '; #false laziness with 'approved' above
 128         return 1;
 129       }
 130       return
 131         ($hash->{'recordtype'} eq '3') || #Account Trailer Record, concludes returned items
 132         ($hash->{'subtype'} ne '0'); #error messages, etc, too late to apply to previous entry
 133   },
 134 );
 135
 136 %export_info = (
 137   init => sub {
 138     $conf = shift;
 139     ($client_num,
 140      $shortname,
 141      $longname,
 142      $trans_code,
 143      $testmode
 144      ) = $conf->config("batchconfig-RBC");
 145     $testmode = '' unless $testmode eq 'TEST';
 146     $i = 1;
 147   },
 148   header => sub {
 149     my $pay_batch = shift;
 150     my $mode = $testmode ? 'TEST' : 'PROD';
 151     my $filenum = $testmode ? 'TEST' : sprintf("%04u", $pay_batch->batchnum);
 152     '$$AAPASTD0152['.$mode.'[NL$$'."\n".
 153     '000001'.
 154     'A'.
 155     'HDR'.
 156     sprintf("%10s", $client_num).
 157     sprintf("%-30s", $longname).
 158     $filenum.
 159     time2str("%Y%j", $pay_batch->download).
 160     'CAD'.
 161     '1'.
 162     ' ' x 87  # filler/reserved fields
 163     ;
 164   },
 165   row => sub {
 166     my ($cust_pay_batch, $pay_batch) = @_;
 167     my ($account, $aba) = split('@', $cust_pay_batch->payinfo);
 168     my($bankno, $branch);
 169     if ( $aba =~ /^0(\d{3})(\d{5})$/ ) { # standard format for Canadian bank ID
 170       ($bankno, $branch) = ( $1, $2 );
 171     } elsif ( $aba =~ /^(\d{5})\.(\d{3})$/ ) { #how we store branches
 172       ($branch, $bankno) = ( $1, $2 );
 173     } else {
 174       die "invalid branch/routing number '$aba'\n";
 175     }
 176
 177     $i++;
 178
 179     ## set to D for debit by default, then override to what cust_pay_batch has as payments may not have paycode.
 180     my $debitorcredit = 'D';
 181     $debitorcredit = $cust_pay_batch->paycode unless !$cust_pay_batch->paycode;
 182
 183     sprintf("%06u", $i).
 184     $debitorcredit.
 185     sprintf("%3s",$trans_code).
 186     sprintf("%10s",$client_num).
 187     ' '.
 188     sprintf("%-19s", $cust_pay_batch->paybatchnum).
 189     '00'.
 190     sprintf("%04s", $bankno).
 191     sprintf("%05s", $branch).
 192     sprintf("%-18s", $account).
 193     ' '.
 194     sprintf("%010.0f",$cust_pay_batch->amount*100).
 195     '      '.
 196     time2str("%Y%j", time + 86400).
 197     sprintf("%-30.30s", encode('utf8', $cust_pay_batch->cust_main->first . ' ' .
 198                      $cust_pay_batch->cust_main->last)).
 199     'E'. # English
 200     ' '.
 201     sprintf("%-15s", $shortname).
 202     'CAD'.
 203     ' '.
 204     'CAN'.
 205     '    '.
 206     'N' # no customer optional information follows
 207     ;
 208 # Note: IAT Address Information and Remittance records are not
 209 # supported. This means you probably can't process payments
 210 # destined to U.S. bank accounts.  If you need this feature, contact
 211 # Freeside Internet Services.
 212   },
 213   footer => sub {
 214     my ($pay_batch, $batchcount, $batchtotal) = @_;
 215     sprintf("%06u", $i + 1).
 216     'Z'.
 217     'TRL'.
 218     sprintf("%10s", $client_num).
 219     '0' x 20 .
 220     sprintf("%06u", $batchcount).
 221     sprintf("%014.0f", $batchtotal*100).
 222     '00' .
 223     '000000' . # total number of customer information records
 224     ' ' x 84
 225     ;
 226   },
 227 );
 228
 229 1;
 230